Quality Measure Implementation Guide (STU5)
5.0.0-ballot2 - ballot United States of America flag

Quality Measure Implementation Guide (STU5), published by HL7 International / Clinical Quality Information. This guide is not an authorized publication; it is the continuous build for version 5.0.0-ballot2 built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/HL7/cqf-measures/ and changes regularly. See the Directory of published versions

Library: BCS Component Library

Official URL: http://hl7.org/fhir/us/cqfmeasures/Library/BCSComponent Version: 0.0.001
Draft as of 2024-03-29 Computable Name: BCSComponent

This library is the primary measure library for the Breast Cancer Screening component of the composite measure examples in this implementation guide.

Title: BCS Component Library
Id: BCSComponent
Version: 0.0.001
Url: BCS Component Library
Status: draft
Type:

system: LibraryType

code: logic-library

Date: 2024-03-29 03:18:54+0000
Publisher: HL7 International / Clinical Quality Information
Description:

This library is the primary measure library for the Breast Cancer Screening component of the composite measure examples in this implementation guide.

Jurisdiction: US
Related Artifacts:

Dependencies

Parameters:
NameTypeMinMaxIn/Out
Measurement PeriodPeriod01in
PatientPatient01out
SDE EthnicityCoding0*out
SDE PayerResource0*out
SDE RaceCoding0*out
SDE SexCoding01out
Initial Populationboolean01out
Denominatorboolean01out
Right Mastectomy DiagnosisCondition0*out
Right Mastectomy ProcedureProcedure0*out
Left Mastectomy ProcedureProcedure0*out
Bilateral Mastectomy DiagnosisCondition0*out
Bilateral Mastectomy ProcedureProcedure0*out
Numeratorboolean01out
Left MastectomyCondition0*out
Denominator Exclusionboolean01out
Data Requirements:
TypeProfileMSCode Filter
Patient http://hl7.org/fhir/StructureDefinition/Patient
Patient http://hl7.org/fhir/StructureDefinition/Patient code filter:
path: url

system: urn:ietf:rfc:3986

code: http://hl7.org/fhir/us/core/StructureDefinition/us-core-ethnicity

Patient http://hl7.org/fhir/StructureDefinition/Patient code filter:
path: url

system: urn:ietf:rfc:3986

code: http://hl7.org/fhir/us/core/StructureDefinition/us-core-race

Condition http://hl7.org/fhir/StructureDefinition/Condition code filter:
path: code
value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1071
Procedure http://hl7.org/fhir/StructureDefinition/Procedure code filter:
path: code
value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1134 code filter:
path: status

system: TestReportStatus

code: completed

Procedure http://hl7.org/fhir/StructureDefinition/Procedure code filter:
path: code
value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1133 code filter:
path: status

system: TestReportStatus

code: completed

Condition http://hl7.org/fhir/StructureDefinition/Condition code filter:
path: code
value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1068
Procedure http://hl7.org/fhir/StructureDefinition/Procedure code filter:
path: code
value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1005 code filter:
path: status

system: TestReportStatus

code: completed

DiagnosticReport http://hl7.org/fhir/StructureDefinition/DiagnosticReport code filter:
path: code
value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1018
Condition http://hl7.org/fhir/StructureDefinition/Condition code filter:
path: code
value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1071
Encounter http://hl7.org/fhir/StructureDefinition/Encounter code filter:
path: type
value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.666.5.307
ServiceRequest http://hl7.org/fhir/StructureDefinition/ServiceRequest code filter:
path: code
value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1108.15 code filter:
path: intent

system: RequestIntent

code: order

code filter:
path: intent

system: RequestIntent

code: order

code filter:
path: intent

system: RequestIntent

code: order

code filter:
path: intent

system: RequestIntent

code: order

code filter:
path: intent

system: RequestIntent

code: order

code filter:
path: intent

system: RequestIntent

code: order

Procedure http://hl7.org/fhir/StructureDefinition/Procedure code filter:
path: code
value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1108.15 code filter:
path: status

system: TestReportStatus

code: completed

code filter:
path: status

system: TestReportStatus

code: completed

code filter:
path: status

system: TestReportStatus

code: completed

code filter:
path: status

system: TestReportStatus

code: completed

code filter:
path: status

system: TestReportStatus

code: completed

code filter:
path: status

system: TestReportStatus

code: completed

DeviceRequest http://hl7.org/fhir/StructureDefinition/DeviceRequest code filter:
path: code
value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.118.12.1300
Condition http://hl7.org/fhir/StructureDefinition/Condition code filter:
path: code
value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.113.12.1074
Encounter http://hl7.org/fhir/StructureDefinition/Encounter code filter:
path: type
value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1088
Observation http://hl7.org/fhir/StructureDefinition/Observation code filter:
path: code
value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.113.12.1075
Content: text/cql
/*
This example is a work in progress and should not be considered a final specification
or recommendation for guidance. This example will help guide and direct the process
of finding conventions and usage patterns that meet the needs of the various stakeholders
in the measure development community.
*/
library BCSComponent version '0.0.001'

using FHIR version '4.0.1'

include FHIRHelpers version '4.0.1' called FHIRHelpers
include SupplementalDataElements version '2.0.000' called SDE
include MATGlobalCommonFunctions version '5.0.000' called Global
include AdultOutpatientEncounters version '2.0.000' called AdultOutpatientEncounters
include Hospice version '2.0.000' called Hospice
include AdvancedIllnessandFrailtyExclusion version '5.12.000' called Frailty

codesystem "LOINC": 'http://loinc.org'
codesystem "SNOMEDCT": 'http://snomed.info/sct'

valueset "Bilateral Mastectomy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1005'
valueset "Ethnicity": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.837'
valueset "Female": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.560.100.2'
valueset "History of bilateral mastectomy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1068'
valueset "Left": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.122.12.1036'
valueset "Mammography": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1018'
valueset "ONC Administrative Sex": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1'
valueset "Payer": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.3591'
valueset "Race": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.836'
valueset "Right": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.122.12.1035'
valueset "Status Post Left Mastectomy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1069'
valueset "Status Post Right Mastectomy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1070'
valueset "Unilateral Mastectomy Left": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1133'
valueset "Unilateral Mastectomy Right": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1134'
valueset "Unilateral Mastectomy, Unspecified Laterality": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1071'

code "Birth date": '21112-8' from "LOINC" display 'Birth date'
code "Left (qualifier value)": '7771000' from "SNOMEDCT" display 'Left (qualifier value)'
code "Right (qualifier value)": '24028007' from "SNOMEDCT" display 'Right (qualifier value)'

parameter "Measurement Period" Interval<DateTime>

context Patient

define "SDE Ethnicity":
  SDE."SDE Ethnicity"

define "SDE Payer":
  SDE."SDE Payer"

define "SDE Race":
  SDE."SDE Race"

define "SDE Sex":
  SDE."SDE Sex"

define "Initial Population":
  Patient.gender = 'female'
      and Global."CalendarAgeInYearsAt" ( FHIRHelpers.ToDate ( Patient.birthDate ), start of "Measurement Period" ) in Interval[51, 74 )
      and exists AdultOutpatientEncounters."Qualifying Encounters"

define "Denominator":
  "Initial Population"

define "Right Mastectomy Diagnosis":
  ( ( [Condition: "Status Post Right Mastectomy"] )
      union ( [Condition: "Unilateral Mastectomy, Unspecified Laterality"] UnilateralMastectomyDiagnosis
          where UnilateralMastectomyDiagnosis.bodySite in "Right"
      ) ) RightMastectomy
      where Global."Normalize Interval" ( RightMastectomy.onset ) starts on or before
      end of "Measurement Period"

define "Right Mastectomy Procedure":
  [Procedure: "Unilateral Mastectomy Right"] UnilateralMastectomyRightPerformed
      where Global."Normalize Interval" ( UnilateralMastectomyRightPerformed.performed ) ends on or before
      end of "Measurement Period"
        and UnilateralMastectomyRightPerformed.status = 'completed'

define "Left Mastectomy Procedure":
  [Procedure: "Unilateral Mastectomy Left"] UnilateralMastectomyLeftPerformed
      where Global."Normalize Interval" ( UnilateralMastectomyLeftPerformed.performed ) ends on or before
      end of "Measurement Period"
        and UnilateralMastectomyLeftPerformed.status = 'completed'

define "Bilateral Mastectomy Diagnosis":
  [Condition: "History of bilateral mastectomy"] BilateralMastectomyHistory
      where Global."Normalize Interval" ( BilateralMastectomyHistory.onset ) starts on or before
      end of "Measurement Period"

define "Bilateral Mastectomy Procedure":
  [Procedure: "Bilateral Mastectomy"] BilateralMastectomyPerformed
      where Global."Normalize Interval" ( BilateralMastectomyPerformed.performed ) ends on or before
      end of "Measurement Period"
        and BilateralMastectomyPerformed.status = 'completed'

define "Numerator":
  exists ( [DiagnosticReport: "Mammography"] Mammogram
        where ( Global."Normalize Interval" ( Mammogram.effective ) ends 27 months or less on or before
          end of "Measurement Period"
        )
          and Mammogram.status in { 'final', 'amended', 'corrected', 'appended' }
    )

define "Denominator Exclusion":
  Hospice."Has Hospice"
      or ( ( exists "Right Mastectomy Diagnosis"
            or exists "Right Mastectomy Procedure"
        )
          and ( exists "Left Mastectomy"
              or exists "Left Mastectomy Procedure"
          )
      )
      or exists "Bilateral Mastectomy Diagnosis"
      or exists "Bilateral Mastectomy Procedure"
      or Frailty."Advanced Illness and Frailty Exclusion Not Including Over Age 80"
      or ( Global."CalendarAgeInYearsAt" ( FHIRHelpers.ToDate ( Patient.birthDate ), start of "Measurement Period" ) >= 65
          and Frailty."Long Term Care Periods Longer Than 90 Consecutive Days"
      )

define "Left Mastectomy":
  ( ( [Condition: "Status Post Left Mastectomy"] )
      union ( [Condition: "Unilateral Mastectomy, Unspecified Laterality"] UnilateralMastectomyDiagnosis
          where UnilateralMastectomyDiagnosis.bodySite in "Left"
      ) ) LeftMastectomy
      where Global."Normalize Interval" ( LeftMastectomy.onset ) starts on or before
      end of "Measurement Period"
Content: application/elm+xml
Encoded data (104968 characters)