dQM CMS Content Implementation Guide
2026.1.0 - CI Build

dQM CMS Content Implementation Guide, published by cqframework. This guide is not an authorized publication; it is the continuous build for version 2026.1.0 built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/cqframework/dqm-content-cms-2026/ and changes regularly. See the Directory of published versions

Library: ImagingStudyFeasibilityTest

Official URL: https://research.balgrist.ch/Library/ImagingStudyFeasibilityTest Version: 1.0.0
Active as of 2024-05-15 Responsible: Balgrist Computable Name: ImagingStudyFeasibilityTest

Imaging Study Feasibility Test

Metadata
Title ImagingStudyFeasibilityTest
Version 1.0.0
Topic FHIR
Topic CQL
Steward (Publisher) Balgrist
Description

Imaging Study Feasibility Test
Type logic-library from http://terminology.hl7.org/CodeSystem/library-type
Dependency Description: Library FHIRHelpers
Resource: http://hl7.org/fhir/uv/cql/Library/FHIRHelpers|4.0.1
Canonical URL: http://hl7.org/fhir/uv/cql/Library/FHIRHelpers|4.0.1
Dependency Description: Code System DICOM
Resource: DICOM Controlled Terminology Definitions
Canonical URL: http://dicom.nema.org/resources/ontology/DCM
Dependency Description: Value Set CTImagingModality
Resource: https://research.balgrist.ch/ValueSet/CTImagingModality
Canonical URL: https://research.balgrist.ch/ValueSet/CTImagingModality
Data Requirement Type: ImagingStudy
Profile(s): ImagingStudy
Data Requirement Type: ImagingStudy
Profile(s): ImagingStudy
Code Filter(s):
Path: modality
Data Requirement Type: ImagingStudy
Profile(s): ImagingStudy
Code Filter(s):
Path: modality
ValueSet: https://research.balgrist.ch/ValueSet/CTImagingModality
Parameters
Name Use Card. Type Documentation
ModalityCode In 0..1 string
Manufacturer In 0..1 string
SeriesDescriptionText In 0..1 string
MinNumberOfSeries In 0..1 integer
Patient Out 0..1 Patient
AllImagingStudies Out 0..* ImagingStudy
StudiesWithModality Out 0..* ImagingStudy
HasStudyWithModality Out 0..1 boolean
CTImagingStudies Out 0..* ImagingStudy
HasCTImagingStudies Out 0..1 boolean
StudiesWithManufacturer Out 0..* ImagingStudy
HasStudyWithManufacturer Out 0..1 boolean
StudiesWithSeriesDescription Out 0..* ImagingStudy
HasStudyWithSeriesDescription Out 0..1 boolean
StudiesWithMinSeries Out 0..* ImagingStudy
HasStudyWithMinSeries Out 0..1 boolean
HasAnyMatch Out 0..1 boolean
HasAllMatchSearchDefault Out 0..1 boolean
HasAllMatchSearchCustom Out 0..1 boolean
HasAllMatchNoSearch Out 0..1 boolean
InitialPopulation Out 0..1 boolean
Library Content
CQL Content 
library ImagingStudyFeasibilityTest version '1.0.0'

using FHIR version '4.0.1'

include hl7.fhir.uv.cql.FHIRHelpers version '4.0.1'

codesystem DICOM: 'http://dicom.nema.org/resources/ontology/DCM'

code CT: 'CT' from DICOM display 'Computed Tomography'
code MR: 'MR' from DICOM display 'Magnetic Resonance'
code US: 'US' from DICOM display 'Ultrasound'
code XR: 'XR' from DICOM display 'X-Ray Radiography'
code MG: 'MG' from DICOM display 'Mammography'
code NM: 'NM' from DICOM display 'Nuclear Medicine'
code PT: 'PT' from DICOM display 'Positron Emission Tomography'
code DX: 'DX' from DICOM display 'Digital Radiography'

valueset CTImagingModality: 'https://research.balgrist.ch/ValueSet/CTImagingModality'

parameter ModalityCode String
parameter Manufacturer String
parameter SeriesDescriptionText String
parameter MinNumberOfSeries Integer

context Patient

define "AllImagingStudies":
  [ImagingStudy]

// =============================================================================
// TEST 1: Default Search Param (modality - study level)
// =============================================================================
define "StudiesWithModality":
  [ImagingStudy: modality ~ ModalityCode]
//  "AllImagingStudies" S
//    where exists (
//      S.modality M
//        where M.code.value = ModalityCode
//    )

define "HasStudyWithModality":
  exists "StudiesWithModality"

/*
@description: Returns ImagingStudy resources with a modality in the CTImagingModality value set
@comment: This item is marked selective to indicate it can be used as a narrowing filter in 
determining the set of subjects on which to run. For the purposes of this demonstration this
tag is added manually to the data requirements for the measure post processing. In the future
this step will be performed by tooling.
@isSelective
*/
define "CTImagingStudies":
  [ImagingStudy: modality in CTImagingModality]

define "HasCTImagingStudies":
  exists "CTImagingStudies"



// =============================================================================
// TEST 2: Custom Search Param (manufacturer - series level extension)
// =============================================================================
define "StudiesWithManufacturer":
//  [ImagingStudy: manufacturer ~ Manufacturer]
  "AllImagingStudies" S
    where exists (
      S.series Serie
        where exists (
          Serie.extension E
            where E.url = 'http://example.org/fhir/StructureDefinition/dicom-equipment-manufacturer'
              and (E.value as FHIR.string).value = Manufacturer
        )
    )

define "HasStudyWithManufacturer":
  exists "StudiesWithManufacturer"

// =============================================================================
// TEST 3a: Non-Search-Param - Text (series.description)
// =============================================================================
define "StudiesWithSeriesDescription":
  "AllImagingStudies" S
    where exists (
      S.series Serie
        where PositionOf(Lower(SeriesDescriptionText), Lower(Serie.description.value)) >= 0
    )

define "HasStudyWithSeriesDescription":
  exists "StudiesWithSeriesDescription"

// =============================================================================
// TEST 3b: Non-Search-Param - Numeric (numberOfSeries)
// =============================================================================
define "StudiesWithMinSeries":
  "AllImagingStudies" S
    where S.numberOfSeries.value >= MinNumberOfSeries

define "HasStudyWithMinSeries":
  exists "StudiesWithMinSeries"

// =============================================================================
// Combined: ANY match (OR logic)
// =============================================================================
define "HasAnyMatch":
  "HasStudyWithModality"
    or "HasStudyWithManufacturer"
    or "HasStudyWithSeriesDescription"
    or "HasStudyWithMinSeries"

// =============================================================================
// Combined: ALL match (AND logic) Default Search Parameter First
// =============================================================================
define "HasAllMatchSearchDefault":
  "HasStudyWithModality"
    and "HasStudyWithManufacturer"
    and "HasStudyWithSeriesDescription"

// =============================================================================
// Combined: ALL match (AND logic) Custom Search Parameter First
// =============================================================================
define "HasAllMatchSearchCustom":
  "HasStudyWithManufacturer"
  and "HasStudyWithModality"
    and "HasStudyWithSeriesDescription"

// =============================================================================
// Combined: ALL match (AND logic) No Search Parameter First
// =============================================================================
define "HasAllMatchNoSearch":
  "HasStudyWithSeriesDescription"
  and "HasStudyWithModality"
    and "HasStudyWithManufacturer"

// =============================================================================
// Initial Population (default to any match)
// =============================================================================
define "InitialPopulation":
  "HasAnyMatch"
ELM XML Content 
Encoded data
ELM JSON Content 
Encoded data
Generated using version 0.5.6-cibuild of the sample-content-ig Liquid templates