WHO Antenatal Care Guideline Implementation Guide
0.3.0 - CI Build International flag

WHO Antenatal Care Guideline Implementation Guide, published by World Health Organization (WHO). This guide is not an authorized publication; it is the continuous build for version 0.3.0 built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/WorldHealthOrganization/smart-anc/ and changes regularly. See the Directory of published versions

Library: ANC.IND.10 Percentage of pregnant women with an ultrasound scan before 24 weeks

Official URL: http://fhir.org/guides/who/anc-cds/Library/ANCIND10 Version: 0.3.0
Active as of 2024-09-10 Computable Name: ANCIND10

This library provides logic for calculating the percentage of pregnant women with an ultrasound scan before 24 weeks

Id: ANCIND10
Url: ANC.IND.10 Percentage of pregnant women with an ultrasound scan before 24 weeks
Version: 0.3.0
Name: ANCIND10
Title: ANC.IND.10 Percentage of pregnant women with an ultrasound scan before 24 weeks
Status: active
Experimental: false
Type:

system: http://terminology.hl7.org/CodeSystem/library-type

code: logic-library

Date: 2024-09-10 13:23:00+0000
Publisher: World Health Organization (WHO)
Description: This library provides logic for calculating the percentage of pregnant women with an ultrasound scan before 24 weeks
Jurisdiction: 001
Related Artifacts:

Dependencies
Parameters:
NameTypeMinMaxIn/Out
Measurement PeriodPeriod01In
PatientPatient01Out
Initial Populationboolean01Out
Numeratorboolean01Out
Denominatorboolean01Out
Age StratifierCoding01Out
Education Level StratifierCodeableConcept0*Out
Data Requirements:
TypeProfileMSCode Filter
Patient http://hl7.org/fhir/StructureDefinition/Patient ;;
EpisodeOfCare http://hl7.org/fhir/StructureDefinition/EpisodeOfCare ; code filter:
path: type
value set: http://fhir.org/guides/who/anc-cds/ValueSet/antenatal-care-case
Procedure http://hl7.org/fhir/StructureDefinition/Procedure ;;; code filter:
path: code
value set: http://fhir.org/guides/who/anc-cds/ValueSet/anc-b9-de3
Observation http://hl7.org/fhir/StructureDefinition/Observation ;;;; code filter:
path: code
value set: http://fhir.org/guides/who/anc-cds/ValueSet/anc-b6-de17
Content: text/cql
/*
Library ANC.IND.10
WHO Antenatal Care (ANC) Indicator 10
Percentage of pregnant women with an ultrasound scan before 24 weeks 

Numerator: Number of pregnant women who received ultrasound scan before 24 weeks 
Numerator Computation: COUNT of all women who had an ultrasound scan done before 24 weeks gestational age 
Denominator: Total number of antenatal clients with gestational age equal to 24 weeks
Denominator Computation: COUNT of all pregnant women who reached 24 weeks gestational age in the past calendar month 

Disaggregation:
Age (10-14, 15-19, 20+)
Education Level (none, don't know, primary, secondary, higher)

Reference:
WHO ANC monitoring framework (1) 
*/
library ANCIND10

using FHIR version '4.0.1'

include FHIRHelpers version '4.0.1'
include FHIRCommon called FC
include ANCCommon called AC
include ANCBaseConcepts called BCx
include ANCConcepts called Cx
include ANCBaseDataElements called BaseData
include ANCDataElements called PatientData
include ANCContactDataElements called ContactData
include ANCStratifiers called Stratifiers

parameter "Measurement Period" Interval<Date> default Interval[@2020-01-01, @2020-01-31]

context Patient

/*
Initial population: Antenatal clients
*/
define "Initial Population":
  exists (BaseData."Antenatal care case")

/*
Numerator: Number of pregnant women who received ultrasound scan before 24 weeks 
Numerator Computation: COUNT of all women who had an ultrasound scan done before 24 weeks gestational age 
*/
define Numerator:
  exists (
    PatientData."Ultrasound scan conducted" P
      where FC.ToInterval(P.performed) during Interval[start of BaseData."Pregnancy".period, start of BaseData."Pregnancy".period + 24 weeks]
    )

/*
Denominator: Total number of antenatal clients with gestational age equal to 24 weeks
Denominator Computation: COUNT of all pregnant women who reached 24 weeks gestational age in the past calendar month 
*/
define Denominator:
  exists (
    PatientData."Gestational age" GA
      where FC.ToInterval(GA.effective) during "Measurement Period"
        and GA.value = 24 weeks
  )

/*
Disaggregation: Age (10-14, 15-19, 20+)
*/
define "Age Stratifier":
  Stratifiers."By Age"

/*
Disaggregation: Education Level (none, don't know, primary, secondary, higher)
*/
define "Education Level Stratifier":
  Stratifiers."By Education Level"
Content: application/elm+xml
Encoded data (32376 characters)
Content: application/elm+json
Encoded data (56120 characters)