2022 CDC Clinical Practice Guideline for Prescribing Opioids Implementation Guide
2022.1.0 - CI Build

2022 CDC Clinical Practice Guideline for Prescribing Opioids Implementation Guide, published by Centers for Disease Control and Prevention (CDC). This guide is not an authorized publication; it is the continuous build for version 2022.1.0 built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/cqframework/opioid-cds-r4/ and changes regularly. See the Directory of published versions

Library: OpioidCDSREC09Library (Experimental)

Official URL: http://fhir.org/guides/cdc/opioid-cds/Library/OpioidCDSREC09 Version: 2022.1.0
Active as of 2024-05-28 Computable Name: OpioidCDSREC09
Id: OpioidCDSREC09
Url: Library - Recommendation #9 - Consider Patient's History of Controlled Substance Prescriptions
Version: 2022.1.0
Name: OpioidCDSREC09
Title: Library - Recommendation #9 - Consider Patient's History of Controlled Substance Prescriptions
Status: active
Experimental: true
Type:

system: LibraryType

code: logic-library

Date: 2024-05-28 16:37:24+0000
Publisher: Centers for Disease Control and Prevention (CDC)
Related Artifacts:

Dependencies

Parameters:
NameTypeMinMaxIn/Out
ContextPrescriptionsMedicationRequest01in
PatientPatient01out
Look Back 90 DaysPeriod01out
Chronic Pain Opioid Analgesic with Ambulatory Misuse Potential PrescriptionsMedicationRequest0*out
Patient Is Being Prescribed Opioid Analgesic with Ambulatory Misuse Potentialboolean01out
PDMP Data Not Reviewed in Past 90 Daysboolean01out
Inclusion Criteriaboolean01out
Exclusion Criteriaboolean01out
Is Recommendation Applicable?boolean01out
Get Indicatorstring01out
Get Summarystring01out
Get Detailstring01out
Content: text/cql
library OpioidCDSREC09 version '2022.1.0'

using FHIR version '4.0.1'

include FHIRHelpers version '4.0.1' called FHIRHelpers
include OpioidCDSCommon version '2022.1.0' called Common
include OpioidCDSCommonConfig version '2022.1.0' called Config
include OpioidCDSRoutines version '2022.1.0' called Routines

/*
**
**  Recommendation #9
**    When prescribing initial opioid therapy for acute, subacute, or chronic pain, and periodically 
**    during opioid therapy for chronic pain, clinicians should review the patient’s history of 
**    controlled substance prescriptions using state prescription drug monitoring program (PDMP) data 
**    to determine whether the patient is receiving opioid dosages or combinations that put the patient 
**    at high risk for overdose (recommendation category: B; evidence type: 4).
**
**  When
**    Provider is prescribing an opioid analgesic with ambulatory misuse potential in the outpatient setting
**    Opioid review is useful for this patient:
**      Patient is 18 or over
**      Patient does not have evidence of sickle cell disease
**      Patient does not have findings indicating limited life expectancy
**      Patient does not have orders for therapies indicating end of life care
**      Patient is not undergoing active cancer treatment:
**        Patient has had at least 2 office visits within the past 12 months with an oncology specialist present, or
**        Patient has had at least 2 office visits within the past 12 months with a CDC malignant cancer condition diagnosis
**      Patient does not have conditions likely terminal for opioid prescribing present
**    PDMP data has not been reviewed in the past 90 days or
**    PDMP review procedure has not been performed in the past 90 days
**  Then
**    Before Ordering Opioids, Review PDMP Data:
**      Access Data - Launch app to review PDMP data
**      Document - PDMP data reviewed, snooze 3 months
**      Snooze - N/A see comment, snooze 3 months
**
*/

// META: Plan Definition: http://fhir.org/guides/cdc/opioid-cds-r4/PlanDefinition/opioid-cds-09

parameter ContextPrescriptions List<MedicationRequest>

context Patient

define "Look Back 90 Days":
  Interval[Today() - 90 days, Today()]

define "Chronic Pain Opioid Analgesic with Ambulatory Misuse Potential Prescriptions":
  ( Common."Is Opioid Analgesic with Ambulatory Misuse Potential?"( ContextPrescriptions ) ) AmbulatoryOpioidPrescription
    where Routines."Is Subacute or Chronic Pain Prescription?"( AmbulatoryOpioidPrescription )

define "Patient Is Being Prescribed Opioid Analgesic with Ambulatory Misuse Potential":
  exists( "Chronic Pain Opioid Analgesic with Ambulatory Misuse Potential Prescriptions" )

define "PDMP Data Not Reviewed in Past 90 Days":
  Config."PDMP Data Not Reviewed in Past 90 Days Criteria Enabled"
    and not (
      exists (
        [Procedure: Common."PDMP review procedure"] P
          where P.status ~ 'completed'
            and P.performed during "Look Back 90 Days"
      )
      or exists (
        [Observation: Common."PDMP data reviewed finding"] O
          where O.status in { 'final', 'amended' }
            and (
              if O.effective is FHIR.Period
                then (O.effective as FHIR.Period) during day of "Look Back 90 Days"
                else if O.effective is FHIR.dateTime
                  then date from O.effective in day of "Look Back 90 Days"
                  else false
          )
      )
    )

define "Inclusion Criteria":
  "Patient Is Being Prescribed Opioid Analgesic with Ambulatory Misuse Potential"
    and Routines."Is Opioid Review Useful?"
    and "PDMP Data Not Reviewed in Past 90 Days"

define "Exclusion Criteria":
  false

define "Is Recommendation Applicable?":
  "Inclusion Criteria"
    and not "Exclusion Criteria"

define "Get Indicator":
  if "Is Recommendation Applicable?"
    then 'warning'
  else null

define "Get Summary":
  if "Is Recommendation Applicable?"
    then 'Notify: PDMP data for this patient has not been reviewed in the past 90 days.'
  else null

define "Get Detail":
  if "Is Recommendation Applicable?"
    then 'Review PDMP data for this patient before completing an opioid order

[Recommendation 9 of the 2022 CDC Clinical Practice Guideline provides guidance about utilizing PDMP information to improve patient safety](https://www.cdc.gov/mmwr/volumes/71/rr/rr7103a1.htm#:~:text=Clinicians%20should%20take,see%20Recommendation%2010).)

[CDC advises not to dismiss patients from your practice on the basis of PDMP information](https://www.cdc.gov/mmwr/volumes/71/rr/rr7103a1.htm#:~:text=Clinicians%20should%20not%20dismiss,Recommendations%208%20and%2012%5D).)'
  else null
Content: application/elm+xml
Encoded data (61640 characters)
Content: application/elm+json
Encoded data (111160 characters)