2022 CDC Clinical Practice Guideline for Prescribing Opioids Implementation Guide
2022.1.0 - CI Build

2022 CDC Clinical Practice Guideline for Prescribing Opioids Implementation Guide, published by Centers for Disease Control and Prevention (CDC). This guide is not an authorized publication; it is the continuous build for version 2022.1.0 built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/cqframework/opioid-cds-r4/ and changes regularly. See the Directory of published versions

Library: OpioidCDSREC03Library (Experimental)

Official URL: http://fhir.org/guides/cdc/opioid-cds/Library/OpioidCDSREC03 Version: 2022.1.0
Active as of 2024-05-28 Computable Name: OpioidCDSREC03
Id: OpioidCDSREC03
Url: Library - Recommendation #3 - Opioid Immediate Release Form When Starting Opioid Therapy
Version: 2022.1.0
Name: OpioidCDSREC03
Title: Library - Recommendation #3 - Opioid Immediate Release Form When Starting Opioid Therapy
Status: active
Experimental: true
Type:

system: LibraryType

code: logic-library

Date: 2024-05-28 16:37:24+0000
Publisher: Centers for Disease Control and Prevention (CDC)
Related Artifacts:

Dependencies

Parameters:
NameTypeMinMaxIn/Out
ContextPrescriptionsMedicationRequest01in
PatientPatient01out
Chronic Pain Extended Release Opioid Analgesic with Ambulatory Misuse Potential PrescriptionsMedicationRequest0*out
Patient Is Being Prescribed Extended Release Opioid Analgesic with Ambulatory Misuse Potentialboolean01out
Inclusion Criteriaboolean01out
Exclusion Criteriaboolean01out
Is Recommendation Applicable?boolean01out
Get Indicatorstring01out
Get Summarystring01out
Get Detailstring01out
Content: text/cql
library OpioidCDSREC03 version '2022.1.0'

using FHIR version '4.0.1'

include FHIRHelpers version '4.0.1' called FHIRHelpers
include OpioidCDSCommon version '2022.1.0' called Common
include OpioidCDSCommonConfig version '2022.1.0' called Config
include OpioidCDSRoutines version '2022.1.0' called Routines

/*
**  Recommendation #3
**    When starting opioid therapy for acute, subacute, or chronic pain, clinicians should 
**    prescribe immediate-release opioids instead of extended-release and long-acting (ER/LA) 
**    opioids (recommendation category: A; evidence type: 4).
**
**  When
**    Provider is prescribing an extended release opioid analgesic with ambulatory misuse potential in the outpatient setting
**    Opioid review is useful for this patient:
**      Patient is 18 or over
**      Patient does not have evidence of sickle cell disease
**      Patient does not have findings indicating limited life expectancy
**      Patient does not have orders for therapies indicating end of life care
**      Patient is not undergoing active cancer treatment:
**        Patient has had at least 2 office visits within the past 12 months with an oncology specialist present, or
**        Patient has had at least 2 office visits within the past 12 months with a CDC malignant cancer condition diagnosis
**      Patient does not have conditions likely terminal for opioid prescribing present
**    Patient is opioid naive:
**      No indication of opioid use in the past 90 days from a prescription, self report (for future implementation), or a dispensing event (for future implementation)
**  Then
**    When Initiating Opioid Therapy, Utilize Immediate Release Opioids:
**      Document - Will prescribe immediate release opioid
**      Snooze - Benefits outweigh risks, snooze 3 months
**      Snooze - N/A see comment, snooze 3 months
**
*/

// META: Plan Definition: http://fhir.org/guides/cdc/opioid-cds-r4/PlanDefinition/opioid-cds-03

parameter ContextPrescriptions List<MedicationRequest>

context Patient

define "Chronic Pain Extended Release Opioid Analgesic with Ambulatory Misuse Potential Prescriptions":
  ( Common."Is Opioid Analgesic with Ambulatory Misuse Potential?"( ContextPrescriptions ) ) AmbulatoryOpioidPrescription
    where Routines."Is Subacute or Chronic Pain Prescription?"( AmbulatoryOpioidPrescription )
      and AmbulatoryOpioidPrescription.medication in Common."Extended release opioid with ambulatory misuse potential"

define "Patient Is Being Prescribed Extended Release Opioid Analgesic with Ambulatory Misuse Potential":
  exists( "Chronic Pain Extended Release Opioid Analgesic with Ambulatory Misuse Potential Prescriptions" )

define "Inclusion Criteria":
  "Patient Is Being Prescribed Extended Release Opioid Analgesic with Ambulatory Misuse Potential"
      and Routines."Is Opioid Review Useful?"
      and Routines."Is Opioid Naive?"

define "Exclusion Criteria":
  Common."End of Life Assessment"

define "Is Recommendation Applicable?":
  "Inclusion Criteria"
    and not "Exclusion Criteria"

define "Get Indicator":
  if "Is Recommendation Applicable?"
    then 'warning'
  else null

define "Get Summary":
  if "Is Recommendation Applicable?"
    then 'When Initiating Opioid Therapy, Utilize Immediate Release Opioids'
  else null

define "Get Detail":
  if "Is Recommendation Applicable?"
    then 'Recommend prescribing immediate release opioids instead of extended release or long-acting opioids

[For guidance regarding prescribing extended release/ long-acting opioids, see Recommendation 3 of the 2022 CDC Clinical Practice Guideline](https://www.cdc.gov/mmwr/volumes/71/rr/rr7103a1.htm#:~:text=evidence%20type%3A%204).-,Implementation%20Considerations,to%20educate%20their%20patients%20about%20its%20use%20should%20consider%20prescribing%20it.,-Supporting%20Rationale)'
  else null
Content: application/elm+xml
Encoded data (27420 characters)
Content: application/elm+json
Encoded data (43600 characters)