Release 5 Preview #3
Orders and Observations Work GroupMaturity Level: N/AStandards Status: InformativeSecurity Category: Patient Compartments: Device, Patient, Practitioner, RelatedPerson

R3 : R4 Conversion maps for SupplyRequest.

Functional status for this map: 1 test that all execute ok. All tests pass round-trip testing and 1 r3 resources are invalid (0 errors). (see documentation)

map "http://hl7.org/fhir/StructureMap/SupplyRequest3to4" = "R3 to R4 Conversions for SupplyRequest"

uses "http://hl7.org/fhir/3.0/StructureDefinition/SupplyRequest" alias SupplyRequestR3 as source
uses "http://hl7.org/fhir/StructureDefinition/SupplyRequest" alias SupplyRequest as target

imports "http://hl7.org/fhir/StructureMap/*3to4"

group SupplyRequest(source src : SupplyRequestR3, target tgt : SupplyRequest) extends DomainResource <<type+>> {
  src.identifier -> tgt.identifier;
  src.status -> tgt.status;
  src.category -> tgt.category;
  src.priority -> tgt.priority;
  src.orderedItem as s then {
    s.item : CodeableConcept as vs -> tgt.item = create('CodeableConcept') as vt then CodeableConcept(vs, vt);
    s.item : Reference as vs -> tgt.item = create('Reference') as vt then Reference(vs, vt);
    s.quantity -> tgt.quantity;
  };
  src.occurrence : dateTime as vs -> tgt.occurrence = create('dateTime') as vt then dateTime(vs, vt);
  src.occurrence : Period as vs -> tgt.occurrence = create('Period') as vt then Period(vs, vt);
  src.occurrence : Timing as vs -> tgt.occurrence = create('Timing') as vt then Timing(vs, vt);
  src.authoredOn -> tgt.authoredOn;
  src.requester as vs0 -> tgt then agent(vs0, tgt);
  src.supplier -> tgt.supplier;
  src.reason : CodeableConcept as vs -> tgt.reasonCode as vt then CodeableConcept(vs, vt);
  src.reason : Reference as vs -> tgt.reasonReference as vt then Reference(vs, vt);
  src.deliverFrom -> tgt.deliverFrom;
  src.deliverTo -> tgt.deliverTo;
}

group agent(source src, target tgt) {
  src.agent -> tgt.requester;
  src.onBehalfOf as v ->  tgt.extension as vt,  vt.url = 'http://hl7.org/fhir/3.0/StructureDefinition/extension-SupplyRequest.requester.onBehalfOf',  vt.value = v;
}


map "http://hl7.org/fhir/StructureMap/SupplyRequest4to3" = "R4 to R3 Conversion for SupplyRequest"

uses "http://hl7.org/fhir/StructureDefinition/SupplyRequest" alias SupplyRequest as source
uses "http://hl7.org/fhir/3.0/StructureDefinition/SupplyRequest" alias SupplyRequestR3 as target

imports "http://hl7.org/fhir/StructureMap/*4to3"

group SupplyRequest(source src : SupplyRequest, target tgt : SupplyRequestR3) extends DomainResource <<type+>> {
  src.identifier -> tgt.identifier;
  src.status -> tgt.status;
  src.category -> tgt.category;
  src.priority -> tgt.priority;
  src.item : CodeableConcept as vs ->  tgt.orderedItem as t,  t.item = create('CodeableConcept') as vt then CodeableConcept(vs, vt);
  src.item : Reference as vs ->  tgt.orderedItem as t,  t.item = create('Reference') as vt then Reference(vs, vt);
  src.quantity as vs ->  tgt.orderedItem as t,  t.quantity as vt then Quantity(vs, vt);
  src.occurrence : dateTime as vs -> tgt.occurrence = create('dateTime') as vt then dateTime(vs, vt);
  src.occurrence : Period as vs -> tgt.occurrence = create('Period') as vt then Period(vs, vt);
  src.occurrence : Timing as vs -> tgt.occurrence = create('Timing') as vt then Timing(vs, vt);
  src.authoredOn -> tgt.authoredOn;
  src where requester.exists() or extension.where(url = 'http://hl7.org/fhir/3.0/StructureDefinition/extension-SupplyRequest.requester.onBehalfOf').exists() -> tgt.requester as vt0 then agent(src, vt0) "requester";
  src.supplier -> tgt.supplier;
  src.reasonCode as vs -> tgt.reason = create('CodeableConcept') as vt then CodeableConcept(vs, vt);
  src.reasonReference as vs -> tgt.reason = create('Reference') as vt then Reference(vs, vt);
  src.deliverFrom -> tgt.deliverFrom;
  src.deliverTo -> tgt.deliverTo;
}

group agent(source src, target tgt) {
  src.requester -> tgt.agent;
  src.extension as e where url = 'http://hl7.org/fhir/3.0/StructureDefinition/extension-SupplyRequest.requester.onBehalfOf' then {
    e.value -> tgt.onBehalfOf;
  };
}


<p>No validation errors - all conversions are clean</p>