Generated Narrative: StructureMap ExtractPrescriptionPad

/// url = 'https://fhir.slade360.co.ke/fhir/StructureMap/ExtractPrescriptionPad'
/// name = 'ExtractPrescriptionPad'
/// title = 'Prescription Extraction'
/// status = 'active'
/// description = 'One MedicationRequest per line written. The paper is five numbered lines with no dose, route or frequency column, so the whole line goes to medication.concept.text exactly as the prescriber wrote it. Nothing is parsed out of it: a guessed dose is the one error on this form that reaches the patient rather than a report, and the hospital\'s formulary is not coded, so an invented RxNorm or ATC code would be worse than none.'

uses "http://hl7.org/fhir/StructureDefinition/QuestionnaireResponse" alias QR as source
uses "http://hl7.org/fhir/StructureDefinition/Bundle" alias Bundle as target
uses "http://hl7.org/fhir/StructureDefinition/MedicationRequest" alias MedicationRequest as target

group ExtractPrescriptionPad(source qr : QR, target bundle : Bundle) {
  qr -> bundle.type = 'transaction' "setBundleType";
  qr.item as it where ((linkId = 'item') and item.where(linkId = 'item/text').answer.value.exists()) ->  bundle.entry as entry,  entry.resource = create('MedicationRequest') as mr then {
    qr ->  mr,  entry then BuildMedicationRequestBase(qr, mr, entry) "base";
    it -> mr.status = 'active' "status";
    it -> mr.intent = 'order' "intent";
    qr.encounter as e -> mr.encounter = e;
    qr.authored as t -> mr.authoredOn = t "authoredOn";
    it.item as l where (linkId = 'item/text') then {
      l.answer first as a then {
        a.value as txt ->  mr.medication as med,  med.concept as mc,  mc.text = txt "medicationText";
      };
    } "textRule";
    // The line also becomes the dosage instruction, because on this form the
    // line *is* the dosage instruction -- "Amoxicillin 500 mg tds x 5 days" is
    // one string on the paper and splitting it would invent structure.
    it.item as l where (linkId = 'item/text') then {
      l.answer first as a then {
        a.value as txt ->  mr.dosageInstruction as di,  di.text = txt "dosageText";
      };
    } "dosageRule";
    it.item as l where ((linkId = 'item/quantity') and answer.value.exists()) then {
      l.answer first as a then {
        a.value as txt ->  mr.dispenseRequest as dr,  dr.quantity = create('Quantity') as dq then {
          txt -> dq.unit = txt "quantityUnit";
        } "dispenseRequest";
      };
    } "quantityRule";
    qr.item as g where (linkId = 'prescription') then {
      g.item as p where ((linkId = 'prescription/prescriber') and answer.value.exists()) then {
        p.answer first as a then {
          a.value as ref -> mr.requester = ref "requester";
        };
      } "prescriberRule";
    } "prescriptionGroup";
    qr.item as it where (linkId = 'notes') then {
      it.answer first as a then {
        a.value as txt ->  mr.note as n,  n.text = txt "text";
      };
    } "note";
  } "prescribedItem";
}

// ─────────────────────────────────────────────────────────────────────────────
// Shared scaffolding. Repeated in each map rather than imported: the transform
// engine resolves `imports` against whatever StructureMaps happen to be on the
// server, and a form that stops extracting because a shared map was not
// uploaded is a worse failure than a duplicated group.
// Two notes on what the publisher's StructureMap validator says about this file.
// Source parameters below are left untyped on purpose. Writing `: Element` makes
// the validator compare QuestionnaireResponse.item against the literal 'Element'
// and report them as incompatible with each other, which is noise, not a finding.
// `evaluate(context, expression)` is flagged as "takes 1 parameter but 2 were
// found". Leave it. The FML parser in the same jar refuses the one-argument form
// outright -- it wants a parameter, a comma, then the FHIRPath -- so the
// publisher is objecting to what its own compiler emits. Two arguments is the
// only form that compiles, and it is what the R5 transform engine executes.
// ─────────────────────────────────────────────────────────────────────────────
group BuildObsBase(source qr : QR, target obs : Observation, target entry) {
  qr -> obs then SetResponseProvenance(qr, obs) "responseProvenance";
  qr -> obs.id = uuid() then SetObservationFullUrl(obs, entry) "idAndFullUrl";
  qr -> entry.request as request then {
    qr -> request.method = 'POST' "requestMethod";
    qr -> request.url = 'Observation' "requestUrl";
  } "entryRequest";
  qr -> obs.status = 'final' "status";
  qr.subject as s -> obs.subject = s;
  qr.encounter as e -> obs.encounter = e;
  qr.authored as t -> obs.effective = t "effective";
  qr.source as src -> obs.performer = src "performerFromSource";
  qr where (source.exists().not()) then {
    qr.author as a -> obs.performer = a "performerFromAuthor";
  } "performerFallback";
  // A stored response's id already reads "QuestionnaireResponse/<id>", so it is
  // a relative reference as it stands. The hasValue() guard is what stops an
  // unsaved response -- one posted straight to $extract rather than saved first
  // -- from writing "QuestionnaireResponse/null" into the record.
  qr.id as qid where ($this.hasValue()) ->  obs.derivedFrom = create('Reference') as ref,  ref.reference = qid "linkQuestionnaireResponse";
}

group SetObservationFullUrl(source obs : Observation, target entry) {
  obs.id as id -> entry.fullUrl = append('https://fhir.slade360.co.ke/fhir/Observation/', id) "assignFullUrl";
}

// The two answer shapes a component can carry. Both read the answer through the
// untyped `.value` accessor: reading `valueCoding` or `valueQuantity` by its
// typed property name fails at transform time on HAPI R5 with "Attempt to read
// invalid property ... on QuestionnaireResponse.item.answer".
group SetComponentCodedValue(source it, target comp) {
  it.answer first as a then {
    a.value as cv -> comp.value = create('CodeableConcept') as cc then {
      cv -> cc.coding = cv "valueCoding";
      cv.display as d -> cc.text = d "valueText";
    } "codedValue";
  } "componentAnswer";
}

group SetComponentValue(source it, target comp) {
  it.answer first as a then {
    a.value as v -> comp.value = v "plainValue";
  } "componentAnswer";
}

group BuildMedicationRequestBase(source qr : QR, target r : MedicationRequest, target entry) {
  qr -> r then SetResponseProvenance(qr, r) "responseProvenance";
  qr -> r.id = uuid() then SetMedicationRequestFullUrl(r, entry) "idAndFullUrl";
  qr -> entry.request as request then {
    qr -> request.method = 'POST' "requestMethod";
    qr -> request.url = 'MedicationRequest' "requestUrl";
  } "entryRequest";
  qr.subject as s -> r.subject = s;
}

group SetMedicationRequestFullUrl(source r : MedicationRequest, target entry) {
  r.id as id -> entry.fullUrl = append('https://fhir.slade360.co.ke/fhir/MedicationRequest/', id) "assignFullUrl";
}

// ── Provenance and tenancy ───────────────────────────────────────────────────
// Two tags on everything this map creates. The first says which questionnaire
// produced it, so a form that reopens mid-admission recalls its own earlier
// entries and not another form's. The second copies the tenant tags off the
// response, because nothing else on the path puts them there.
// The code is the form's document type, not the questionnaire's id: every
// environment mints its own ids, and there is only one set of maps, so an id
// here would tie the tag to whichever environment stamped it.
// ── Provenance and tenancy ───────────────────────────────────────────────────
group SetResponseProvenance(source qr : QR, target r) {
  qr -> r.meta as m then {
    qr -> m.tag as t then {
      qr -> t.system = 'http://slade360edi.com/questionnaire-provenance' "provenanceSystem";
      qr -> t.code = 'prescription-pad' "provenanceCode";
      qr -> t.display = 'Prescription' "provenanceDisplay";
    } "provenanceTag";
  } "provenanceMeta";
  // Every tag the response carries, onto the resource. `meta` is 0..1, so this
  // lands on the same meta the rule above created rather than a second one.
  qr.meta as qm then {
    qm.tag as qt ->  r.meta as m,  m.tag = qt "copyTag";
  } "tenantTags";
}