Generated Narrative: StructureMap ExtractIntakeOutputRecord

/// url = 'https://fhir.slade360.co.ke/fhir/StructureMap/ExtractIntakeOutputRecord'
/// name = 'ExtractIntakeOutputRecord'
/// title = 'Intake and Output Record Extraction'
/// status = 'active'
/// description = 'The 24-hour totals under LOINC 9108-2 fluid intake and 9192-6 urine output, plus the balance and each hourly row as its own pair of panels. The sheet\'s own instruction is to add the columns and circle the figure; the form computes it instead, because that circled number at the end of a twelve-hour shift is the most error-prone arithmetic on any ward chart -- and the hourly rows are still extracted so the total can be audited against them.'

uses "http://hl7.org/fhir/StructureDefinition/QuestionnaireResponse" alias QR as source
uses "http://hl7.org/fhir/StructureDefinition/Bundle" alias Bundle as target
uses "http://hl7.org/fhir/StructureDefinition/Observation" alias Observation as target

group ExtractIntakeOutputRecord(source qr : QR, target bundle : Bundle) {
  qr -> bundle.type = 'transaction' "setBundleType";
  qr.item as g where (linkId = 'totals') then {
    g.item as it where ((linkId = 'totals/intake') and answer.value.exists()) ->  bundle.entry as entry,  entry.resource = create('Observation') as obs then {
      qr ->  obs,  entry then BuildObsBase(qr, obs, entry) "base";
      qr -> obs then SetVitalSignsCategory(qr, obs) "category";
      it -> obs.code as cc then {
        it -> cc.coding as cg then {
          it -> cg.system = 'http://loinc.org' "sys";
          it -> cg.code = '9108-2' "cd";
          it -> cg.display = 'Fluid intake total 24 hour' "dsp";
        } "coding";
      } "code";
      it.answer first as a then {
        a.value as v -> obs.value = create('Quantity') as q then {
          v -> q.value = v "qValue";
          v -> q.unit = 'mL' "qUnit";
          v -> q.system = 'http://unitsofmeasure.org' "qSystem";
          v -> q.code = 'mL' "qCode";
        } "quantity";
      };
      it ->  obs.note as n,  n.text = 'Computed from the hourly rows rather than added by hand.' "note";
    } "measureq_9108_2";
    g.item as it where ((linkId = 'totals/output') and answer.value.exists()) ->  bundle.entry as entry,  entry.resource = create('Observation') as obs then {
      qr ->  obs,  entry then BuildObsBase(qr, obs, entry) "base";
      qr -> obs then SetVitalSignsCategory(qr, obs) "category";
      it -> obs.code as cc then {
        it -> cc.coding as cg then {
          it -> cg.system = 'https://fhir.slade360.co.ke/fhir/CodeSystem/concept-codesystem' "sys";
          it -> cg.code = 'fluid-balance-fluid-output-total-24-hours' "cd";
          it -> cg.display = 'Fluid output total 24 hours' "dsp";
        } "coding";
      } "code";
      it.answer first as a then {
        a.value as v -> obs.value = create('Quantity') as q then {
          v -> q.value = v "qValue";
          v -> q.unit = 'mL' "qUnit";
          v -> q.system = 'http://unitsofmeasure.org' "qSystem";
          v -> q.code = 'mL' "qCode";
        } "quantity";
      };
    } "measureq_fluid_balance";
    g.item as it where ((linkId = 'totals/balance') and answer.value.exists()) ->  bundle.entry as entry,  entry.resource = create('Observation') as obs then {
      qr ->  obs,  entry then BuildObsBase(qr, obs, entry) "base";
      qr -> obs then SetVitalSignsCategory(qr, obs) "category";
      it -> obs.code as cc then {
        it -> cc.coding as cg then {
          it -> cg.system = 'https://fhir.slade360.co.ke/fhir/CodeSystem/concept-codesystem' "sys";
          it -> cg.code = 'fluid-balance-over-24-hours' "cd";
          it -> cg.display = 'Fluid balance over 24 hours' "dsp";
        } "coding";
      } "code";
      it.answer first as a then {
        a.value as v -> obs.value = create('Quantity') as q then {
          v -> q.value = v "qValue";
          v -> q.unit = 'mL' "qUnit";
          v -> q.system = 'http://unitsofmeasure.org' "qSystem";
          v -> q.code = 'mL' "qCode";
        } "quantity";
      };
    } "measureq_fluid_balance2";
    g.item as it where ((linkId = 'totals/remarks') and answer.value.exists()) ->  bundle.entry as entry,  entry.resource = create('Observation') as obs then {
      qr ->  obs,  entry then BuildObsBase(qr, obs, entry) "base";
      qr -> obs then SetSurveyCategory(qr, obs) "category";
      it -> obs.code as cc then {
        it -> cc.coding as cg then {
          it -> cg.system = 'https://fhir.slade360.co.ke/fhir/CodeSystem/concept-codesystem' "sys";
          it -> cg.code = 'fluid-balance-remarks-on-the-intake-and-output-record' "cd";
          it -> cg.display = 'Remarks on the intake and output record' "dsp";
        } "coding";
      } "code";
      it.answer first as a then {
        a.value as txt ->  obs.note as n,  n.text = txt "text";
      };
    } "narr_fluid_balance_remarks_on_the_intake_and_output_record";
  } "totalsGroup";
  // The urine output on its own, under its own LOINC code and summed from the
  // rows. Urine output is what says whether a kidney is still working and it
  // is asked for on its own, not as half of a balance.
  qr where (item.where(linkId = 'hour').item.where(linkId = 'hour/output').item.where(linkId = 'hour/output/urine').answer.value.ofType(Quantity).exists()) ->  bundle.entry as entry,  entry.resource = create('Observation') as obs then {
    qr ->  obs,  entry then BuildObsBase(qr, obs, entry) "base";
    qr -> obs then SetVitalSignsCategory(qr, obs) "category";
    qr -> obs.code as cc then {
      qr -> cc.coding as cg then {
        qr -> cg.system = 'http://loinc.org' "sys";
        qr -> cg.code = '9192-6' "cd";
        qr -> cg.display = 'Urine output 24 hour' "dsp";
      } "coding";
    } "code";
    qr -> obs.value = create('Quantity') as q then {
      qr -> q.value = evaluate(qr, item.where(linkId = 'hour').item.where(linkId = 'hour/output').item.where(linkId = 'hour/output/urine').answer.value.ofType(Quantity).value.aggregate($this + $total, 0)) "qValue";
      qr -> q.unit = 'mL' "qUnit";
      qr -> q.system = 'http://unitsofmeasure.org' "qSystem";
      qr -> q.code = 'mL' "qCode";
    } "quantity";
    qr ->  obs.note as n,  n.text = 'Summed from the hourly rows on the intake and output record' "sumNote";
  } "urineOutputTotal";
  // ── One hourly row ──────────────────────────────────────────────────────
  qr.item as row where (linkId = 'hour') then {
    row.item as i where ((linkId = 'hour/intake') and item.answer.value.exists()) ->  bundle.entry as entry,  entry.resource = create('Observation') as obs then {
      qr ->  obs,  entry then BuildObsBase(qr, obs, entry) "base";
      qr -> obs then SetVitalSignsCategory(qr, obs) "category";
      i -> obs.code as cc then {
        i -> cc.coding as cg then {
          i -> cg.system = 'https://fhir.slade360.co.ke/fhir/CodeSystem/concept-codesystem' "sys";
          i -> cg.code = 'fluid-balance-hourly-fluid-intake' "cd";
          i -> cg.display = 'Hourly fluid intake' "dsp";
        } "coding";
      } "code";
      i.item as it where ((linkId = 'hour/intake/oral') and answer.value.exists()) -> obs.component as comp then {
        it -> comp.code as cc then {
          it -> cc.coding as cg then {
            it -> cg.system = 'https://fhir.slade360.co.ke/fhir/CodeSystem/concept-codesystem' "sys";
            it -> cg.code = 'fluid-balance-oral-fluid-volume' "cd";
            it -> cg.display = 'Oral fluid volume' "dsp";
          } "coding";
        } "code";
        it -> comp then SetComponentValue(it, comp) "value";
      } "comp_fluid_balance_oral_fluid_volume";
      i.item as it where ((linkId = 'hour/intake/iv-infusion-name') and answer.value.exists()) -> obs.component as comp then {
        it -> comp.code as cc then {
          it -> cc.coding as cg then {
            it -> cg.system = 'https://fhir.slade360.co.ke/fhir/CodeSystem/concept-codesystem' "sys";
            it -> cg.code = 'fluid-balance-iv-infusion-given' "cd";
            it -> cg.display = 'IV infusion given' "dsp";
          } "coding";
        } "code";
        it -> comp then SetComponentValue(it, comp) "value";
      } "comp_fluid_balance_iv_infusion_given";
      i.item as it where ((linkId = 'hour/intake/iv-amount') and answer.value.exists()) -> obs.component as comp then {
        it -> comp.code as cc then {
          it -> cc.coding as cg then {
            it -> cg.system = 'https://fhir.slade360.co.ke/fhir/CodeSystem/concept-codesystem' "sys";
            it -> cg.code = 'fluid-balance-iv-fluid-volume' "cd";
            it -> cg.display = 'IV fluid volume' "dsp";
          } "coding";
        } "code";
        it -> comp then SetComponentValue(it, comp) "value";
      } "comp_fluid_balance_iv_fluid_volume";
      i.item as it where ((linkId = 'hour/intake/ng-feeding') and answer.value.exists()) -> obs.component as comp then {
        it -> comp.code as cc then {
          it -> cc.coding as cg then {
            it -> cg.system = 'https://fhir.slade360.co.ke/fhir/CodeSystem/concept-codesystem' "sys";
            it -> cg.code = 'fluid-balance-nasogastric-feed-volume' "cd";
            it -> cg.display = 'Nasogastric feed volume' "dsp";
          } "coding";
        } "code";
        it -> comp then SetComponentValue(it, comp) "value";
      } "comp_fluid_balance_nasogastric_feed_volume";
      row -> obs then SetIoRowTime(row, obs) "rowTime";
    } "hourlyIntake";
    row.item as o where ((linkId = 'hour/output') and item.answer.value.exists()) ->  bundle.entry as entry,  entry.resource = create('Observation') as obs then {
      qr ->  obs,  entry then BuildObsBase(qr, obs, entry) "base";
      qr -> obs then SetVitalSignsCategory(qr, obs) "category";
      o -> obs.code as cc then {
        o -> cc.coding as cg then {
          o -> cg.system = 'https://fhir.slade360.co.ke/fhir/CodeSystem/concept-codesystem' "sys";
          o -> cg.code = 'fluid-balance-hourly-fluid-output' "cd";
          o -> cg.display = 'Hourly fluid output' "dsp";
        } "coding";
      } "code";
      o.item as it where ((linkId = 'hour/output/urine') and answer.value.exists()) -> obs.component as comp then {
        it -> comp.code as cc then {
          it -> cc.coding as cg then {
            it -> cg.system = 'https://fhir.slade360.co.ke/fhir/CodeSystem/concept-codesystem' "sys";
            it -> cg.code = 'fluid-balance-urine-volume' "cd";
            it -> cg.display = 'Urine volume' "dsp";
          } "coding";
        } "code";
        it -> comp then SetComponentValue(it, comp) "value";
      } "comp_fluid_balance_urine_volume";
      o.item as it where ((linkId = 'hour/output/stools') and answer.value.exists()) -> obs.component as comp then {
        it -> comp.code as cc then {
          it -> cc.coding as cg then {
            it -> cg.system = 'https://fhir.slade360.co.ke/fhir/CodeSystem/concept-codesystem' "sys";
            it -> cg.code = 'fluid-balance-stool-volume' "cd";
            it -> cg.display = 'Stool volume' "dsp";
          } "coding";
        } "code";
        it -> comp then SetComponentValue(it, comp) "value";
      } "comp_fluid_balance_stool_volume";
      o.item as it where ((linkId = 'hour/output/vomit') and answer.value.exists()) -> obs.component as comp then {
        it -> comp.code as cc then {
          it -> cc.coding as cg then {
            it -> cg.system = 'https://fhir.slade360.co.ke/fhir/CodeSystem/concept-codesystem' "sys";
            it -> cg.code = 'fluid-balance-vomit-volume' "cd";
            it -> cg.display = 'Vomit volume' "dsp";
          } "coding";
        } "code";
        it -> comp then SetComponentValue(it, comp) "value";
      } "comp_fluid_balance_vomit_volume";
      o.item as it where ((linkId = 'hour/output/ng-suction') and answer.value.exists()) -> obs.component as comp then {
        it -> comp.code as cc then {
          it -> cc.coding as cg then {
            it -> cg.system = 'https://fhir.slade360.co.ke/fhir/CodeSystem/concept-codesystem' "sys";
            it -> cg.code = 'fluid-balance-nasogastric-suction-volume' "cd";
            it -> cg.display = 'Nasogastric suction volume' "dsp";
          } "coding";
        } "code";
        it -> comp then SetComponentValue(it, comp) "value";
      } "comp_fluid_balance_nasogastric_suction_volume";
      o.item as it where ((linkId = 'hour/output/drainage') and answer.value.exists()) -> obs.component as comp then {
        it -> comp.code as cc then {
          it -> cc.coding as cg then {
            it -> cg.system = 'https://fhir.slade360.co.ke/fhir/CodeSystem/concept-codesystem' "sys";
            it -> cg.code = 'fluid-balance-drainage-volume' "cd";
            it -> cg.display = 'Drainage volume' "dsp";
          } "coding";
        } "code";
        it -> comp then SetComponentValue(it, comp) "value";
      } "comp_fluid_balance_drainage_volume";
      row -> obs then SetIoRowTime(row, obs) "rowTime";
    } "hourlyOutput";
  } "hourlyRows";
}

// A clock time, not a dateTime -- the sheet is one day per block with the date
// in its header -- so it rides as a note rather than being forced into
// Observation.effective as a bare time, which that element does not accept.
group SetIoRowTime(source row, target obs : Observation) {
  row.item as it where ((linkId = 'hour/time') and answer.value.exists()) then {
    it.answer first as a then {
      a.value as t ->  obs.note as n,  n.text = 'Recorded against the clock hour on the intake and output record' "timeNote";
    };
  } "rowTimeRule";
}

// ─────────────────────────────────────────────────────────────────────────────
// Shared scaffolding. Repeated in each map rather than imported: the transform
// engine resolves `imports` against whatever StructureMaps happen to be on the
// server, and a form that stops extracting because a shared map was not
// uploaded is a worse failure than a duplicated group.
// Two notes on what the publisher's StructureMap validator says about this file.
// Source parameters below are left untyped on purpose. Writing `: Element` makes
// the validator compare QuestionnaireResponse.item against the literal 'Element'
// and report them as incompatible with each other, which is noise, not a finding.
// `evaluate(context, expression)` is flagged as "takes 1 parameter but 2 were
// found". Leave it. The FML parser in the same jar refuses the one-argument form
// outright -- it wants a parameter, a comma, then the FHIRPath -- so the
// publisher is objecting to what its own compiler emits. Two arguments is the
// only form that compiles, and it is what the R5 transform engine executes.
// ─────────────────────────────────────────────────────────────────────────────
group BuildObsBase(source qr : QR, target obs : Observation, target entry) {
  qr -> obs then SetResponseProvenance(qr, obs) "responseProvenance";
  qr -> obs.id = uuid() then SetObservationFullUrl(obs, entry) "idAndFullUrl";
  qr -> entry.request as request then {
    qr -> request.method = 'POST' "requestMethod";
    qr -> request.url = 'Observation' "requestUrl";
  } "entryRequest";
  qr -> obs.status = 'final' "status";
  qr.subject as s -> obs.subject = s;
  qr.encounter as e -> obs.encounter = e;
  qr.authored as t -> obs.effective = t "effective";
  qr.source as src -> obs.performer = src "performerFromSource";
  qr where (source.exists().not()) then {
    qr.author as a -> obs.performer = a "performerFromAuthor";
  } "performerFallback";
  // A stored response's id already reads "QuestionnaireResponse/<id>", so it is
  // a relative reference as it stands. The hasValue() guard is what stops an
  // unsaved response -- one posted straight to $extract rather than saved first
  // -- from writing "QuestionnaireResponse/null" into the record.
  qr.id as qid where ($this.hasValue()) ->  obs.derivedFrom = create('Reference') as ref,  ref.reference = qid "linkQuestionnaireResponse";
}

group SetObservationFullUrl(source obs : Observation, target entry) {
  obs.id as id -> entry.fullUrl = append('https://fhir.slade360.co.ke/fhir/Observation/', id) "assignFullUrl";
}

// The two answer shapes a component can carry. Both read the answer through the
// untyped `.value` accessor: reading `valueCoding` or `valueQuantity` by its
// typed property name fails at transform time on HAPI R5 with "Attempt to read
// invalid property ... on QuestionnaireResponse.item.answer".
group SetComponentCodedValue(source it, target comp) {
  it.answer first as a then {
    a.value as cv -> comp.value = create('CodeableConcept') as cc then {
      cv -> cc.coding = cv "valueCoding";
      cv.display as d -> cc.text = d "valueText";
    } "codedValue";
  } "componentAnswer";
}

group SetComponentValue(source it, target comp) {
  it.answer first as a then {
    a.value as v -> comp.value = v "plainValue";
  } "componentAnswer";
}

group SetSurveyCategory(source qr : QR, target obs : Observation) {
  qr -> obs.category as cat then {
    qr -> cat.coding as coding then {
      qr -> coding.system = 'http://terminology.hl7.org/CodeSystem/observation-category' "categorySystem";
      qr -> coding.code = 'survey' "categoryCode";
      qr -> coding.display = 'Survey' "categoryDisplay";
    } "categoryCoding";
  } "category";
}

group SetVitalSignsCategory(source qr : QR, target obs : Observation) {
  qr -> obs.category as cat then {
    qr -> cat.coding as coding then {
      qr -> coding.system = 'http://terminology.hl7.org/CodeSystem/observation-category' "categorySystem";
      qr -> coding.code = 'vital-signs' "categoryCode";
      qr -> coding.display = 'Vital Signs' "categoryDisplay";
    } "categoryCoding";
  } "category";
}

// ── Provenance and tenancy ───────────────────────────────────────────────────
// Two tags on everything this map creates. The first says which questionnaire
// produced it, so a form that reopens mid-admission recalls its own earlier
// entries and not another form's. The second copies the tenant tags off the
// response, because nothing else on the path puts them there.
// The code is the form's document type, not the questionnaire's id: every
// environment mints its own ids, and there is only one set of maps, so an id
// here would tie the tag to whichever environment stamped it.
// ── Provenance and tenancy ───────────────────────────────────────────────────
group SetResponseProvenance(source qr : QR, target r) {
  qr -> r.meta as m then {
    qr -> m.tag as t then {
      qr -> t.system = 'http://slade360edi.com/questionnaire-provenance' "provenanceSystem";
      qr -> t.code = 'intake-output-record' "provenanceCode";
      qr -> t.display = 'Intake and output record' "provenanceDisplay";
    } "provenanceTag";
  } "provenanceMeta";
  // Every tag the response carries, onto the resource. `meta` is 0..1, so this
  // lands on the same meta the rule above created rather than a second one.
  qr.meta as qm then {
    qm.tag as qt ->  r.meta as m,  m.tag = qt "copyTag";
  } "tenantTags";
}