define "Initial Population":
  AgeInYearsAt(date from 
    end of "Measurement Period"
  ) = 2
    and exists ( "Qualifying Encounters" )

define "Initial Population":
  AgeInYearsAt(date from 
    end of "Measurement Period"
  ) = 2
    and exists ( "Qualifying Encounters" )

define "Denominator":
  "Initial Population"

define "Denominator Exclusions":
  Hospice."Has Hospice Services"
    or "Has Severe Combined Immunodeficiency"
    or "Has Immunodeficiency"
    or "Has HIV"
    or "Has Lymphoreticular Cancer, Multiple Myeloma or Leukemia"
    or "Has Intussusception"

define "Numerator":
  ( exists ( "Four DTaP Vaccinations" )
      or exists ( "DTaP Numerator Inclusion Conditions" )
  )
    and ( exists ( "Three Polio Vaccinations" )
        or exists ( "Polio Numerator Inclusion Conditions" )
    )
    and ( exists ( "One MMR Vaccination" )
        or exists ( "MMR Numerator Inclusion Conditions" )
        or ( exists ( "Measles Indicators" )
            and exists ( "Mumps Indicators" )
            and exists ( "Rubella Indicators" )
        )
    )
    and ( "Has Appropriate Number of Hib Immunizations"
        or exists ( "Hib Numerator Inclusion Conditions" )
    )
    and ( exists ( "Three Hepatitis B Vaccinations" )
        or ( exists ( "Meets HepB Vaccination Requirement" )
            or exists ( "Hepatitis B Numerator Inclusion Conditions" )
        )
    )
    and ( exists ( "One Chicken Pox Vaccination" )
        or exists ( "Varicella Zoster Numerator Inclusion Conditions" )
    )
    and ( exists ( "Four Pneumococcal Conjugate Vaccinations" )
        or exists ( "Pneumococcal Conjugate Numerator Inclusion Conditions" )
    )
    and ( exists ( "One Hepatitis A Vaccinations" )
        or exists ( "Hepatitis A Numerator Inclusion Conditions" )
    )
    and ( "Has Appropriate Number of Rotavirus Immunizations"
        or exists ( "Rotavirus Numerator Inclusion Conditions" )
    )
    and ( exists ( "Two Influenza Vaccinations" )
        or ( "Two Influenza Vaccinations Including One LAIV Vaccination" )
        or exists ( "Influenza Numerator Inclusion Conditions" )
    )

define "Has Hospice Services":
  exists ((([Encounter: "Encounter Inpatient"]).isEncounterPerformed()) InpatientEncounter
      where (InpatientEncounter.hospitalization.dischargeDisposition ~ "Discharge to home for hospice care (procedure)"
          or InpatientEncounter.hospitalization.dischargeDisposition ~ "Discharge to healthcare facility for hospice care (procedure)"
      )
        and InpatientEncounter.period.toInterval() ends during day of "Measurement Period"
  )
    or exists ((([Encounter: "Hospice Encounter"]).isEncounterPerformed()) HospiceEncounter
        where HospiceEncounter.period.toInterval() overlaps day of "Measurement Period"
    )
    or exists ((([ObservationScreeningAssessment: "Hospice care [Minimum Data Set]"]).isAssessmentPerformed()) HospiceAssessment
        where HospiceAssessment.value ~ "Yes (qualifier value)"
          and HospiceAssessment.effective.toInterval() overlaps day of "Measurement Period"
    )
    or exists ((([ServiceRequest: "Hospice Care Ambulatory"]).isInterventionOrder()) HospiceOrder
        where HospiceOrder.authoredOn.toInterval() during day of "Measurement Period"
    )
    or exists ((([Procedure: "Hospice Care Ambulatory"]).isInterventionPerformed()) HospicePerformed
        where HospicePerformed.performed.toInterval() overlaps day of "Measurement Period"
    )
    or exists ((([ConditionProblemsHealthConcerns: "Hospice Diagnosis"])
        union ([ConditionEncounterDiagnosis: "Hospice Diagnosis"])) HospiceCareDiagnosis
        where HospiceCareDiagnosis.prevalenceInterval() overlaps day of "Measurement Period"
    )

define "SDE Sex":
  case
    when Patient.sex = '248153007' then "Male (finding)"
    when Patient.sex = '248152002' then "Female (finding)"
    else null
  end

define "SDE Payer":
  [Coverage: type in "Payer Type"] Payer
    return {
      code: Payer.type,
      period: Payer.period
    }

define "SDE Ethnicity":
  Patient.ethnicity E
    return Tuple {
      codes: { E.ombCategory } union E.detailed,
      display: E.text
    }

define "SDE Race":
  Patient.race R
    return Tuple {
      codes: R.ombCategory union R.detailed,
      display: R.text
    }

define "SDE Sex":
  SDE."SDE Sex"

define "Date of Second Birthday":
  Patient.birthDate + 2 years

define "Vaccine Administration Interval - 42 Days up to 2 Years Old":
  Interval[date from Patient.birthDate + 42 days, "Date of Second Birthday"]

define "DTaP Immunizations or Procedures":
  ( ( ( [Immunization: "DTaP Vaccine"] ).isImmunizationAdministered ( ) ) DTaPVaccination
      where date from DTaPVaccination.occurrence.earliest ( ) during day of "Vaccine Administration Interval - 42 Days up to 2 Years Old"
      return date from DTaPVaccination.occurrence.earliest ( )
  )
    union ( ( ( [Procedure: "DTaP Vaccine Administered"] ).isProcedurePerformed ( ) ) DTaPProcedure
        where date from DTaPProcedure.performed.earliest ( ) during day of "Vaccine Administration Interval - 42 Days up to 2 Years Old"
        return date from DTaPProcedure.performed.earliest ( )
    )

//DTaP


define "Four DTaP Vaccinations":
  from
    "DTaP Immunizations or Procedures" DTaPVaccination1,
    "DTaP Immunizations or Procedures" DTaPVaccination2,
    "DTaP Immunizations or Procedures" DTaPVaccination3,
    "DTaP Immunizations or Procedures" DTaPVaccination4
    where date from DTaPVaccination2.earliest ( ) 1 day or more after day of date from DTaPVaccination1.earliest ( )
      and date from DTaPVaccination3.earliest ( ) 1 day or more after day of DTaPVaccination2.earliest ( )
      and date from DTaPVaccination4.earliest ( ) 1 day or more after day of DTaPVaccination3.earliest ( )
    return all DTaPVaccination1

define "First Two Years":
  Interval[date from Patient.birthDate, "Date of Second Birthday"]

define "DTaP Numerator Inclusion Conditions":
  ( ( [ConditionEncounterDiagnosis: "Anaphylactic Reaction to DTaP Vaccine"]
      union [ConditionProblemsHealthConcerns: "Anaphylactic Reaction to DTaP Vaccine"]
      union [ConditionEncounterDiagnosis: "Encephalitis Due to Diphtheria, Tetanus or Pertussis Vaccine"]
      union [ConditionProblemsHealthConcerns: "Encephalitis Due to Diphtheria, Tetanus or Pertussis Vaccine"]
  ) ) DTaPConditions
    where date from start of DTaPConditions.prevalenceInterval ( ) during day of "First Two Years"

//Polio


define "Polio Immunizations or Procedures":
  ( ( ( [Immunization: "Inactivated Polio Vaccine (IPV)"] ).isImmunizationAdministered ( ) ) PolioVaccination
      where date from PolioVaccination.occurrence.earliest ( ) during day of "Vaccine Administration Interval - 42 Days up to 2 Years Old"
      return date from PolioVaccination.occurrence.earliest ( )
  )
    union ( ( ( [Procedure: "Inactivated Polio Vaccine (IPV) Administered"] ).isProcedurePerformed ( ) ) PolioProcedure
        where date from PolioProcedure.performed.earliest ( ) during day of "Vaccine Administration Interval - 42 Days up to 2 Years Old"
        return date from PolioProcedure.performed.earliest ( )
    )

define "Three Polio Vaccinations":
  from
    "Polio Immunizations or Procedures" PolioVaccination1,
    "Polio Immunizations or Procedures" PolioVaccination2,
    "Polio Immunizations or Procedures" PolioVaccination3
    where date from PolioVaccination2.earliest ( ) 1 day or more after date from PolioVaccination1.earliest ( )
      and date from PolioVaccination3.earliest ( ) 1 day or more after date from PolioVaccination2.earliest ( )
    return date from PolioVaccination1.earliest ( )

define "Polio Numerator Inclusion Conditions":
  ( [ConditionEncounterDiagnosis: "Anaphylaxis caused by vaccine product containing human poliovirus antigen (disorder)"]
    union [ConditionProblemsHealthConcerns: "Anaphylaxis caused by vaccine product containing human poliovirus antigen (disorder)"] ) PolioConditions
    where date from start of PolioConditions.prevalenceInterval ( ) during day of "First Two Years"

define "Date of First Birthday":
  date from Patient.birthDate + 1 year

define "Date of First Birthday to Date of Second Birthday":
  Interval["Date of First Birthday", "Date of Second Birthday"]

//MMR


define "One MMR Vaccination":
  ( ( ( [Immunization: "Measles, Mumps and Rubella (MMR) Vaccine"] ).isImmunizationAdministered ( ) ) MMRVaccination
      where date from MMRVaccination.occurrence.earliest ( ) during "Date of First Birthday to Date of Second Birthday"
      return date from MMRVaccination.occurrence.earliest ( )
  )
    union ( ( ( [Procedure: "Measles, Mumps and Rubella (MMR) Vaccine Administered"] ).isProcedurePerformed ( ) ) MMRProcedure
        where date from MMRProcedure.performed.earliest ( ) during "Date of First Birthday to Date of Second Birthday"
        return date from MMRProcedure.performed.earliest ( )
    )

define "MMR Numerator Inclusion Conditions":
  ( [ConditionEncounterDiagnosis: "Anaphylaxis caused by vaccine product containing Measles morbillivirus and Mumps orthorubulavirus and Rubella virus antigens (disorder)"]
    union [ConditionProblemsHealthConcerns: "Anaphylaxis caused by vaccine product containing Measles morbillivirus and Mumps orthorubulavirus and Rubella virus antigens (disorder)"] ) MMRConditions
    where date from start of MMRConditions.prevalenceInterval ( ) during day of "First Two Years"

define "Measles Indicators":
  ( [ConditionEncounterDiagnosis: "Measles"]
    union [ConditionEncounterDiagnosis: "Measles"] ) MeaslesDiagnosis
    where date from start of MeaslesDiagnosis.prevalenceInterval ( ) during day of "First Two Years"

define "Mumps Indicators":
  ( [ConditionEncounterDiagnosis: "Mumps"]
    union [ConditionProblemsHealthConcerns: "Mumps"] ) MumpsDiagnosis
    where date from start of MumpsDiagnosis.prevalenceInterval ( ) during day of "First Two Years"

define "Rubella Indicators":
  ( [ConditionEncounterDiagnosis: "Rubella"]
    union [ConditionProblemsHealthConcerns: "Rubella"] ) RubellaDiagnosis
    where date from start of RubellaDiagnosis.prevalenceInterval ( ) during day of "First Two Years"

define "Hib 3 Dose Immunizations or Procedures":
  ( ( ( [Immunization: "Hib Vaccine (3 dose schedule)"] ).isImmunizationAdministered ( ) ) ThreeDoseHibVaccine
      where date from ThreeDoseHibVaccine.occurrence.earliest ( ) during day of "Vaccine Administration Interval - 42 Days up to 2 Years Old"
      return date from ThreeDoseHibVaccine.occurrence.earliest ( )
  )
    union ( ( ( [Procedure: "Hib Vaccine (3 dose schedule) Administered"] ).isProcedurePerformed ( ) ) ThreeDoseHibProcedure
        where date from ThreeDoseHibProcedure.performed.earliest ( ) during day of "Vaccine Administration Interval - 42 Days up to 2 Years Old"
        return date from ThreeDoseHibProcedure.performed.earliest ( )
    )

define "Hib 4 Dose Immunizations or Procedures":
  ( ( ( [Immunization: "Hib Vaccine (4 dose schedule)"] ).isImmunizationAdministered ( ) ) HibVaccine
      where date from HibVaccine.occurrence.earliest ( ) during day of "Vaccine Administration Interval - 42 Days up to 2 Years Old"
      return date from HibVaccine.occurrence.earliest ( )
  )
    union ( ( ( [Procedure: "Hib Vaccine (4 dose schedule) Administered"] ).isProcedurePerformed ( ) ) HibProcedure
        where date from HibProcedure.performed.earliest ( ) during day of "Vaccine Administration Interval - 42 Days up to 2 Years Old"
        return date from HibProcedure.performed.earliest ( )
    )

define "Hib 3 or 4 Dose Immunizations":
  "Hib 3 Dose Immunizations or Procedures"
    union "Hib 4 Dose Immunizations or Procedures"

//HiB


define "Has Appropriate Number of Hib Immunizations":
  exists ( "Hib 3 or 4 Dose Immunizations" HibImmunization //4 dose test
      
      let HasFourDose: Count("Hib 4 Dose Immunizations or Procedures") > 0
      where ( HasFourDose //if pt had at least one 4 dose code
          
          and Count(distinct("Hib 3 or 4 Dose Immunizations" HibVaccinations
                return date from HibVaccinations.earliest()
            )
          ) >= 4 //pt must have 4 regimens (e.g., 3,3,4,4 or 4,3,4,4)
      
      )
        or ( HasFourDose is false //if pt did not have at least one 4 dose code
            
            and Count(distinct("Hib 3 or 4 Dose Immunizations" HibVaccinations
                  return date from HibVaccinations.earliest()
              )
            ) >= 3 //pt must have 3 regimens of 3 dose codes
        
        )
  )

define "Hib Numerator Inclusion Conditions":
  ( [ConditionEncounterDiagnosis: "Anaphylaxis caused by vaccine product containing only Haemophilus influenzae type b antigen (disorder)"]
    union [ConditionProblemsHealthConcerns: "Anaphylaxis caused by vaccine product containing only Haemophilus influenzae type b antigen (disorder)"] ) HibReaction
    where date from start of HibReaction.prevalenceInterval ( ) during day of "First Two Years"

define "Hepatitis B Immunizations or Procedures":
  ( ( ( [Immunization: "Hepatitis B Vaccine"] ).isImmunizationAdministered ( ) ) HepatitisBVaccination
      where date from HepatitisBVaccination.occurrence.earliest ( ) during day of "First Two Years"
      return date from HepatitisBVaccination.occurrence.earliest ( )
  )
    union ( ( ( [Procedure: "Hepatitis B Vaccine Administered"] ).isProcedurePerformed ( ) ) HepatitisBProcedure
        where date from HepatitisBProcedure.performed.earliest ( ) during day of "First Two Years"
        return date from HepatitisBProcedure.performed.earliest ( )
    )

define "Three Hepatitis B Vaccinations":
  from
    "Hepatitis B Immunizations or Procedures" HepatitisBVaccination1,
    "Hepatitis B Immunizations or Procedures" HepatitisBVaccination2,
    "Hepatitis B Immunizations or Procedures" HepatitisBVaccination3
    where date from HepatitisBVaccination2.earliest ( ) 1 day or more after date from HepatitisBVaccination1.earliest ( )
      and date from HepatitisBVaccination3.earliest ( ) 1 day or more after date from HepatitisBVaccination2.earliest ( )
    return date from HepatitisBVaccination1.earliest ( )

define "NewBorn Vaccine Requirement":
  ( ( [Procedure: "Introduction of Serum, Toxoid and Vaccine into Muscle, Percutaneous Approach"] ).isProcedurePerformed ( ) ) NewBornVaccine
    where date from NewBornVaccine.performed.earliest ( ) during day of Interval[date from Patient.birthDate, date from Patient.birthDate + 7 days]
    return date from NewBornVaccine.performed.earliest ( )

define "Meets HepB Vaccination Requirement":
  from
    "Hepatitis B Immunizations or Procedures" HepatitisBVaccination1,
    "Hepatitis B Immunizations or Procedures" HepatitisBVaccination2,
    "NewBorn Vaccine Requirement" NewBornVaccine3
    where date from HepatitisBVaccination2.earliest ( ) 1 day or more after date from HepatitisBVaccination1.earliest ( )
      and date from HepatitisBVaccination1.earliest ( ) 1 day or more after date from NewBornVaccine3.earliest ( )
      and date from HepatitisBVaccination2.earliest ( ) 1 day or more after date from NewBornVaccine3.earliest ( )
    return date from HepatitisBVaccination1.earliest ( )

//HepB


define "Hepatitis B Numerator Inclusion Conditions":
  ( [ConditionEncounterDiagnosis: "Anaphylaxis caused by vaccine product containing Hepatitis B virus antigen (disorder)"]
    union [ConditionProblemsHealthConcerns: "Anaphylaxis caused by vaccine product containing Hepatitis B virus antigen (disorder)"]
    union [ConditionEncounterDiagnosis: "Hepatitis B"]
    union [ConditionProblemsHealthConcerns: "Hepatitis B"] ) HepBConditions
    where date from start of HepBConditions.prevalenceInterval ( ) during day of "First Two Years"

//VZV


define "One Chicken Pox Vaccination":
  ( ( ( [Immunization: "Varicella Zoster Vaccine (VZV)"] ).isImmunizationAdministered ( ) ) ChickenPoxVaccination
      where date from ChickenPoxVaccination.occurrence.earliest ( ) during "Date of First Birthday to Date of Second Birthday"
      return date from ChickenPoxVaccination.occurrence.earliest ( )
  )
    union ( ( ( [Procedure: "Varicella Zoster Vaccine (VZV) Administered"] ).isProcedurePerformed ( ) ) ChickenPoxProcedure
        where date from ChickenPoxProcedure.performed.earliest ( ) during "Date of First Birthday to Date of Second Birthday"
        return date from ChickenPoxProcedure.performed.earliest ( )
    )

define "Varicella Zoster Numerator Inclusion Conditions":
  ( ( [ConditionEncounterDiagnosis: "Varicella Zoster"]
      union [ConditionProblemsHealthConcerns: "Varicella Zoster"]
      union [ConditionEncounterDiagnosis: "Anaphylaxis caused by vaccine containing Human alphaherpesvirus 3 antigen (disorder)"]
      union [ConditionProblemsHealthConcerns: "Anaphylaxis caused by vaccine containing Human alphaherpesvirus 3 antigen (disorder)"]
  ) ) VaricellaZoster
    where date from start of VaricellaZoster.prevalenceInterval ( ) during day of "First Two Years"

define "Pneumococcal Conjugate Immunizations or Procedures":
  ( ( ( [Immunization: "Pneumococcal Conjugate Vaccine"] ).isImmunizationAdministered ( ) ) PneumococcalVaccination
      where date from PneumococcalVaccination.occurrence.earliest ( ) during day of "Vaccine Administration Interval - 42 Days up to 2 Years Old"
      return date from PneumococcalVaccination.occurrence.earliest ( )
  )
    union ( ( ( [Procedure: "Pneumococcal Conjugate Vaccine Administered"] ).isProcedurePerformed ( ) ) PneumococcalProcedure
        where date from PneumococcalProcedure.performed.earliest ( ) during day of "Vaccine Administration Interval - 42 Days up to 2 Years Old"
        return date from PneumococcalProcedure.performed.earliest ( )
    )

//PCV


define "Four Pneumococcal Conjugate Vaccinations":
  from
    "Pneumococcal Conjugate Immunizations or Procedures" PneumococcalVaccination1,
    "Pneumococcal Conjugate Immunizations or Procedures" PneumococcalVaccination2,
    "Pneumococcal Conjugate Immunizations or Procedures" PneumococcalVaccination3,
    "Pneumococcal Conjugate Immunizations or Procedures" PneumococcalVaccination4
    where date from PneumococcalVaccination2.earliest ( ) 1 day or more after date from PneumococcalVaccination1.earliest ( )
      and date from PneumococcalVaccination3.earliest ( ) 1 day or more after date from PneumococcalVaccination2.earliest ( )
      and date from PneumococcalVaccination4.earliest ( ) 1 day or more after date from PneumococcalVaccination3.earliest ( )
    return date from PneumococcalVaccination1.earliest ( )

define "Pneumococcal Conjugate Numerator Inclusion Conditions":
  ( [ConditionEncounterDiagnosis: "Anaphylaxis caused by vaccine product containing Streptococcus pneumoniae antigen (disorder)"]
    union [ConditionProblemsHealthConcerns: "Anaphylaxis caused by vaccine product containing Streptococcus pneumoniae antigen (disorder)"] ) PneumococcalReaction
    where date from start of PneumococcalReaction.prevalenceInterval ( ) during day of "First Two Years"

//HepA


define "One Hepatitis A Vaccinations":
  ( ( ( [Immunization: "Hepatitis A Vaccine"] ).isImmunizationAdministered ( ) ) HepatitisAVaccination
      where date from HepatitisAVaccination.occurrence.earliest ( ) during "Date of First Birthday to Date of Second Birthday"
      return date from HepatitisAVaccination.occurrence.earliest ( )
  )
    union ( ( ( [Procedure: "Hepatitis A Vaccine Administered"] ).isProcedurePerformed ( ) ) HepatitisAProcedure
        where date from HepatitisAProcedure.performed.earliest ( ) during "Date of First Birthday to Date of Second Birthday"
        return date from HepatitisAProcedure.performed.earliest ( )
    )

define "Hepatitis A Numerator Inclusion Conditions":
  ( [ConditionEncounterDiagnosis: "Hepatitis A"]
    union [ConditionProblemsHealthConcerns: "Hepatitis A"]
    union [ConditionEncounterDiagnosis: "Anaphylaxis caused by vaccine product containing Hepatitis A virus antigen (disorder)"]
    union [ConditionProblemsHealthConcerns: "Anaphylaxis caused by vaccine product containing Hepatitis A virus antigen (disorder)"] ) HepatitisADiagnosis
    where date from start of HepatitisADiagnosis.prevalenceInterval ( ) during day of "First Two Years"

define "Rotavirus 2 Dose Immunizations or Procedures":
  ( ( ( [Immunization: "rotavirus, live, monovalent vaccine"] ).isImmunizationAdministered ( ) ) TwoDoseRotavirusVaccine
      where date from TwoDoseRotavirusVaccine.occurrence.earliest ( ) during day of "Vaccine Administration Interval - 42 Days up to 2 Years Old"
      return date from TwoDoseRotavirusVaccine.occurrence.earliest ( )
  )
    union ( ( ( [Procedure: "Rotavirus Vaccine (2 dose schedule) Administered"] ).isProcedurePerformed ( ) ) TwoDoseRotavirusProcedure
        where date from TwoDoseRotavirusProcedure.performed.earliest ( ) during day of "Vaccine Administration Interval - 42 Days up to 2 Years Old"
        return date from TwoDoseRotavirusProcedure.performed.earliest ( )
    )

define "Rotavirus 3 Dose Immunizations or Procedures":
  ( ( ( [Immunization: "Rotavirus Vaccine (3 dose schedule)"] ).isImmunizationAdministered ( ) ) ThreeDoseRotavirusVaccine
      where date from ThreeDoseRotavirusVaccine.occurrence.earliest ( ) during day of "Vaccine Administration Interval - 42 Days up to 2 Years Old"
      return date from ThreeDoseRotavirusVaccine.occurrence.earliest ( )
  )
    union ( ( ( [Procedure: "Rotavirus Vaccine (3 dose schedule) Administered"] ).isProcedurePerformed ( ) ) ThreeDoseRotavirusAdministered
        where date from ThreeDoseRotavirusAdministered.performed.earliest ( ) during day of "Vaccine Administration Interval - 42 Days up to 2 Years Old"
        return date from ThreeDoseRotavirusAdministered.performed.earliest ( )
    )

define "Rotavirus 2 or 3 Dose Immunizations":
  "Rotavirus 2 Dose Immunizations or Procedures"
    union "Rotavirus 3 Dose Immunizations or Procedures"

//RV


define "Has Appropriate Number of Rotavirus Immunizations":
  exists ( "Rotavirus 2 or 3 Dose Immunizations" RotavirusImmunization
      let HasThreeDose: Count("Rotavirus 3 Dose Immunizations or Procedures") > 0
      where ( HasThreeDose
          and Count(distinct("Rotavirus 2 or 3 Dose Immunizations" RotavirusVaccinations
                return date from RotavirusVaccinations.earliest()
            )
          ) >= 3
      )
        or ( HasThreeDose is false
            and Count(distinct("Rotavirus 2 or 3 Dose Immunizations" RotavirusVaccinations
                  return date from RotavirusVaccinations.earliest()
              )
            ) >= 2
        )
  )

define "Rotavirus Numerator Inclusion Conditions":
  ( [ConditionEncounterDiagnosis: "Anaphylaxis due to rotavirus vaccine (disorder)"]
    union [ConditionProblemsHealthConcerns: "Anaphylaxis due to rotavirus vaccine (disorder)"] ) RotavirusConditions
    where date from start of RotavirusConditions.prevalenceInterval ( ) during day of "First Two Years"

define "Vaccine Administration Interval - 180 Days up to 2 Years Old":
  Interval[date from Patient.birthDate + 180 days, "Date of Second Birthday"]

//Flu


define "Influenza Immunizations or Procedures":
  ( ( ( [Immunization: "Child Influenza Vaccine"] ).isImmunizationAdministered ( ) ) InfluenzaVaccine
      where date from InfluenzaVaccine.occurrence.earliest ( ) during day of "Vaccine Administration Interval - 42 Days up to 2 Years Old"
      return date from InfluenzaVaccine.occurrence.earliest ( )
  )
    union ( ( ( [Procedure: "Child Influenza Vaccine Administered"] ).isProcedurePerformed ( ) ) InfluenzaAdministration
        where date from InfluenzaAdministration.performed.earliest ( ) during day of "Vaccine Administration Interval - 180 Days up to 2 Years Old"
        return date from InfluenzaAdministration.performed.earliest ( )
    )

define "Two Influenza Vaccinations":
  from
    "Influenza Immunizations or Procedures" FluVaccination1,
    "Influenza Immunizations or Procedures" FluVaccination2
    where date from FluVaccination2.earliest ( ) 1 day or more after date from FluVaccination1.earliest ( )
    return date from FluVaccination1.earliest ( )

define "LAIV Vaccinations":
  ( ( ( [Immunization: "Influenza Virus LAIV Vaccine"] ).isImmunizationAdministered ( ) ) LAIVVaccine
      where date from LAIVVaccine.occurrence.earliest ( ) during day of Interval["Date of Second Birthday", "Date of Second Birthday"]
      return date from LAIVVaccine.occurrence.earliest ( )
  )
    union ( ( ( [Procedure: "Influenza Virus LAIV Vaccine Administered"] ).isProcedurePerformed ( ) ) InfluenzaAdministration
        where date from InfluenzaAdministration.performed.earliest ( ) during day of Interval["Date of Second Birthday", "Date of Second Birthday"]
        return date from InfluenzaAdministration.performed.earliest ( )
    )

define "Two Influenza Vaccinations Including One LAIV Vaccination":
  exists "LAIV Vaccinations"
    and exists "Influenza Immunizations or Procedures"

define "Influenza Numerator Inclusion Conditions":
  ( [ConditionEncounterDiagnosis: "Anaphylaxis caused by vaccine product containing Influenza virus antigen (disorder)"]
    union [ConditionProblemsHealthConcerns: "Anaphylaxis caused by vaccine product containing Influenza virus antigen (disorder)"] ) InfluenzaConditions
    where date from start of InfluenzaConditions.prevalenceInterval ( ) during day of "First Two Years"

define "Numerator":
  ( exists ( "Four DTaP Vaccinations" )
      or exists ( "DTaP Numerator Inclusion Conditions" )
  )
    and ( exists ( "Three Polio Vaccinations" )
        or exists ( "Polio Numerator Inclusion Conditions" )
    )
    and ( exists ( "One MMR Vaccination" )
        or exists ( "MMR Numerator Inclusion Conditions" )
        or ( exists ( "Measles Indicators" )
            and exists ( "Mumps Indicators" )
            and exists ( "Rubella Indicators" )
        )
    )
    and ( "Has Appropriate Number of Hib Immunizations"
        or exists ( "Hib Numerator Inclusion Conditions" )
    )
    and ( exists ( "Three Hepatitis B Vaccinations" )
        or ( exists ( "Meets HepB Vaccination Requirement" )
            or exists ( "Hepatitis B Numerator Inclusion Conditions" )
        )
    )
    and ( exists ( "One Chicken Pox Vaccination" )
        or exists ( "Varicella Zoster Numerator Inclusion Conditions" )
    )
    and ( exists ( "Four Pneumococcal Conjugate Vaccinations" )
        or exists ( "Pneumococcal Conjugate Numerator Inclusion Conditions" )
    )
    and ( exists ( "One Hepatitis A Vaccinations" )
        or exists ( "Hepatitis A Numerator Inclusion Conditions" )
    )
    and ( "Has Appropriate Number of Rotavirus Immunizations"
        or exists ( "Rotavirus Numerator Inclusion Conditions" )
    )
    and ( exists ( "Two Influenza Vaccinations" )
        or ( "Two Influenza Vaccinations Including One LAIV Vaccination" )
        or exists ( "Influenza Numerator Inclusion Conditions" )
    )

define "Qualifying Encounters":
  ( ( [Encounter: "Office Visit"]
      union [Encounter: "Home Healthcare Services"]
      union [Encounter: "Preventive Care, Established Office Visit, 0 to 17"]
      union [Encounter: "Preventive Care Services, Initial Office Visit, 0 to 17"]
      union ( [Encounter] E
          where exists ( ( E.type ) T
              where T ~ "Office or other outpatient visit for the evaluation and management of an established patient that may not require the presence of a physician or other qualified health care professional"
          )
      )
      union [Encounter: "Virtual Encounter"]
      union [Encounter: "Telephone Visits"]
  ).isEncounterPerformed ( ) ) ValidEncounters
    where ValidEncounters.period.toInterval ( ) during day of "Measurement Period"

define "Initial Population":
  AgeInYearsAt(date from 
    end of "Measurement Period"
  ) = 2
    and exists ( "Qualifying Encounters" )

define "Denominator":
  "Initial Population"

define "SDE Payer":
  SDE."SDE Payer"

define "Initial Population":
  AgeInYearsAt(date from 
    end of "Measurement Period"
  ) = 2
    and exists ( "Qualifying Encounters" )

define "SDE Ethnicity":
  SDE."SDE Ethnicity"

define "Has Severe Combined Immunodeficiency":
  exists ( ( [ConditionEncounterDiagnosis: "Severe Combined Immunodeficiency"]
      union [ConditionProblemsHealthConcerns: "Severe Combined Immunodeficiency"] ) SevereImmuneDisorder
      where date from start of SevereImmuneDisorder.prevalenceInterval ( ) during day of "First Two Years"
  )

define "Has Immunodeficiency":
  exists ( ( [ConditionEncounterDiagnosis: "Disorders of the Immune System"]
      union [ConditionProblemsHealthConcerns: "Disorders of the Immune System"] ) ImmuneDisorder
      where date from start of ImmuneDisorder.prevalenceInterval ( ) during day of "First Two Years"
  )

define "Has HIV":
  exists ( ( [ConditionEncounterDiagnosis: "HIV"]
      union [ConditionProblemsHealthConcerns: "HIV"] ) HIVDiagnosis
      where date from start of HIVDiagnosis.prevalenceInterval ( ) during day of "First Two Years"
  )

define "Has Lymphoreticular Cancer, Multiple Myeloma or Leukemia":
  exists ( ( [ConditionEncounterDiagnosis: "Malignant Neoplasm of Lymphatic and Hematopoietic Tissue"]
      union [ConditionProblemsHealthConcerns: "Malignant Neoplasm of Lymphatic and Hematopoietic Tissue"] ) LymphaticMalignantNeoplasm
      where date from start of LymphaticMalignantNeoplasm.prevalenceInterval ( ) during day of "First Two Years"
  )

define "Has Intussusception":
  exists ( ( [ConditionEncounterDiagnosis: "Intussusception"]
      union [ConditionProblemsHealthConcerns: "Intussusception"] ) IntussusceptionDisorder
      where date from start of IntussusceptionDisorder.prevalenceInterval ( ) during day of "First Two Years"
  )

define "Denominator Exclusions":
  Hospice."Has Hospice Services"
    or "Has Severe Combined Immunodeficiency"
    or "Has Immunodeficiency"
    or "Has HIV"
    or "Has Lymphoreticular Cancer, Multiple Myeloma or Leukemia"
    or "Has Intussusception"

define "SDE Race":
  SDE."SDE Race"

/*
@description: Given an interval, return the starting point if the interval has a starting boundary specified,
otherwise, return the ending point
*/
define fluent function earliest(choice Choice<DateTime, Quantity, Interval<DateTime>, Interval<Quantity>> ):
  (choice.toInterval()) period
    return
      if (period."hasStart"()) then start of period
      else end of period

/*
@description: Given an interval, return true if the interval has a starting boundary specified
(i.e. the start of the interval is not null and not the minimum DateTime value)
*/
define fluent function hasStart(period Interval<DateTime> ):
  not ( start of period is null
      or start of period = minimum DateTime
  )

/*
@description: Returns an interval representing the normalized prevalence period of a given Condition.
@comment: Uses the ToInterval and ToAbatementInterval functions to determine the widest potential interval from
onset to abatement as specified in the given Condition. If the condition is active, or has an abatement date the resulting 
interval will have a closed ending boundary. Otherwise, the resulting interval will have an open ending boundary.
*/
define fluent function prevalenceInterval(condition Choice<"ConditionEncounterDiagnosis", "ConditionProblemsHealthConcerns">):
if condition.clinicalStatus ~ "active"
  or condition.clinicalStatus ~ "recurrence"
  or condition.clinicalStatus ~ "relapse" then
  Interval[start of condition.onset.toInterval(), end of condition.abatementInterval()]
else
    (end of condition.abatementInterval()) abatementDate
    return if abatementDate is null then
      Interval[start of condition.onset.toInterval(), abatementDate)
    else
      Interval[start of condition.onset.toInterval(), abatementDate]

/*
@description: Returns an interval representing the normalized abatement of a given Condition.
@comment: If the abatement element of the Condition is represented as a DateTime, the result
is an interval beginning and ending on that DateTime.
If the abatement is represented as a Quantity, the quantity is expected to be a calendar-duration and is interpreted as the age of the patient. The
result is an interval from the date the patient turned that age to immediately before one year later.
If the abatement is represented as a Quantity Interval, the quantities are expected to be calendar-durations and are interpreted as an age range during
which the abatement occurred. The result is an interval from the date the patient turned the starting age of the quantity interval, and ending immediately
before one year later than the date the patient turned the ending age of the quantity interval.
*/
define fluent function abatementInterval(condition Choice<"ConditionEncounterDiagnosis", "ConditionProblemsHealthConcerns">):
	if condition.abatement is DateTime then
	  Interval[condition.abatement as DateTime, condition.abatement as DateTime]
	else if condition.abatement is Quantity then
		Interval[Patient.birthDate + (condition.abatement as Quantity),
			Patient.birthDate + (condition.abatement as Quantity) + 1 year)
	else if condition.abatement is Interval<Quantity> then
	  Interval[Patient.birthDate + (condition.abatement.low as Quantity),
		  Patient.birthDate + (condition.abatement.high as Quantity) + 1 year)
	else if condition.abatement is Interval<DateTime> then
	  Interval[condition.abatement.low, condition.abatement.high)
	else null as Interval<DateTime>

/*
@description: Normalizes a value that is a choice of timing-valued types to an equivalent interval
@comment: Normalizes a choice type of DateTime, Quanitty, Interval<DateTime>, or Interval<Quantity> types
to an equivalent interval. This selection of choice types is a superset of the majority of choice types that are used as possible
representations for timing-valued elements in QICore, allowing this function to be used across any resource.
The input can be provided as a DateTime, Quantity, Interval<DateTime> or Interval<Quantity>.
The intent of this function is to provide a clear and concise mechanism to treat single
elements that have multiple possible representations as intervals so that logic doesn't have to account
for the variability. More complex calculations (such as medication request period or dispense period
calculation) need specific guidance and consideration. That guidance may make use of this function, but
the focus of this function is on single element calculations where the semantics are unambiguous.
If the input is a DateTime, the result a DateTime Interval beginning and ending on that DateTime.
If the input is a Quantity, the quantity is expected to be a calendar-duration interpreted as an Age,
and the result is a DateTime Interval beginning on the Date the patient turned that age and ending immediately before one year later.
If the input is a DateTime Interval, the result is the input.
If the input is a Quantity Interval, the quantities are expected to be calendar-durations interpreted as an Age, and the result
is a DateTime Interval beginning on the date the patient turned the age given as the start of the quantity interval, and ending
immediately before one year later than the date the patient turned the age given as the end of the quantity interval.
If the input is a Timing, an error will be thrown indicating that Timing calculations are not implemented. Any other input will reslt in a null DateTime Interval
*/
define fluent function toInterval(choice Choice<DateTime, Quantity, Interval<DateTime>, Interval<Quantity>, Timing>):
  case
	  when choice is DateTime then
    	Interval[choice as DateTime, choice as DateTime]
		when choice is Interval<DateTime> then
  		choice as Interval<DateTime>
		when choice is Quantity then
		  Interval[Patient.birthDate + (choice as Quantity),
			  Patient.birthDate + (choice as Quantity) + 1 year)
		when choice is Interval<Quantity> then
		  Interval[Patient.birthDate + (choice.low as Quantity),
			  Patient.birthDate + (choice.high as Quantity) + 1 year)
		when choice is Timing then
      Message(null, true, 'NOT_IMPLEMENTED', 'Error', 'Calculation of an interval from a Timing value is not supported') as Interval<DateTime>
		else
			null as Interval<DateTime>
	end

define function ToString(value uri): value.value

/*
@description: Converts the given FHIR [CodeableConcept](https://hl7.org/fhir/datatypes.html#CodeableConcept) value to a CQL Concept.
*/
define function ToConcept(concept FHIR.CodeableConcept):
    if concept is null then
        null
    else
        System.Concept {
            codes: concept.coding C return ToCode(C),
            display: concept.text.value
        }

/*
@description: Converts the given FHIR [Coding](https://hl7.org/fhir/datatypes.html#Coding) value to a CQL Code.
*/
define function ToCode(coding FHIR.Coding):
    if coding is null then
        null
    else
        System.Code {
          code: coding.code.value,
          system: coding.system.value,
          version: coding.version.value,
          display: coding.display.value
        }

/*
@description: Converts the given [Period](https://hl7.org/fhir/datatypes.html#Period)
value to a CQL DateTime Interval
@comment: If the start value of the given period is unspecified, the starting
boundary of the resulting interval will be open (meaning the start of the interval
is unknown, as opposed to interpreted as the beginning of time).
*/
define function ToInterval(period FHIR.Period):
    if period is null then
        null
    else
        if period."start" is null then
            Interval(period."start".value, period."end".value]
        else
            Interval[period."start".value, period."end".value]

//Immunization, Administered
define fluent function isImmunizationAdministered(Immunization List<Immunization>):
  Immunization I
    where I.status ~ 'completed'

//Procedure, Performed
define fluent function isProcedurePerformed(Proc List<Procedure>):
  Proc P
    where P.status ~ 'completed'

//Encounter, Performed
//General usage unless required otherwise by measure intent (e.g., follow-up encounters)
define fluent function isEncounterPerformed(Enc List<Encounter>):
  Enc E
    where E.status in {'finished', 'arrived', 'triaged', 'in-progress', 'onleave'}

//This library contains functions used to constrain FHIR resource elements for measures authored by NCQA, based on QICore 6.0.0 resources including IG and authoring patterns. The functions may appear similar to some QICoreCommon functions but differ in that they have constraints that are relevant for measures authored by NCQA.

//Assessment, Performed
define fluent function isAssessmentPerformed(Obs List<ObservationScreeningAssessment>):
  Obs O
    where O.status in { 'final', 'amended', 'corrected' }

//Intervention, Order
define fluent function isInterventionOrder(ServiceRequest List<ServiceRequest>):
  ServiceRequest S
    where S.status in { 'active', 'completed' }
      and S.intent = 'order'

//Intervention, Performed
define fluent function isInterventionPerformed(Proc List<Procedure>):
  Proc P
    where P.status ~ 'completed'