eCQM QICore Content Implementation Guide
2025.0.0 - CI Build

eCQM QICore Content Implementation Guide, published by cqframework. This guide is not an authorized publication; it is the continuous build for version 2025.0.0 built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/cqframework/ecqm-content-qicore-2025/ and changes regularly. See the Directory of published versions

Library: CMS1056CTClinicalFHIR

Official URL: https://madie.cms.gov/Library/CMS1056CTClinicalFHIR Version: 0.6.000
Active as of 2025-04-18 Responsible: Alara Imaging, Inc. Computable Name: CMS1056CTClinicalFHIR
Other Identifiers: https://madie.cms.gov/login#CMS1056CTClinicalFHIR (use: official, )

CMS1056CTClinicalFHIR

Title: CMS1056CTClinicalFHIR
Id: CMS1056CTClinicalFHIR
Version: 0.6.000
Url: https://madie.cms.gov/Library/CMS1056CTClinicalFHIR
official

CMS1056CTClinicalFHIR

Type:

system: http://terminology.hl7.org/CodeSystem/library-type

code: logic-library

Date: 2025-04-18T13:49:26+00:00
Publisher: Alara Imaging, Inc.
Description: CMS1056CTClinicalFHIR
Related Artifacts:

Dependencies

  • https://madie.cms.gov/Library/SupplementalDataElements|5.1.000
  • https://madie.cms.gov/Library/QICoreCommon|4.0.000
  • https://madie.cms.gov/Library/FHIRHelpers|4.4.000
  • https://madie.cms.gov/Library/AlaraCommonFunctions|1.6.000
  • http://loinc.org
Data Requirements:
TypeProfileMSCode Filter
Patient http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-patient ;;
Observation http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-observation-lab ;;;; code filter:
path: code

system: http://loinc.org

code: 96914-7

display: CT dose and image quality category

Coverage http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-coverage ;; code filter:
path: type
value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.3591
Content: text/cql
library CMS1056CTClinicalFHIR version '0.6.000'

using QICore version '6.0.0'

include FHIRHelpers version '4.4.000' called FHIRHelpers
include CQMCommon version '4.0.000' called CQMCommon
include QICoreCommon version '4.0.000' called QICoreCommon
include SupplementalDataElements version '5.1.000' called SDE
include AlaraCommonFunctions version '1.6.000' called AlaraCommon

codesystem "LOINC": 'http://loinc.org'

code "Birth date": '21112-8' from "LOINC" display 'Birth date'
code "CT dose and image quality category": '96914-7' from "LOINC" display 'CT dose and image quality category'
code "Full Body": 'LA31771-1' from "LOINC" display 'Full Body'

parameter "Measurement Period" Interval<DateTime>

context Patient

define "SDE Ethnicity":
  SDE."SDE Ethnicity"

define "SDE Payer":
  SDE."SDE Payer"

define "SDE Race":
  SDE."SDE Race"

define "SDE Sex":
  SDE."SDE Sex"

define "Patients with Qualifying CTScan":
  [LaboratoryResultObservation: "CT dose and image quality category"] CTScanResult
    where QICoreCommon.ToInterval ( CTScanResult.effective ) ends during day of "Measurement Period"
      and ( AgeInYearsAt(start of "Measurement Period") >= 18 )

define "Patients with Qualifying CTScan with Values":
  "Patients with Qualifying CTScan" CTScan
    where AlaraCommon."Global Noise Value" ( CTScan ) is not null
      and AlaraCommon."Size Adjusted Value" ( CTScan ) is not null
      and CTScan.value is not null

define "Initial Population":
  exists ( "Patients with Qualifying CTScan" )

define "Denominator":
  exists ( "Patients with Qualifying CTScan with Values" )

define "Denominator Exclusion":
  exists ( "Patients with Qualifying CTScan with Values" CTScan
      where ( CTScan.value as Concept ).codes contains "Full Body"
  )

define "Numerator":
  exists ( "Patients with Qualifying CTScan with Values" CTScan
      where AlaraCommon."CT Scan Qualifies" ( CTScan )
  )