eCQM QICore Content Implementation Guide
2025.0.0 - CI Build

eCQM QICore Content Implementation Guide, published by cqframework. This guide is not an authorized publication; it is the continuous build for version 2025.0.0 built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/cqframework/ecqm-content-qicore-2025/ and changes regularly. See the Directory of published versions

Library: Antibiotic

Official URL: https://madie.cms.gov/Library/Antibiotic Version: 1.9.000
Active as of 2025-04-15 Responsible: National Committee for Quality Assurance Computable Name: Antibiotic
Other Identifiers: https://madie.cms.gov/login#67fd69295291b0360f7fbac8 (use: official, )

This library contains functions used to exclude patients with a history of comorbid conditions, competing diagnoses, or antibiotic medications.

Title: Antibiotic
Id: Antibiotic
Version: 1.9.000
Url: https://madie.cms.gov/Library/Antibiotic
official

67fd69295291b0360f7fbac8

Type:

system: http://terminology.hl7.org/CodeSystem/library-type

code: logic-library

Date: 2025-04-15T20:44:04+00:00
Publisher: National Committee for Quality Assurance
Description: This library contains functions used to exclude patients with a history of comorbid conditions, competing diagnoses, or antibiotic medications.
Related Artifacts:

Dependencies

  • https://madie.cms.gov/Library/QICoreCommon|4.0.000
  • https://madie.cms.gov/Library/FHIRHelpers|4.4.000
  • https://madie.cms.gov/Library/CumulativeMedicationDuration|6.0.000
Content: text/cql
library Antibiotic version '1.9.000'

using QICore version '6.0.0'

include FHIRHelpers version '4.4.000' called FHIRHelpers
include QICoreCommon version '4.0.000' called QICoreCommon
include CumulativeMedicationDuration version '6.0.000' called CMD

parameter "Measurement Period" Interval<DateTime>

context Patient

define function "Has Comorbid Condition History"(episodeDate List<Encounter>, comorbidConditions List<ConditionEncounterDiagnosis>):
  episodeDate eDate
      with comorbidConditions comcondition
        such that date from start of comcondition.prevalenceInterval() during Interval[date from start of eDate.period.toInterval() - 1 year, date from start of eDate.period.toInterval()]
      return eDate

define function "Has Competing Diagnosis History"(episodeDate List<Encounter>, competingConditions List<ConditionEncounterDiagnosis>):
  episodeDate eDate
      with competingConditions competcondition
        such that competcondition.prevalenceInterval() starts 3 days or less on or after day of start of eDate.period
      return eDate

define function "Has Antibiotic Medication History"(episodeDate List<Encounter>, antibioticMedications List<MedicationRequest>):
   episodeDate DateOfEpisode
    with antibioticMedications ActiveMedication
      such that ActiveMedication.medicationRequestPeriod() overlaps day of Interval[date from start of DateOfEpisode.period.toInterval()  - 30 days, date from start of DateOfEpisode.period.toInterval() - 1 day]