eCQM QICore Content Implementation Guide
2024.0.0 - CI Build

eCQM QICore Content Implementation Guide, published by cqframework. This guide is not an authorized publication; it is the continuous build for version 2024.0.0 built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/cqframework/ecqm-content-qicore-2024/ and changes regularly. See the Directory of published versions

Library: CMS1074AlaraCTIQRFHIR

Official URL: https://madie.cms.gov/Library/CMS1074AlaraCTIQRFHIR Version: 0.4.003
Active as of 2025-01-03 Responsible: Alara Imaging, Inc. Computable Name: CMS1074AlaraCTIQRFHIR
Other Identifiers: https://madie.cms.gov/login#CMS1074AlaraCTIQRFHIR (use: official, )

CMS1074AlaraCTIQRFHIR

Title: CMS1074AlaraCTIQRFHIR
Id: CMS1074AlaraCTIQRFHIR
Version: 0.4.003
Url: https://madie.cms.gov/Library/CMS1074AlaraCTIQRFHIR
official

CMS1074AlaraCTIQRFHIR

Type:

system: http://terminology.hl7.org/CodeSystem/library-type

code: logic-library

Date: 2025-01-03T18:14:26+00:00
Publisher: Alara Imaging, Inc.
Description: CMS1074AlaraCTIQRFHIR
Related Artifacts:

Dependencies

  • http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.666.5.307
  • http://loinc.org
  • https://madie.cms.gov/Library/AlaraCommonFunctions|1.5.000
  • https://madie.cms.gov/Library/CQMCommon|2.2.000
  • https://madie.cms.gov/Library/FHIRHelpers|4.4.000
  • https://madie.cms.gov/Library/QICoreCommon|2.1.000
  • https://madie.cms.gov/Library/SupplementalDataElements|3.5.000
Data Requirements:
TypeProfileMSCode Filter
Patient http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-patient ;;;;
Coverage http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-coverage ;; code filter:
path: type
value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.3591
Content: text/cql
library CMS1074AlaraCTIQRFHIR version '0.4.003'

using QICore version '4.1.1'

include FHIRHelpers version '4.4.000' called FHIRHelpers
include CQMCommon version '2.2.000' called CQMCommon
include QICoreCommon version '2.1.000' called QICoreCommon
include SupplementalDataElements version '3.5.000' called SDE
include AlaraCommonFunctions version '1.5.000' called AlaraCommon

codesystem "LOINC": 'http://loinc.org'

valueset "Encounter Inpatient": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.666.5.307'

code "CT dose and image quality category": '96914-7' from "LOINC" display 'CT dose and image quality category'
code "Full Body": 'LA31771-1' from "LOINC" display 'Full Body'

parameter "Measurement Period" Interval<DateTime>

context Patient

define "Qualifying Inpatient Encounters":
  ["Encounter": "Encounter Inpatient"] InpatientEncounter
    where InpatientEncounter.period overlaps "Measurement Period"
      and AgeInYearsAt(date from start of "Measurement Period") >= 18

define "SDE Ethnicity":
  SDE."SDE Ethnicity"

define "SDE Payer":
  SDE."SDE Payer"

define "SDE Race":
  SDE."SDE Race"

define "SDE Sex":
  SDE."SDE Sex"

define "Numerator":
  "Qualifying Scan with Values" CTScan
    where AlaraCommon."CT Scan Qualifies" ( CTScan )

define "Initial Population":
  "Qualifying Scan During Inpatient Encounter"

define "Denominator":
  "Qualifying Scan with Values"

define "Denominator Exclusion":
  "Qualifying Scan with Values" CTScan
    where ( CTScan.value as Concept ).codes contains "Full Body"

define "Qualifying Scan with Values":
  "Qualifying Scan During Inpatient Encounter" CTScan
    where AlaraCommon."Global Noise Value" ( CTScan ) is not null
      and AlaraCommon."Size Adjusted Value" ( CTScan ) is not null
      and CTScan.value is not null

define "Qualifying Scan During Inpatient Encounter":
  [Observation: "CT dose and image quality category"] CTScan
    with "Qualifying Inpatient Encounters" InpatientEncounters
      such that QICoreCommon.ToInterval ( CTScan.effective ) starts during InpatientEncounters.period
        and QICoreCommon.ToInterval ( CTScan.effective ) ends during day of "Measurement Period"