Draft dQM CMS Content Implementation Guide
2025.1.0 - CI Build

Draft dQM CMS Content Implementation Guide, published by cqframework. This guide is not an authorized publication; it is the continuous build for version 2025.1.0 built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/cqframework/dqm-content-cms-2025/ and changes regularly. See the Directory of published versions

## Library: CMS135FHIRACEIorARBorARNIforHF

Official URL: https://madie.cms.gov/Library/CMS135FHIRACEIorARBorARNIforHF | Version: 1.1.000
Active as of 2025-08-22 | Responsible: American Heart Association | Computable Name: CMS135FHIRACEIorARBorARNIforHF
Other Identifiers: https://madie.cms.gov/login#CMS135FHIRACEIorARBorARNIforHF (use: official, )

CMS135FHIRACEIorARBorARNIforHF

Metadata
Title | CMS135FHIRACEIorARBorARNIforHF
Version | 1.1.000
Identifier | CMS135FHIRACEIorARBorARNIforHF
Topic | FHIR
Topic | CQL
Steward (Publisher) | American Heart Association
Description | CMS135FHIRACEIorARBorARNIforHF
Type | logic-library from http://terminology.hl7.org/CodeSystem/library-type
Dependency | Description: Model USQualityCore Resource: `https://madie.cms.gov/Library/USQualityCore-ModelInfo|0.1.0-cibuild` Canonical URL: `https://madie.cms.gov/Library/USQualityCore-ModelInfo|0.1.0-cibuild`
Dependency | Description: Library FHIRHelpers Resource: http://hl7.org/fhir/uv/cql/Library/FHIRHelpers|4.0.1 Canonical URL: `http://hl7.org/fhir/uv/cql/Library/FHIRHelpers|4.0.1`
Dependency | Description: Library FHIRCommon Resource: http://hl7.org/fhir/uv/cql/Library/FHIRCommon|2.0.0 Canonical URL: `http://hl7.org/fhir/uv/cql/Library/FHIRCommon|2.0.0`
Dependency | Description: Library USCoreCommon Resource: http://hl7.org/fhir/us/cql/Library/USCoreCommon|2.0.0-ballot Canonical URL: `http://hl7.org/fhir/us/cql/Library/USCoreCommon|2.0.0-ballot`
Dependency | Description: Library USCoreElements Resource: http://hl7.org/fhir/us/cql/Library/USCoreElements|2.0.0-ballot Canonical URL: `http://hl7.org/fhir/us/cql/Library/USCoreElements|2.0.0-ballot`
Dependency | Description: Library USQualityCoreCommon Resource: US Quality Core Commonversion: null0.1.0-cibuild) Canonical URL: `https://madie.cms.gov/Library/USQualityCoreCommon|0.1.0-cibuild`
Dependency | Description: Library SDE Resource: SupplementalDataElementsversion: null6.1.000) Canonical URL: `https://madie.cms.gov/Library/SupplementalDataElements|6.1.000`
Dependency | Description: Library AHA Resource: AHAOverallversion: null5.1.000) Canonical URL: `https://madie.cms.gov/Library/AHAOverall|5.1.000`
Dependency | Description: Code System SNOMEDCT Resource: SNOMED CT (all versions) Canonical URL: `http://snomed.info/sct`
Dependency | Description: Value Set ACE Inhibitor or ARB or ARNI Ingredient Resource: ACE Inhibitor or ARB or ARNI Ingredient Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.526.3.1489`
Dependency | Description: Value Set ACE Inhibitor or ARB or ARNI Resource: ACE Inhibitor or ARB or ARNI Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.526.3.1139`
Dependency | Description: Value Set Allergy to ACE Inhibitor or ARB Resource: Allergy to ACE Inhibitor or ARB Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.526.3.1211`
Dependency | Description: Value Set Intolerance to ACE Inhibitor or ARB Resource: Intolerance to ACE Inhibitor or ARB Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.526.3.1212`
Dependency | Description: Value Set Medical Reason Resource: Medical Reason Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.526.3.1007`
Dependency | Description: Value Set Patient Reason Resource: Patient Reason Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.526.3.1008`
Dependency | Description: Value Set Patient Reason for ACE Inhibitor or ARB Decline Resource: Patient Reason for ACE Inhibitor or ARB Decline Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.526.3.1140`
Dependency | Description: Value Set Pregnancy Resource: Pregnancy Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.526.3.378`
Data Requirement | Type: MedicationRequest Profile(s): MedicationRequest Code Filter(s): Path: medication ValueSet: ACE Inhibitor or ARB or ARNI
Data Requirement | Type: MedicationRequest Profile(s): `http://fhir.org/guides/astp/us-quality-core/StructureDefinition/us-quality-core-medicationnotrequested` Code Filter(s): Path: medication ValueSet: ACE Inhibitor or ARB or ARNI
Data Requirement | Type: AllergyIntolerance Profile(s): AllergyIntolerance Code Filter(s): Path: code ValueSet: ACE Inhibitor or ARB or ARNI Ingredient
Data Requirement | Type: AllergyIntolerance Profile(s): AllergyIntolerance Code Filter(s): Path: code Code(s): SNOMED CT: 372733002 (Substance with angiotensin-converting enzyme inhibitor mechanism of action (substance))
Data Requirement | Type: AllergyIntolerance Profile(s): AllergyIntolerance Code Filter(s): Path: code Code(s): SNOMED CT: 372913009 (Substance with angiotensin II receptor antagonist mechanism of action (substance))
Data Requirement | Type: AllergyIntolerance Profile(s): AllergyIntolerance Code Filter(s): Path: code Code(s): SNOMED CT: 786886009 (Substance with neprilysin inhibitor mechanism of action (substance))
Data Requirement | Type: Condition Profile(s): Condition Code Filter(s): Path: code ValueSet: Allergy to ACE Inhibitor or ARB
Data Requirement | Type: Condition Profile(s): Condition Code Filter(s): Path: code ValueSet: Intolerance to ACE Inhibitor or ARB
Data Requirement | Type: Condition Profile(s): Condition Code Filter(s): Path: code ValueSet: Pregnancy
Data Requirement | Type: Observation Profile(s): US Core Observation Pregnancy Status Profile
Data Requirement | Type: Condition Profile(s): Condition Code Filter(s): Path: code Code(s): SNOMED CT: 422593004 (Acute renal failure caused by angiotensin-converting-enzyme inhibitor (disorder))
Parameters
Name | Use | Card. | Type | Documentation
Measurement Period | In | 0..1 | Period |
Patient | Out | 0..1 | Resource |
Initial Population | Out | 0..1 | boolean |
Denominator | Out | 0..1 | boolean |
Denominator Exclusions | Out | 0..1 | boolean |
Has ACEI or ARB or ARNI Ordered | Out | 0..1 | boolean |
Is Currently Taking ACEI or ARB or ARNI | Out | 0..1 | boolean |
Numerator | Out | 0..1 | boolean |
Has Medical or Patient Reason for Not Ordering ACEI or ARB or ARNI | Out | 0..1 | boolean |
Has Allergy or Intolerance to ACEI or ARB or ARNI Ingredient | Out | 0..1 | boolean |
Has Diagnosis of Allergy or Intolerance to ACEI or ARB | Out | 0..1 | boolean |
Has Diagnosis of Pregnancy | Out | 0..1 | boolean |
Has Diagnosis of Renal Failure Due to ACEI | Out | 0..1 | boolean |
Denominator Exceptions | Out | 0..1 | boolean |
SDE Ethnicity | Out | 0..1 | Resource |
SDE Payer | Out | 0..* | Resource |
SDE Race | Out | 0..1 | Resource |
SDE Sex | Out | 0..1 | Coding |
Library Content
CQL Content |
    /*
    NOTE: For use by March 2026 US Realm Connectathon participants for internal use only. Not for use or distribution in commercial products.
    */
    library CMS135FHIRACEIorARBorARNIforHF version '1.1.000'

    using USQualityCore version '0.1.0-cibuild'
    using USCore version '6.1.0-derived'
    using FHIR version '4.0.1'

    include hl7.fhir.uv.cql.FHIRHelpers version '4.0.1' called FHIRHelpers
    include hl7.fhir.uv.cql.FHIRCommon version '2.0.0' called FHIRCommon
    include hl7.fhir.us.cql.USCoreCommon version '2.0.0-ballot' called USCoreCommon
    include hl7.fhir.us.cql.USCoreElements version '2.0.0-ballot' called USCoreElements

    include USQualityCoreCommon version '0.1.0-cibuild' called USQualityCoreCommon
    include SupplementalDataElements version '6.1.000' called SDE
    include AHAOverall version '5.1.000' called AHA

    codesystem "SNOMEDCT": 'http://snomed.info/sct'

    valueset "ACE Inhibitor or ARB or ARNI Ingredient": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.526.3.1489'
    valueset "ACE Inhibitor or ARB or ARNI": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.526.3.1139'
    valueset "Allergy to ACE Inhibitor or ARB": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.526.3.1211'
    valueset "Intolerance to ACE Inhibitor or ARB": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.526.3.1212'
    valueset "Medical Reason": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.526.3.1007'
    valueset "Patient Reason": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.526.3.1008'
    valueset "Patient Reason for ACE Inhibitor or ARB Decline": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.526.3.1140'
    valueset "Pregnancy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.526.3.378'

    code "Acute renal failure caused by angiotensin-converting-enzyme inhibitor (disorder)": '422593004' from "SNOMEDCT" display 'Acute renal failure caused by angiotensin-converting-enzyme inhibitor (disorder)'
    code "Substance with angiotensin II receptor antagonist mechanism of action (substance)": '372913009' from "SNOMEDCT" display 'Substance with angiotensin II receptor antagonist mechanism of action (substance)'
    code "Substance with angiotensin-converting enzyme inhibitor mechanism of action (substance)": '372733002' from "SNOMEDCT" display 'Substance with angiotensin-converting enzyme inhibitor mechanism of action (substance)'
    code "Substance with neprilysin inhibitor mechanism of action (substance)": '786886009' from "SNOMEDCT" display 'Substance with neprilysin inhibitor mechanism of action (substance)'

    parameter "Measurement Period" Interval<DateTime>
      default Interval[@2026-01-01T00:00:00.000Z, @2027-01-01T00:00:00.000Z)

    context Patient

    define "Initial Population":
      AHA."Is Adult With Two Qualifying Outpatient Encounters and One Heart Failure Outpatient Encounter During the Measurement Period"

    define "Denominator":
      "Initial Population"
        and exists AHA."Heart Failure Outpatient Encounter with History of Moderate or Severe LVSD"

    define "Denominator Exclusions":
      AHA."Has Heart Transplant"
        or AHA."Has Heart Transplant Complications"
        or AHA."Has Left Ventricular Assist Device"
        or AHA."Has Left Ventricular Assist Device Complications"

    define "Numerator":
      "Has ACEI or ARB or ARNI Ordered"
        or "Is Currently Taking ACEI or ARB or ARNI"

    define "Denominator Exceptions":
      "Has Medical or Patient Reason for Not Ordering ACEI or ARB or ARNI"
        or "Has Allergy or Intolerance to ACEI or ARB or ARNI Ingredient"
        or "Has Diagnosis of Allergy or Intolerance to ACEI or ARB"
        or "Has Diagnosis of Pregnancy"
        or "Has Diagnosis of Renal Failure Due to ACEI"

    define "SDE Ethnicity":
      SDE."SDE Ethnicity"

    define "SDE Payer":
      SDE."SDE Payer"

    define "SDE Race":
      SDE."SDE Race"

    define "SDE Sex":
      SDE."SDE Sex"

    define "Has ACEI or ARB or ARNI Ordered":
      exists ( [MedicationRequest: medication in "ACE Inhibitor or ARB or ARNI"] ACEIOrARBOrARNIOrdered
          where ACEIOrARBOrARNIOrdered.isOrderedDuringHeartFailureOutpatientEncounter ( )
      )

    define "Has Allergy or Intolerance to ACEI or ARB or ARNI Ingredient":
      exists ( ( [AllergyIntolerance: "ACE Inhibitor or ARB or ARNI Ingredient"]
          union [AllergyIntolerance: "Substance with angiotensin-converting enzyme inhibitor mechanism of action (substance)"]
          union [AllergyIntolerance: "Substance with angiotensin II receptor antagonist mechanism of action (substance)"]
          union [AllergyIntolerance: "Substance with neprilysin inhibitor mechanism of action (substance)"] ) ACEIOrARBOrARNIAllergyIntolerance
          where ACEIOrARBOrARNIAllergyIntolerance.overlapsAfterHeartFailureOutpatientEncounter ( )
      )

    define "Has Diagnosis of Allergy or Intolerance to ACEI or ARB":
      exists ( (
        ["Condition": "Allergy to ACE Inhibitor or ARB"]
          union ["Condition": "Intolerance to ACE Inhibitor or ARB"]
       ) ACEIOrARBAllergyOrIntoleranceDiagnosis
          where ACEIOrARBAllergyOrIntoleranceDiagnosis.overlapsAfterHeartFailureOutpatientEncounter ( )
      )

    define "Has Diagnosis of Pregnancy":
      exists ( ( [Condition: "Pregnancy"] ) PregnancyDiagnosis
          with AHA."Heart Failure Outpatient Encounter with History of Moderate or Severe LVSD" ModerateOrSevereLVSDHFOutpatientEncounter
            such that PregnancyDiagnosis.prevalenceInterval ( ) starts 9 months or less before or on start of ModerateOrSevereLVSDHFOutpatientEncounter.period
              and PregnancyDiagnosis.isVerified ( )
      )
        or exists ( [USCore.ObservationPregnancyStatusProfile] PregnantObservation
            with AHA."Heart Failure Outpatient Encounter with History of Moderate or Severe LVSD" ModerateOrSevereLVSDHFOutpatientEncounter
              such that PregnantObservation.effective.toInterval ( ) starts 9 months or less before or on start of ModerateOrSevereLVSDHFOutpatientEncounter.period
                and ( PregnantObservation.value in "Pregnancy"
                    and PregnantObservation.status in { 'final', 'amended', 'corrected' }
                )
        )

    define "Has Diagnosis of Renal Failure Due to ACEI":
      exists ( ( [Condition: "Acute renal failure caused by angiotensin-converting-enzyme inhibitor (disorder)"] ) RenalFailureDueToACEI
          where RenalFailureDueToACEI.overlapsHeartFailureOutpatientEncounter ( )
      )

    define "Has Medical or Patient Reason for Not Ordering ACEI or ARB or ARNI":
      exists ( [MedicationNotRequested: medication in "ACE Inhibitor or ARB or ARNI"] NoACEIOrARBOrARNIOrdered
          where NoACEIOrARBOrARNIOrdered.isMedicationNotRequestedOrderedDuringHeartFailureOutpatientEncounter ( )
            and ( NoACEIOrARBOrARNIOrdered.reasonCode in "Medical Reason"
                or NoACEIOrARBOrARNIOrdered.reasonCode in "Patient Reason"
                or NoACEIOrARBOrARNIOrdered.reasonCode in "Patient Reason for ACE Inhibitor or ARB Decline"
            )
      )

    define "Is Currently Taking ACEI or ARB or ARNI":
      exists ( [MedicationRequest: medication in "ACE Inhibitor or ARB or ARNI"] ActiveACEIOrARBOrARNI
          where ActiveACEIOrARBOrARNI.overlapsAfterHeartFailureOutpatientEncounter ( )
      )
ELM XML Content |
    Encoded data
ELM JSON Content |
    Encoded data
Generated using version 0.5.4 of the sample-content-ig Liquid templates