Draft dQM CMS Content Implementation Guide
2025.1.0 - CI Build

Draft dQM CMS Content Implementation Guide, published by cqframework. This guide is not an authorized publication; it is the continuous build for version 2025.1.0 built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/cqframework/dqm-content-cms-2025/ and changes regularly. See the Directory of published versions

Library: CMS1206FHIRCTOQR

Official URL: https://madie.cms.gov/Library/CMS1206FHIRCTOQR Version: 1.1.000
Active as of 2025-08-25 Responsible: Alara Imaging, Inc. Computable Name: CMS1206FHIRCTOQR
Other Identifiers: https://madie.cms.gov/login#CMS1206FHIRCTOQR (use: official, )

CMS1206FHIRCTOQR

Metadata
Title CMS1206FHIRCTOQR
Version 1.1.000
Identifier CMS1206FHIRCTOQR
Topic FHIR
Topic CQL
Steward (Publisher) Alara Imaging, Inc.
Description

CMS1206FHIRCTOQR
Type logic-library from http://terminology.hl7.org/CodeSystem/library-type
Dependency Description: Model USQualityCore
Resource: https://madie.cms.gov/Library/USQualityCore-ModelInfo|0.1.0-cibuild
Canonical URL: https://madie.cms.gov/Library/USQualityCore-ModelInfo|0.1.0-cibuild
Dependency Description: Library FHIRHelpers
Resource: http://hl7.org/fhir/uv/cql/Library/FHIRHelpers|4.0.1
Canonical URL: http://hl7.org/fhir/uv/cql/Library/FHIRHelpers|4.0.1
Dependency Description: Library FHIRCommon
Resource: http://hl7.org/fhir/uv/cql/Library/FHIRCommon|2.0.0
Canonical URL: http://hl7.org/fhir/uv/cql/Library/FHIRCommon|2.0.0
Dependency Description: Library USCoreCommon
Resource: http://hl7.org/fhir/us/cql/Library/USCoreCommon|2.0.0-ballot
Canonical URL: http://hl7.org/fhir/us/cql/Library/USCoreCommon|2.0.0-ballot
Dependency Description: Library USCoreElements
Resource: http://hl7.org/fhir/us/cql/Library/USCoreElements|2.0.0-ballot
Canonical URL: http://hl7.org/fhir/us/cql/Library/USCoreElements|2.0.0-ballot
Dependency Description: Library USQualityCoreCommon
Resource: US Quality Core Commonversion: null0.1.0-cibuild)
Canonical URL: https://madie.cms.gov/Library/USQualityCoreCommon|0.1.0-cibuild
Dependency Description: Library SDE
Resource: SupplementalDataElementsversion: null6.1.000)
Canonical URL: https://madie.cms.gov/Library/SupplementalDataElements|6.1.000
Dependency Description: Library CQMCommon
Resource: CQMCommonversion: null5.1.000)
Canonical URL: https://madie.cms.gov/Library/CQMCommon|5.1.000
Dependency Description: Library AlaraCommonFunctions
Resource: https://madie.cms.gov/Library/AlaraCommonFunctions|2.1.000
Canonical URL: https://madie.cms.gov/Library/AlaraCommonFunctions|2.1.000
Dependency Description: Code System LOINC
Resource: Logical Observation Identifiers, Names and Codes (LOINC)
Canonical URL: http://loinc.org
Dependency Description: Value Set Encounter Inpatient
Resource: Encounter Inpatient
Canonical URL: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.666.5.307
Data Requirement Type: Observation
Profile(s): http://fhir.org/guides/astp/us-quality-core/StructureDefinition/us-quality-core-observation-clinical-result
Code Filter(s):
Path: code
Code(s): LOINC: 96914-7 (CT dose and image quality category)
Data Requirement Type: Encounter
Profile(s): Encounter
Code Filter(s):
Path: type
ValueSet: Encounter Inpatient
Parameters
Name Use Card. Type Documentation
Measurement Period In 0..1 Period
Patient Out 0..1 Resource
Qualified Scan Out 0..* Resource
Qualified Scan Without Inpatient Encounter Out 0..* Resource
Qualified Scan With Values Out 0..* Resource
Denominator Out 0..* Resource
Denominator Exclusion Out 0..* Resource
Initial Population Out 0..* Resource
Numerator Out 0..* Resource
SDE Ethnicity Out 0..1 Resource
SDE Payer Out 0..* Resource
SDE Race Out 0..1 Resource
SDE Sex Out 0..1 Coding
Library Content
CQL Content 
/*
NOTE: For use by March 2026 US Realm Connectathon participants for internal use only. Not for use or distribution in commercial products.
*/
library CMS1206FHIRCTOQR version '1.1.000'

using USQualityCore version '0.1.0-cibuild'
using USCore version '6.1.0-derived'
using FHIR version '4.0.1'

include hl7.fhir.uv.cql.FHIRHelpers version '4.0.1' called FHIRHelpers
include hl7.fhir.uv.cql.FHIRCommon version '2.0.0' called FHIRCommon
include hl7.fhir.us.cql.USCoreCommon version '2.0.0-ballot' called USCoreCommon
include hl7.fhir.us.cql.USCoreElements version '2.0.0-ballot' called USCoreElements

include USQualityCoreCommon version '0.1.0-cibuild' called USQualityCoreCommon
include SupplementalDataElements version '6.1.000' called SDE
include CQMCommon version '5.1.000' called CQMCommon
include AlaraCommonFunctions version '2.1.000' called AlaraCommonFunctions

codesystem "LOINC": 'http://loinc.org'

valueset "Encounter Inpatient": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.666.5.307'

code "CT dose and image quality category": '96914-7' from "LOINC" display 'CT dose and image quality category'
code "Full Body": 'LA31771-1' from "LOINC" display 'Full Body'

parameter "Measurement Period" Interval<DateTime>
  default Interval[@2026-01-01T00:00:00.000Z, @2027-01-01T00:00:00.000Z)

context Patient

define "Denominator":
  "Qualified Scan With Values"

// TODO: Note that this used to use a .coding contains "Full Body", presumably to allow for other codings, so long as at least Full Body is present
// But that is the definition of concept equivalent within CQL, so it should be the same to just use the ~ operator. Please confirm.
define "Denominator Exclusion":
  "Qualified Scan With Values" CTScanWithValues
    where ( CTScanWithValues.value as FHIR.CodeableConcept ) ~ "Full Body"

define "Initial Population":
  "Qualified Scan Without Inpatient Encounter"

define "Numerator":
  "Qualified Scan With Values" CTScanWithValues
    where CTScanWithValues.ctScanQualifies ( )

define "Qualified Scan With Values":
  "Qualified Scan Without Inpatient Encounter" CTScan
    where CTScan.globalNoiseValue ( ) is not null
      and CTScan.sizeAdjustedValue ( ) is not null
      and CTScan.value is not null

define "Qualified Scan Without Inpatient Encounter":
  "Qualified Scan" QualifiedCTScan
    without [Encounter: "Encounter Inpatient"] InpatientEncounter
      such that InpatientEncounter.status ~ 'finished'
        and InpatientEncounter.period ends during day of "Measurement Period"
        and QualifiedCTScan.effective.toInterval ( ) starts during InpatientEncounter.period

define "Qualified Scan":
  [ObservationClinicalResult: "CT dose and image quality category"] CTScanResult
    where CTScanResult.status in { 'final', 'amended', 'corrected' }
      and CTScanResult.effective.toInterval ( ) ends during day of "Measurement Period"
      and AgeInYearsAt(date from start of "Measurement Period") >= 18

define "SDE Ethnicity":
  SDE."SDE Ethnicity"

define "SDE Payer":
  SDE."SDE Payer"

define "SDE Race":
  SDE."SDE Race"

define "SDE Sex":
  SDE."SDE Sex"
ELM XML Content 
Encoded data
ELM JSON Content 
Encoded data
Generated using version 0.5.4 of the sample-content-ig Liquid templates