CMS Draft FHIR Measures
2024.1.0 - CI Build

CMS Draft FHIR Measures, published by cqframework. This guide is not an authorized publication; it is the continuous build for version 2024.1.0 built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/cqframework/dqm-content-cms-2024/ and changes regularly. See the Directory of published versions

## Library: Breast Cancer Screening FHIR

Official URL: https://madie.cms.gov/Library/BreastCancerScreeningFHIR | Version: 0.0.001
Active as of 2024-05-16 | Computable Name: BreastCancerScreeningFHIR
Other Identifiers: https://madie.cms.gov/login#BreastCancerScreeningFHIR (use: official, )

Breast Cancer Screening FHIR

Metadata
Title | Breast Cancer Screening FHIR
Version | 0.0.001
Identifier | BreastCancerScreeningFHIR
Topic | FHIR
Topic | CQL
Description | Breast Cancer Screening FHIR
Type | logic-library from http://terminology.hl7.org/CodeSystem/library-type
Dependency | Description: Library FHIRHelpers Resource: FHIRHelpersversion: null4.4.000) Canonical URL: `https://madie.cms.gov/Library/FHIRHelpers|4.4.000`
Dependency | Description: Library SDE Resource: SupplementalDataElementsversion: null3.5.000) Canonical URL: `https://madie.cms.gov/Library/SupplementalDataElements|3.5.000`
Dependency | Description: Library QICoreCommon Resource: QICoreCommonversion: null2.1.000) Canonical URL: `https://madie.cms.gov/Library/QICoreCommon|2.1.000`
Dependency | Description: Library AdultOutpatientEncounters Resource: AdultOutpatientEncountersversion: null4.11.000) Canonical URL: `https://madie.cms.gov/Library/AdultOutpatientEncounters|4.11.000`
Dependency | Description: Library Hospice Resource: Hospiceversion: null6.12.000) Canonical URL: `https://madie.cms.gov/Library/Hospice|6.12.000`
Dependency | Description: Library Status Resource: Statusversion: null1.8.000) Canonical URL: `https://madie.cms.gov/Library/Status|1.8.000`
Dependency | Description: Library PalliativeCare Resource: PalliativeCareversion: null1.11.000) Canonical URL: `https://madie.cms.gov/Library/PalliativeCare|1.11.000`
Dependency | Description: Library AIFrailLTCF Resource: AdvancedIllnessandFrailtyversion: null1.16.000) Canonical URL: `https://madie.cms.gov/Library/AdvancedIllnessandFrailty|1.16.000`
Dependency | Description: Code System AdministrativeGender Resource: AdministrativeGender Canonical URL: `http://terminology.hl7.org/CodeSystem/v3-AdministrativeGender`
Dependency | Description: Code System SNOMEDCT Resource: SNOMED CT (all versions) Canonical URL: `http://snomed.info/sct`
Dependency | Description: Code System LOINC Resource: Logical Observation Identifiers, Names and Codes (LOINC) Canonical URL: `http://loinc.org`
Dependency | Description: Value Set Bilateral Mastectomy Resource: Bilateral Mastectomy Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1005`
Dependency | Description: Value Set History of bilateral mastectomy Resource: History of bilateral mastectomy Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1068`
Dependency | Description: Value Set Mammography Resource: Mammography Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1018`
Dependency | Description: Value Set Status Post Left Mastectomy Resource: Status Post Left Mastectomy Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1069`
Dependency | Description: Value Set Status Post Right Mastectomy Resource: Status Post Right Mastectomy Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1070`
Dependency | Description: Value Set Unilateral Mastectomy Left Resource: Unilateral Mastectomy Left Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1133`
Dependency | Description: Value Set Unilateral Mastectomy Right Resource: Unilateral Mastectomy Right Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1134`
Dependency | Description: Value Set Unilateral Mastectomy, Unspecified Laterality Resource: Unilateral Mastectomy, Unspecified Laterality Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1071`
Data Requirement | Type: Condition Profile(s): QICoreCondition Code Filter(s): Path: code ValueSet: Status Post Right Mastectomy
Data Requirement | Type: Procedure Profile(s): QICoreProcedure Code Filter(s): Path: code ValueSet: Unilateral Mastectomy Right
Data Requirement | Type: Condition Profile(s): QICoreCondition Code Filter(s): Path: code ValueSet: Status Post Left Mastectomy
Data Requirement | Type: Condition Profile(s): QICoreCondition Code Filter(s): Path: code ValueSet: Unilateral Mastectomy, Unspecified Laterality
Data Requirement | Type: Procedure Profile(s): QICoreProcedure Code Filter(s): Path: code ValueSet: Unilateral Mastectomy Left
Data Requirement | Type: Condition Profile(s): QICoreCondition Code Filter(s): Path: code ValueSet: History of bilateral mastectomy
Data Requirement | Type: Procedure Profile(s): QICoreProcedure Code Filter(s): Path: code ValueSet: Bilateral Mastectomy
Data Requirement | Type: Observation Profile(s): QICoreObservation Code Filter(s): Path: code ValueSet: Mammography
Parameters
Name | Use | Card. | Type | Documentation
Measurement Period | In | 0..1 | Period |
Patient | Out | 0..1 | Resource |
Initial Population | Out | 0..1 | boolean |
Denominator | Out | 0..1 | boolean |
Right Mastectomy Diagnosis | Out | 0..* | Resource |
Right Mastectomy Procedure | Out | 0..* | Resource |
Left Mastectomy Diagnosis | Out | 0..* | Resource |
Left Mastectomy Procedure | Out | 0..* | Resource |
Bilateral Mastectomy Diagnosis | Out | 0..* | Resource |
Bilateral Mastectomy Procedure | Out | 0..* | Resource |
Denominator Exclusions | Out | 0..1 | boolean |
October 1 Two Years Prior to the Measurement Period | Out | 0..1 | dateTime |
Numerator | Out | 0..1 | boolean |
SDE Ethnicity | Out | 0..1 | Resource |
SDE Payer | Out | 0..* | Resource |
SDE Race | Out | 0..1 | Resource |
SDE Sex | Out | 0..1 | Coding |
Library Content
CQL Content |
    library BreastCancerScreeningFHIR version '0.0.001'

    using QICore version '4.1.1'

    include FHIRHelpers version '4.4.000' called FHIRHelpers
    include SupplementalDataElements version '3.5.000' called SDE
    include QICoreCommon version '2.1.000' called QICoreCommon
    include AdultOutpatientEncounters version '4.11.000' called AdultOutpatientEncounters
    include Hospice version '6.12.000' called Hospice
    include Status version '1.8.000' called Status
    include PalliativeCare version '1.11.000' called PalliativeCare
    include AdvancedIllnessandFrailty version '1.16.000' called AIFrailLTCF

    codesystem "AdministrativeGender": 'http://terminology.hl7.org/CodeSystem/v3-AdministrativeGender'
    codesystem "SNOMEDCT": 'http://snomed.info/sct'
    codesystem "LOINC": 'http://loinc.org'

    valueset "Bilateral Mastectomy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1005'
    valueset "History of bilateral mastectomy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1068'
    valueset "Mammography": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1018'
    valueset "Status Post Left Mastectomy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1069'
    valueset "Status Post Right Mastectomy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1070'
    valueset "Unilateral Mastectomy Left": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1133'
    valueset "Unilateral Mastectomy Right": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1134'
    valueset "Unilateral Mastectomy, Unspecified Laterality": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1071'

    code "Female": 'F' from "AdministrativeGender" display 'Female'
    code "Left (qualifier value)": '7771000' from "SNOMEDCT" display 'Left (qualifier value)'
    code "Right (qualifier value)": '24028007' from "SNOMEDCT" display 'Right (qualifier value)'

    parameter "Measurement Period" Interval<DateTime>
      default Interval[@2025-01-01T00:00:00.000Z, @2025-12-31T23:59:59.999Z]

    context Patient

    define "Initial Population":
      AgeInYearsAt(date from
        end of "Measurement Period"
      ) in Interval[52, 74]
        and Patient.gender = 'female'
        and exists AdultOutpatientEncounters."Qualifying Encounters"

    define "Denominator":
      "Initial Population"

    define "Denominator Exclusions":
      Hospice."Has Hospice Services"
        or ( ( exists ( "Right Mastectomy Diagnosis" )
              or exists ( "Right Mastectomy Procedure" )
          )
            and ( exists ( "Left Mastectomy Diagnosis" )
                or exists ( "Left Mastectomy Procedure" )
            )
        )
        or exists "Bilateral Mastectomy Diagnosis"
        or exists "Bilateral Mastectomy Procedure"
        or AIFrailLTCF."Is Age 66 or Older with Advanced Illness and Frailty"
        or AIFrailLTCF."Is Age 66 or Older Living Long Term in a Nursing Home"
        or PalliativeCare."Has Palliative Care in the Measurement Period"

    define "Right Mastectomy Diagnosis":
      ( [Condition: "Status Post Right Mastectomy"] RightMastectomyProcedure
        union ( [Condition: "Unilateral Mastectomy, Unspecified Laterality"] UnilateralMastectomyDiagnosis
            where exists ( UnilateralMastectomyDiagnosis.bodySite S
                where S ~ "Right (qualifier value)"
            )
        ) ) RightMastectomy
        where RightMastectomy.prevalenceInterval ( ) starts on or before end of "Measurement Period"

    define "Right Mastectomy Procedure":
      ( ( [Procedure: "Unilateral Mastectomy Right"] ).isProcedurePerformed ( ) ) UnilateralMastectomyRightPerformed
        where UnilateralMastectomyRightPerformed.performed.toInterval ( ) ends on or before end of "Measurement Period"

    define "Left Mastectomy Diagnosis":
      ( [Condition: "Status Post Left Mastectomy"]
        union ( [Condition: "Unilateral Mastectomy, Unspecified Laterality"] UnilateralMastectomyDiagnosis
            where exists ( UnilateralMastectomyDiagnosis.bodySite S
                where S ~ "Left (qualifier value)"
            )
        ) ) LeftMastectomy
        where LeftMastectomy.prevalenceInterval ( ) starts on or before end of "Measurement Period"

    define "Left Mastectomy Procedure":
      ( ( [Procedure: "Unilateral Mastectomy Left"] ).isProcedurePerformed ( ) ) UnilateralMastectomyLeftPerformed
        where UnilateralMastectomyLeftPerformed.performed.toInterval ( ) ends on or before end of "Measurement Period"

    define "Bilateral Mastectomy Diagnosis":
      [Condition: "History of bilateral mastectomy"] BilateralMastectomyHistory
        where BilateralMastectomyHistory.prevalenceInterval ( ) starts on or before end of "Measurement Period"

    define "Bilateral Mastectomy Procedure":
      ( ( [Procedure: "Bilateral Mastectomy"] ).isProcedurePerformed ( ) ) BilateralMastectomyPerformed
        where BilateralMastectomyPerformed.performed.toInterval ( ) ends on or before end of "Measurement Period"

    define "Numerator":
      exists ( ( ( [Observation: "Mammography"] ).isDiagnosticStudyPerformed ( ) ) Mammogram
          where Mammogram.effective.toInterval ( ) ends during day of Interval["October 1 Two Years Prior to the Measurement Period", end of "Measurement Period"]
      )

    define "October 1 Two Years Prior to the Measurement Period":
      DateTime((year from start of "Measurement Period" - 2), 10, 1, 0, 0, 0, 0, 0)

    define "SDE Ethnicity":
      SDE."SDE Ethnicity"

    define "SDE Payer":
      SDE."SDE Payer"

    define "SDE Race":
      SDE."SDE Race"

    define "SDE Sex":
      SDE."SDE Sex"
ELM XML Content |
    Encoded data
ELM JSON Content |
    Encoded data
Generated using version 0.5.4-cibuild of the sample-content-ig Liquid templates