CMS Draft FHIR Measures
2024.1.0 - CI Build

CMS Draft FHIR Measures, published by cqframework. This guide is not an authorized publication; it is the continuous build for version 2024.1.0 built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/cqframework/dqm-content-cms-2024/ and changes regularly. See the Directory of published versions

Library: Colon Cancer Screening FHIR

Official URL: https://madie.cms.gov/Library/ColonCancerScreeningFHIR Version: 0.1.000
Active as of 2024-05-15 Computable Name: ColonCancerScreeningFHIR
Other Identifiers: https://madie.cms.gov/login#ColonCancerScreeningFHIR (use: official, )

Colon Cancer Screening FHIR

Metadata
Title Colon Cancer Screening FHIR
Version 0.1.000
Identifier ColonCancerScreeningFHIR
Topic FHIR
Topic CQL
Description

Colon Cancer Screening FHIR
Type logic-library from http://terminology.hl7.org/CodeSystem/library-type
Dependency Description: Library FHIRHelpers
Resource: FHIRHelpersversion: null4.4.000)
Canonical URL: https://madie.cms.gov/Library/FHIRHelpers|4.4.000
Dependency Description: Library SDE
Resource: SupplementalDataElementsversion: null3.5.000)
Canonical URL: https://madie.cms.gov/Library/SupplementalDataElements|3.5.000
Dependency Description: Library Hospice
Resource: Hospiceversion: null6.12.000)
Canonical URL: https://madie.cms.gov/Library/Hospice|6.12.000
Dependency Description: Library PalliativeCare
Resource: PalliativeCareversion: null1.11.000)
Canonical URL: https://madie.cms.gov/Library/PalliativeCare|1.11.000
Dependency Description: Library AdultOutpatientEncounters
Resource: AdultOutpatientEncountersversion: null4.11.000)
Canonical URL: https://madie.cms.gov/Library/AdultOutpatientEncounters|4.11.000
Dependency Description: Library AIFrailLTCF
Resource: AdvancedIllnessandFrailtyversion: null1.16.000)
Canonical URL: https://madie.cms.gov/Library/AdvancedIllnessandFrailty|1.16.000
Dependency Description: Library Status
Resource: Statusversion: null1.8.000)
Canonical URL: https://madie.cms.gov/Library/Status|1.8.000
Dependency Description: Library QICoreCommon
Resource: QICoreCommonversion: null2.1.000)
Canonical URL: https://madie.cms.gov/Library/QICoreCommon|2.1.000
Dependency Description: Value Set Colonoscopy
Resource: Colonoscopy
Canonical URL: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1020
Dependency Description: Value Set CT Colonography
Resource: CT Colonography
Canonical URL: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1038
Dependency Description: Value Set Fecal Occult Blood Test (FOBT)
Resource: Fecal Occult Blood Test (FOBT)
Canonical URL: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1011
Dependency Description: Value Set sDNA FIT Test
Resource: FIT DNA
Canonical URL: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1039
Dependency Description: Value Set Flexible Sigmoidoscopy
Resource: Flexible Sigmoidoscopy
Canonical URL: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1010
Dependency Description: Value Set Malignant Neoplasm of Colon
Resource: Malignant Neoplasm of Colon
Canonical URL: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1001
Dependency Description: Value Set Total Colectomy
Resource: Total Colectomy
Canonical URL: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1019
Data Requirement Type: Condition
Profile(s): QICoreCondition
Code Filter(s):
Path: code
ValueSet: Malignant Neoplasm of Colon
Data Requirement Type: Procedure
Profile(s): QICoreProcedure
Code Filter(s):
Path: code
ValueSet: Total Colectomy
Data Requirement Type: Observation
Profile(s): QICoreObservation
Code Filter(s):
Path: code
ValueSet: Fecal Occult Blood Test (FOBT)
Data Requirement Type: Observation
Profile(s): QICoreObservation
Code Filter(s):
Path: code
ValueSet: FIT DNA
Data Requirement Type: Procedure
Profile(s): QICoreProcedure
Code Filter(s):
Path: code
ValueSet: Flexible Sigmoidoscopy
Data Requirement Type: Observation
Profile(s): QICoreObservation
Code Filter(s):
Path: code
ValueSet: CT Colonography
Data Requirement Type: Procedure
Profile(s): QICoreProcedure
Code Filter(s):
Path: code
ValueSet: Colonoscopy
Parameters
Name Use Card. Type Documentation
Measurement Period In 0..1 Period
Patient Out 0..1 Resource
SDE Ethnicity Out 0..1 Resource
SDE Payer Out 0..* Resource
SDE Race Out 0..1 Resource
SDE Sex Out 0..1 Coding
Initial Population Out 0..1 boolean
Denominator Out 0..1 boolean
Malignant Neoplasm Out 0..* Resource
Total Colectomy Performed Out 0..* Resource
Denominator Exclusion Out 0..1 boolean
Fecal Occult Blood Test Performed Out 0..* Resource
Stool DNA with FIT Test Performed Out 0..* Resource
Flexible Sigmoidoscopy Performed Out 0..* Resource
CT Colonography Performed Out 0..* Resource
Colonoscopy Performed Out 0..* Resource
Numerator Out 0..1 boolean
Stratification 1 Out 0..1 boolean
Stratification 2 Out 0..1 boolean
Library Content
CQL Content 
library ColonCancerScreeningFHIR version '0.1.000'

using QICore version '4.1.1'

include FHIRHelpers version '4.4.000' called FHIRHelpers
include SupplementalDataElements version '3.5.000' called SDE
include Hospice version '6.12.000' called Hospice
include PalliativeCare version '1.11.000' called PalliativeCare
include AdultOutpatientEncounters version '4.11.000' called AdultOutpatientEncounters
include AdvancedIllnessandFrailty version '1.16.000' called AIFrailLTCF
include Status version '1.8.000' called Status
include QICoreCommon version '2.1.000' called QICoreCommon

valueset "Colonoscopy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1020'
valueset "CT Colonography": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1038'
valueset "Fecal Occult Blood Test (FOBT)": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1011'
valueset "sDNA FIT Test": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1039'
valueset "Flexible Sigmoidoscopy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1010'
valueset "Malignant Neoplasm of Colon": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1001'
valueset "Total Colectomy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1019'

parameter "Measurement Period" Interval<DateTime>
  default Interval[@2025-01-01T00:00:00.000Z, @2025-12-31T23:59:59.999Z]

context Patient

define "SDE Ethnicity":
  SDE."SDE Ethnicity"

define "SDE Payer":
  SDE."SDE Payer"

define "SDE Race":
  SDE."SDE Race"

define "SDE Sex":
  SDE."SDE Sex"

define "Initial Population":
  AgeInYearsAt(date from 
    end of "Measurement Period"
  ) in Interval[46, 75]
    and exists AdultOutpatientEncounters."Qualifying Encounters"

define "Denominator":
  "Initial Population"

define "Denominator Exclusion":
  Hospice."Has Hospice Services"
    or exists "Malignant Neoplasm"
    or exists "Total Colectomy Performed"
    or AIFrailLTCF."Is Age 66 or Older with Advanced Illness and Frailty"
    or AIFrailLTCF."Is Age 66 or Older Living Long Term in a Nursing Home"
    or PalliativeCare."Has Palliative Care in the Measurement Period"

define "Numerator":
  exists "Fecal Occult Blood Test Performed"
    or exists "Stool DNA with FIT Test Performed"
    or exists "Flexible Sigmoidoscopy Performed"
    or exists "CT Colonography Performed"
    or exists "Colonoscopy Performed"

define "Fecal Occult Blood Test Performed":
  ( ( [Observation: "Fecal Occult Blood Test (FOBT)"] ).isLaboratoryTestPerformed ( ) ) FecalOccultResult
    where FecalOccultResult.value is not null
      and FecalOccultResult.effective.latest ( ) during day of "Measurement Period"

define "Malignant Neoplasm":
  ( [Condition: "Malignant Neoplasm of Colon"] ) ColorectalCancer
    where ColorectalCancer.prevalenceInterval ( ) starts on or before day of end of "Measurement Period"

define "Total Colectomy Performed":
  ( ( [Procedure: "Total Colectomy"] ).isProcedurePerformed ( ) ) Colectomy
    where Colectomy.performed.toInterval ( ) ends on or before day of end of "Measurement Period"

define "Stratification 1":
  AgeInYearsAt(date from 
    end of "Measurement Period"
  ) in Interval[46, 49]

define "Stratification 2":
  AgeInYearsAt(date from 
    end of "Measurement Period"
  ) in Interval[50, 75]

define "Colonoscopy Performed":
  ( ( [Procedure: "Colonoscopy"] ).isProcedurePerformed ( ) ) Colonoscopy
    where Colonoscopy.performed.toInterval ( ) ends during day of Interval[start of "Measurement Period" - 9 years, end of "Measurement Period"]

define "Flexible Sigmoidoscopy Performed":
  ( ( [Procedure: "Flexible Sigmoidoscopy"] ).isProcedurePerformed ( ) ) FlexibleSigmoidoscopy
    where FlexibleSigmoidoscopy.performed.toInterval ( ) ends during day of Interval[start of "Measurement Period" - 4 years, end of "Measurement Period"]

define "CT Colonography Performed":
  ( ( [Observation: "CT Colonography"] ).isDiagnosticStudyPerformed ( ) ) Colonography
    where Colonography.effective.toInterval ( ) ends during day of Interval[start of "Measurement Period" - 4 years, end of "Measurement Period"]

define "Stool DNA with FIT Test Performed":
  ( ( [Observation: "sDNA FIT Test"] ).isLaboratoryTestPerformed ( ) ) sDNATest
    where sDNATest.value is not null
      and sDNATest.effective.latest ( ) during day of Interval[start of "Measurement Period" - 2 years, end of "Measurement Period"]
ELM XML Content 
Encoded data
ELM JSON Content 
Encoded data
Generated using version 0.5.4-cibuild of the sample-content-ig Liquid templates