WHO Antenatal Care Guideline Implementation Guide
0.3.0 - CI Build International flag

WHO Antenatal Care Guideline Implementation Guide, published by World Health Organization (WHO). This guide is not an authorized publication; it is the continuous build for version 0.3.0 built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/WorldHealthOrganization/smart-anc/ and changes regularly. See the Directory of published versions

Library: ANC.IND.04 Percentage of pregnant women with at least four ANC contacts

Official URL: http://smart.who.int/anc/Library/ANCIND04 Version: 0.3.0
Active as of 2025-10-27 Computable Name: ANCIND04

This library provides logic for calculating the percentage of pregnant women with at least four ANC contacts

Title: ANC.IND.04 Percentage of pregnant women with at least four ANC contacts
Id: ANCIND04
Version: 0.3.0
Url: ANC.IND.04 Percentage of pregnant women with at least four ANC contacts
Type:

system: http://terminology.hl7.org/CodeSystem/library-type

code: logic-library

Date: 2025-10-27 08:52:21+0000
Publisher: World Health Organization (WHO)
Description:

This library provides logic for calculating the percentage of pregnant women with at least four ANC contacts
Jurisdiction: 001
Related Artifacts:

Dependencies
Parameters:
NameTypeMinMaxIn/Out
Measurement PeriodPeriod01In
PatientPatient01Out
Initial Populationboolean01Out
Numeratorboolean01Out
Denominatorboolean01Out
Age StratifierCoding01Out
Education Level StratifierCodeableConcept0*Out
Data Requirements:
TypeProfileMSCode Filter
Patient http://hl7.org/fhir/StructureDefinition/Patient
Content: text/cql
/*
Library ANC.IND.4
WHO Antenatal Care (ANC) Indicator 4
Percentage of pregnant women with at least four ANC contacts

Numerator: Number of pregnant women with four ANC contacts
Numerator Computation: COUNT of all women who had a total of at least FOUR contacts during pregnancy
Denominator: Total number of antenatal clients with a first contact
Denominator Computation: COUNT of all women whose records were closed (ANC close form) in the last reporting period due to any of the reasons below:
*live birth
*stillbirth
*miscarriage
*abortion
*woman died
*lost to follow-up
*moved away

Disaggregation:
Age (10-14, 15-19, 20+)
Education Level (none, don't know, primary, secondary, higher)
Reference:
WHO ANC monitoring framework (1) 

WHO–UNICEF guidance for RMNCAH programme managers on the analysis and use of health-care facility data (2) 
*/
library ANCIND04

using FHIR version '4.0.1'

include FHIRHelpers version '4.0.1'
include FHIRCommon called FC
include ANCCommon called AC
include ANCBaseConcepts called BCx
include ANCConcepts called Cx
include ANCBaseDataElements called BaseData
include ANCDataElements called PatientData
include ANCContactDataElements called ContactData
include ANCStratifiers called Stratifiers

parameter "Measurement Period" Interval<Date> default Interval[@2020-01-01, @2020-01-31]

context Patient

/*
Initial population: Antenatal clients
*/
define "Initial Population":
  exists (BaseData."Antenatal care case")

/*
Numerator: Number of pregnant women with four ANC contacts
Numerator Computation: COUNT of all women who had a total of at least FOUR contacts during pregnancy
*/
define Numerator:
  Count(BaseData."Antenatal care contact") >= 4

/*
Denominator: Total number of antenatal clients with a first contact
Denominator Computation: COUNT of all women whose records were closed (ANC close form) in the last reporting period due to any of the reasons below:
*live birth
*stillbirth
*miscarriage
*abortion
*woman died
*lost to follow-up
*moved away
*/
define Denominator:
  exists (
    PatientData."Reason for closing ANC record" R
      where FC.ToInterval(R.effective) during "Measurement Period"
        and R.value as FHIR.CodeableConcept in Stratifiers."Qualifying Reason for closing ANC record Choices"
  )

/*
Disaggregation: Age (10-14, 15-19, 20+)
*/
define "Age Stratifier":
  Stratifiers."By Age"

/*
Disaggregation: Education Level (none, don't know, primary, secondary, higher)
*/
define "Education Level Stratifier":
  Stratifiers."By Education Level"
Content: application/elm+json
Encoded data (46596 characters)