//大腸直腸_Cetuximab給付規定2
library CRCCetuximabRule2 version '1.0.0'

using FHIR version '4.0.1'

include FHIRHelpers version '4.0.1' called FHIRHelpers

include CRCCodeConcept version '1.0.0' called CodeConcept

include Reusable version '1.0.0' called Reusable
 
context Patient

//============================================
// 申請類型判斷
//============================================

define "初次申請":
  "申請類型" = '初次使用'

define "續用申請":
  "申請類型" = '續用'

define "申請類型未知":
  "申請類型" = '無法判斷申請類型'

define "申請類型":
  case
    when Reusable."續用註記為1" then '初次使用'
    when Reusable."續用註記為2" then '續用'
    else '無法判斷申請類型'
  end


//============================================
// 主要規定一：初次使用條件
//============================================

/*規則1*/
//條件1
define "規則1-1=初次使用Cetuximab與與Irinotecan合併使用":
  (
    // 存在 Irinotecan 處方  
    exists (
      [MedicationRequest] MROrder2
      where MROrder2.intent = 'order'
      and exists (
        MROrder2.medication.coding Cdg
        where Cdg in CodeConcept.NHIMedication
        and Cdg.code in CodeConcept.L01CE02
      )
      and Reusable."HasValidTiming"(MROrder2)
    )
    and
    // Cetuximab 申請
    exists (
      [MedicationRequest] MRPlan
      where MRPlan.intent = 'plan'
      and exists (
        MRPlan.medication.coding Cdg
        where Cdg in CodeConcept.NHIMedication
        and Cdg.code in CodeConcept.L01FE01
      )
    )
  )
  and Reusable."醫令類別為1"

//條件2
define "規則1-2=用藥線別>1":
  exists (
    [Claim] C
      where exists (
        C.item I
          where exists (
            I.modifier M
              where exists (
                M.coding Cdg
                  where Cdg in CodeConcept.NHILOT
                    and Cdg.code in {'2', '3', '4', '5'}
              )
          )
      )
  )

define "規則1": 
  "規則1-1=初次使用Cetuximab與與Irinotecan合併使用"
  and "規則1-2=用藥線別>1"

/*規則2*/
//條件1
define "規則2-1=治療已接受過含5-fluorouracil、irinotecan及oxaliplatin二線以上之細胞毒性治療失敗":
  (
  // 存在 Fluorouracil 處方
  exists (
   [MedicationRequest] MROrder1
  where MROrder1.intent = 'order'
  and exists (
  MROrder1.medication.coding Cdg
  where Cdg in CodeConcept.NHIMedication
      and Cdg.code in CodeConcept.L01BC02
      or Cdg.code in CodeConcept.L01CE02
   )
  and Reusable."HasValidTiming"(MROrder1)
  and MROrder1.authoredOn before Today()
   )
  and
  // 存在 Oxaliplatin 處方
  exists (
   [MedicationRequest] MROrder2
  where MROrder2.intent = 'order'
  and exists (
  MROrder2.medication.coding Cdg
  where Cdg in CodeConcept.NHIMedication
  and Cdg.code in CodeConcept.L01XA03
   )
  and Reusable."HasValidTiming"(MROrder2)
  and MROrder2.authoredOn before Today()
   )
  and
  // 存在 Irinotecan 處方
  exists (
   [MedicationRequest] MROrder3
  where MROrder3.intent = 'order'
  and exists (
  MROrder3.medication.coding Cdg
  where Cdg in CodeConcept.NHIMedication
  and Cdg.code in CodeConcept.L01CE02
   )
  and Reusable."HasValidTiming"(MROrder3)
  and MROrder3.authoredOn before Today()
   )
  )

//條件2
define  "規則2-2=用於治療具表皮生長因子受體表現型(EGFR expressing)":
  exists (
    [Observation] RasObs
    where RasObs.status = 'final'
    and exists (
      RasObs.code.coding Cdg
      where Cdg.code = '69548-6'
      and Cdg in CodeConcept.LOINC
    )
    and exists (
      RasObs.component C
      where exists (
        C.code.coding Cdg
        where Cdg.code in CodeConcept.GeneTestEGFRexpressing
      )
      and C.value is not null
      and C.value is FHIR.string
      and Matches((C.value as FHIR.string).value, '(?i).*(positive|detected|present|expressed|overexpressed|amplified|\\+).*')
    )
  )

//條件3
define "規則2-3=K-ras為原生型(wild type)":
  exists (
    [Observation] RasObs
    where RasObs.status = 'final'
    and exists (
      RasObs.code.coding Cdg
      where Cdg.code = '69548-6'
      and Cdg in CodeConcept.LOINC
    )
    and exists (
      RasObs.component C
      where exists (
        C.code.coding Cdg
        where Cdg.code in CodeConcept.GeneTest
      )
    )
    and exists (
      RasObs.interpretation.coding I
      where I.code = 'NEG'
    )
  )

//條件4-1    
//Reusable."ICD-10使用C18、C19、C20、C21"
define "ICD代碼檢核_布林值": Reusable."ICD-10使用C18、C19、C20、C21"

//條件4-2
define "規則2-4-2=三個月內有影像檢查報告":
  exists (
    [DiagnosticReport] O
    where exists (
      O.code.coding Cdg
      where (
        Cdg in CodeConcept.ICD10PCS2023Image
        or Cdg in CodeConcept.ICD10PCS2014Image
      )
      and Cdg.code in CodeConcept.ImageReportCode
    )
    and O.effective is not null
    and FHIRHelpers.ToDateTime(O.effective) >= Today() - 90 days
    and FHIRHelpers.ToDateTime(O.effective) <= Today()
  )

//條件4-3
define "規則2-4-3=癌症分期分數或結果為M>=1":
  Count(
    [Observation] O
    where exists (
      O.code.coding Cdg
      where Cdg.code = '399390009'
        and Cdg in CodeConcept.SNOMED
    )
    and O.value is not null
    and O.value is FHIR.string
    and Matches((O.value as FHIR.string).value, '.*M[1-9].*')
  ) > 0

define "規則2-4":
  Reusable."ICD-10使用C18、C19、C20、C21"
  and "規則2-4-2=三個月內有影像檢查報告"
  and "規則2-4-3=癌症分期分數或結果為M>=1"

define "規則2":
  "規則2-1=治療已接受過含5-fluorouracil、irinotecan及oxaliplatin二線以上之細胞毒性治療失敗"
  and  "規則2-2=用於治療具表皮生長因子受體表現型(EGFR expressing)"
  and "規則2-3=K-ras為原生型(wild type)"
  and "規則2-4"

/*規則3*/
define "規則3=存在All-RAS基因突變分析檢測結果報告":
  exists (
    [Observation] RasObservation
    where RasObservation.status = 'final'
    and exists (
      RasObservation.code.coding ObsCodeCoding
      where ObsCodeCoding.code = '69548-6'
      and ObsCodeCoding in CodeConcept.LOINC
    )
    and exists (
      RasObservation.component ComponentRecord
      where exists (
        ComponentRecord.code.coding ComponentCodeCoding
        where ComponentCodeCoding.code in CodeConcept.GeneTest
      )
    )
    and exists (
      RasObservation.derivedFrom DerivedFromRef
      where DerivedFromRef.reference is not null
    )
    and exists (
      [DocumentReference] DocumentRef
      where exists (
        RasObservation.derivedFrom DerivedFromRef
        where EndsWith(DerivedFromRef.reference, DocumentRef.id)
      )
      and DocumentRef.status = 'current'
      and exists (
        DocumentRef.content ContentRecord
        where ContentRecord.attachment.url is not null
      )
    )
  )

define "主要規定一":
  "初次申請" and
  "規則1"
  and "規則2"
  and "規則3=存在All-RAS基因突變分析檢測結果報告"


//============================================
// 主要規定二：續用條件－治療持續給付
//============================================

/*規則1*/
define "規則1=提出客觀證據（如：影像學）證實無惡化，才可繼續使用":
  exists (
    [MedicationRequest] MRPlan
     where MRPlan.intent = 'plan'
     and exists (
        MRPlan.medication.coding Cdg
        where Cdg in CodeConcept.NHIMedication
        and Cdg.code in CodeConcept.L01FE01
      )
  and exists (
    [DiagnosticReport] Report
     where exists (
      Report.code.coding Cdg
        where (
          Cdg in CodeConcept.ICD10PCS2023Image
          or Cdg in CodeConcept.ICD10PCS2014Image
        )
        and Cdg.code in CodeConcept.ImageReportCode
      )
      and Report.effective is not null
      and FHIRHelpers.ToDateTime(Report.effective) >= Today() - 90 days
      and FHIRHelpers.ToDateTime(Report.effective) <= Today()
      )
    )
  and Reusable."醫令類別為1"

define "主要規定二":
  "續用申請" and
  "規則1=提出客觀證據（如：影像學）證實無惡化，才可繼續使用"


//============================================
// 主要規定三：藥品使用規則
//============================================

/*規則1*/
//條件1
define "規則1-1=每次申請事前審查之療程以9週為限":
  exists [MedicationRequest] MRPlan
  where MRPlan.intent = 'plan'
  and exists (
  MRPlan.medication.coding Cdg
  where Cdg in CodeConcept.NHIMedication
  and Cdg.code in CodeConcept.L01FE01
   )
  and days between
  start of (MRPlan.dosageInstruction[0].timing.repeat.bounds as Period)
  and
  end of (MRPlan.dosageInstruction[0].timing.repeat.bounds as Period)
  <= 63

//條件2
define "規則1-2=總使用療程以18週為上限":
  Sum(
   [MedicationRequest] MRTotal
  where (MRTotal.intent = 'plan' or MRTotal.intent = 'order')
  and (MRTotal.status is null or MRTotal.status in { 'active', 'completed', 'on-hold' })
  and exists MRTotal.dosageInstruction
  and MRTotal.dosageInstruction[0].timing.repeat.bounds is Period
  and (start of (MRTotal.dosageInstruction[0].timing.repeat.bounds as Period)) is not null
  and (end of (MRTotal.dosageInstruction[0].timing.repeat.bounds as Period)) is not null
  and exists (
  MRTotal.medication.coding Cdg
  where Cdg in CodeConcept.NHIMedication
  and Cdg.code in CodeConcept.L01FE01
   )
  return
  days between
  start of (MRTotal.dosageInstruction[0].timing.repeat.bounds as Period)
  and
  end of (MRTotal.dosageInstruction[0].timing.repeat.bounds as Period)
   ) <= 126

define "主要規定三":
  "規則1-1=每次申請事前審查之療程以9週為限"
  and "規則1-2=總使用療程以18週為上限"


//============================================
// 審核結果
//============================================

define "MainRule1_Pass":
  if "初次申請"
  then "主要規定一"
  else null

define "MainRule2_Pass":
  if "續用申請"
  then "主要規定二"
  else null

define "MainRule3_Pass":
  "主要規定三"

define "大腸直腸癌Cetuximab(Rule2)申請結果_布林":
  case
    when "初次申請" then ("MainRule1_Pass" and "MainRule3_Pass")
    when "續用申請" then ("MainRule2_Pass" and "MainRule3_Pass")
    else false
  end

define "大腸直腸癌Cetuximab(Rule2)申請結果":
  case
    when "申請類型未知" then '申請未通過：無法判斷申請類型'
    when "初次申請" and "MainRule1_Pass" and "MainRule3_Pass" then '初次使用大腸直腸癌之Cetuximab(二線以上治療)用藥申請 - 通過'
    when "初次申請" then '初次使用大腸直腸癌之Cetuximab(二線以上治療)用藥申請 - 未通過'
    when "續用申請" and "MainRule2_Pass" and "MainRule3_Pass" then '續用大腸直腸癌之Cetuximab(二線以上治療)用藥申請 - 通過'
    when "續用申請" then '續用大腸直腸癌之Cetuximab(二線以上治療)用藥申請 - 未通過'
    else '申請未通過'
  end


//============================================
// 申請審核報告（根據申請類型顯示相關檢核）
//============================================

define "申請審核報告":
  '\n' +
  '\n=== 大腸直腸癌之Cetuximab(二線以上治療) 申請審核報告 ===\n' +
  '\n【申請類型】' + "申請類型" + '\n' +
  
  case
    when "初次申請" then
      '\n【初次使用條件檢核】\n' +
      '主要規定一：' + case when "MainRule1_Pass" then '通過' else '未通過' end + '\n' +
      case when "規則1-1=初次使用Cetuximab與與Irinotecan合併使用"
        then '● 符合：Cetuximab與Irinotecan合併使用'
        else '▲ 不符合：Cetuximab與Irinotecan合併使用'
      end + '\n' +
      case when "規則1-2=用藥線別>1"
        then '● 符合：用藥線別為二線以上'
        else '▲ 不符合：用藥線別為二線以上'
      end + '\n' +
      case when "規則2-1=治療已接受過含5-fluorouracil、irinotecan及oxaliplatin二線以上之細胞毒性治療失敗"
        then '● 符合：已接受過含5-fluorouracil、irinotecan及oxaliplatin二線以上之細胞毒性治療失敗'
        else '▲ 不符合：已接受過含5-fluorouracil、irinotecan及oxaliplatin二線以上之細胞毒性治療失敗'
      end + '\n' +
      case when "規則2-2=用於治療具表皮生長因子受體表現型(EGFR expressing)"
        then '● 符合：具表皮生長因子受體表現型(EGFR expressing)'
        else '▲ 不符合：具表皮生長因子受體表現型(EGFR expressing)'
      end + '\n' +
      case when "規則2-3=K-ras為原生型(wild type)"
        then '● 符合：K-ras為原生型(wild type)'
        else '▲ 不符合：K-ras為原生型(wild type)'
      end + '\n' +
      case when "規則2-4"
        then '● 符合：轉移性大腸直腸癌病患'
        else '▲ 不符合：轉移性大腸直腸癌病患'
      end + '\n' +
      case when "規則3=存在All-RAS基因突變分析檢測結果報告"
        then '● 符合：檢附All-RAS基因突變分析檢測結果報告'
        else '▲ 不符合：檢附All-RAS基因突變分析檢測結果報告'
      end + '\n'
    
    when "續用申請" then
      '\n【續用條件檢核】\n' +
      '主要規定二：' + case when "MainRule2_Pass" then '通過' else '未通過' end + '\n' +
      case when "規則1=提出客觀證據（如：影像學）證實無惡化，才可繼續使用"
        then '● 符合：須提出客觀證據(如：影像學)證實無惡化'
        else '▲ 不符合：須提出客觀證據(如：影像學)證實無惡化'
      end + '\n'
    
    else '\n【錯誤】無法判斷申請類型\n'
  end +
  
  '\n【藥品使用規則檢核】\n' +
  '主要規定三：' + case when "MainRule3_Pass" then '通過' else '未通過' end + '\n' +
  case when "規則1-1=每次申請事前審查之療程以9週為限"
    then '● 符合：每次申請事前審查之療程以9週為限'
    else '▲ 不符合：每次申請事前審查之療程超過9週限制'
  end + '\n' +
  case when "規則1-2=總使用療程以18週為上限"
    then '● 符合：總使用療程以18週為上限'
    else '▲ 不符合：總使用療程超過18週上限'
  end + '\n' +
  
  '\n【申請結果】\n' +
  "大腸直腸癌Cetuximab(Rule2)申請結果" + '\n' +
  '\n====================\n'

Encoded data 

Encoded data