FHIR Extensions Pack
5.1.0-cibuild - Working Copy International flag

FHIR Extensions Pack, published by HL7 International / FHIR Infrastructure. This is not an authorized publication; it is the continuous build for version 5.1.0-cibuild). This version is based on the current content of https://github.com/HL7/fhir-extensions/ and changes regularly. See the Directory of published versions

StructureMap: FML Conversion for Subscription: R4 to R5

Official URL: http://hl7.org/fhir/StructureMap/Subscription4to5 Version: 5.1.0-cibuild
Standards status: Trial-use Maturity Level: 1 Computable Name: Subscription4to5

FMLConversionforSubscriptionR4toR5

/// url = 'http://hl7.org/fhir/StructureMap/Subscription4to5'
/// name = 'Subscription4to5'
/// title = 'FML Conversion for Subscription: R4 to R5'
/// status = 'active'

conceptmap "SubscriptionStatusCodes" {
  prefix s = "http://hl7.org/fhir/4.0/subscription-status"
  prefix t = "http://hl7.org/fhir/subscription-status"

  s:requested - t:requested
  s:active - t:active
  s:error - t:error
  s:off - t:off
}

uses "http://hl7.org/fhir/4.0/StructureDefinition/Subscription" alias SubscriptionR4 as source
uses "http://hl7.org/fhir/StructureDefinition/Subscription" alias SubscriptionR5 as target

imports "http://hl7.org/fhir/StructureMap/*4to5"

group Subscription(source src : SubscriptionR4, target tgt : SubscriptionR5) extends DomainResource <<type+>> {
  src.status as v -> tgt.status = translate(v, '#SubscriptionStatusCodes', 'code'); // src.identifier -> tgt.identifier;
  src.contact -> tgt.contact; // src.topic -> tgt.topic;
  src.end -> tgt.end;
  src.reason -> tgt.reason; // src.managingEntity -> tgt.managingEntity;
  src.channel as s -> tgt then {
    s.type as s1 ->  tgt.channelType = create('Coding') as t,  t.code = s1;
    s.endpoint -> tgt.endpoint;
    s.header as s1 ->  tgt.parameter as t,  t.name = (%s1.substring(0, %s1.indexOf(': '))),  t.value = (%s1.substring(%s1.indexOf(': ') + 1));
    s.payload -> tgt.contentType;
  }; // criteria replaced - see subscriptions backport IG
}