FHIR Extensions Pack
5.1.0-cibuild - Working Copy International flag

FHIR Extensions Pack, published by HL7 International / FHIR Infrastructure. This guide is not an authorized publication; it is the continuous build for version 5.1.0-cibuild built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/HL7/fhir-extensions/ and changes regularly. See the Directory of published versions

StructureMap: FML Conversion for MedicationAdministration: R4 to R5

Official URL: http://hl7.org/fhir/StructureMap/MedicationAdministration4to5 Version: 5.1.0-cibuild
Standards status: Trial-use Maturity Level: 1 Computable Name: MedicationAdministration4to5

FMLConversionforMedicationAdministrationR4toR5

/// url = 'http://hl7.org/fhir/StructureMap/MedicationAdministration4to5'
/// name = 'MedicationAdministration4to5'
/// title = 'FML Conversion for MedicationAdministration: R4 to R5'
/// status = 'active'

conceptmap "MedicationAdministrationStatus" {
  prefix s = "http://terminology.hl7.org/CodeSystem/medication-admin-status"
  prefix t = "http://hl7.org/fhir/CodeSystem/medication-admin-status"

  s:"in-progress" - t:"in-progress"
  s:"not-done" - t:"not-done"
  s:"on-hold" - t:"on-hold"
  s:completed - t:completed
  s:"entered-in-error" - t:"entered-in-error"
  s:stopped - t:stopped
  s:unknown - t:unknown
}

uses "http://hl7.org/fhir/4.0/StructureDefinition/MedicationAdministration" alias MedicationAdministrationR4 as source
uses "http://hl7.org/fhir/StructureDefinition/MedicationAdministration" alias MedicationAdministrationR5 as target

imports "http://hl7.org/fhir/StructureMap/*4to5"

group MedicationAdministration(source src : MedicationAdministrationR4, target tgt : MedicationAdministrationR5) extends DomainResource <<type+>> {
  src.identifier -> tgt.identifier;
  src.partOf -> tgt.partOf; // src.basedOn -> tgt.basedOn;
  src.status as v -> tgt.status = translate(v, '#MedicationAdministrationStatus', 'code');
  src.statusReason -> tgt.statusReason;
  src.category -> tgt.category;
  src.medication : CodeableConcept -> tgt.medication;
  src.medication : Reference -> tgt.medication;
  src.subject -> tgt.subject;
  src.context -> tgt.encounter;
  src.supportingInformation -> tgt.supportingInformation;
  src.effective : dateTime -> tgt.occurence;
  src.effective : Period -> tgt.occurence;
  src.performer as s -> tgt.performer as t then MedicationAdministrationPerformer(s, t); // src.occurence : Timing -> tgt.occurence;
  src.reasonCode -> tgt.reason;
  src.reasonReference -> tgt.reason;
  src.request -> tgt.request;
  src.device -> tgt.device;
  src.note -> tgt.note;
  src.dosage as s -> tgt.dosage as t then MedicationAdministrationDosage(s, t);
  src.eventHistory -> tgt.eventHistory;
}

group MedicationAdministrationPerformer(source src, target tgt) extends BackboneElement {
  src.function -> tgt.function;
  src.actor -> tgt.actor;
}

group MedicationAdministrationDosage(source src, target tgt) extends BackboneElement {
  src.text -> tgt.text;
  src.site -> tgt.site;
  src.route -> tgt.route;
  src.method -> tgt.method;
  src.dose -> tgt.dose;
  src.rate : Ratio -> tgt.rate;
  src.rate : Quantity -> tgt.rate;
}