FHIR Extensions Pack
5.1.0-cibuild - Working Copy International flag

FHIR Extensions Pack, published by HL7 International / FHIR Infrastructure. This guide is not an authorized publication; it is the continuous build for version 5.1.0-cibuild built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/HL7/fhir-extensions/ and changes regularly. See the Directory of published versions

StructureMap: FML Conversion for Group: R5 to R4B

Official URL: http://hl7.org/fhir/StructureMap/Group5to4B Version: 5.1.0-cibuild
Standards status: Trial-use Maturity Level: 1 Computable Name: Group5to4B

FMLConversionforGroupR5toR4B

/// url = 'http://hl7.org/fhir/StructureMap/Group5to4B'
/// name = 'Group5to4B'
/// title = 'FML Conversion for Group: R5 to R4B'
/// status = 'active'

conceptmap "GroupType" {
  prefix s = "http://hl7.org/fhir/group-type"
  prefix t = "http://hl7.org/fhir/4.3/group-type"

  s:person - t:person
  s:animal - t:animal
  s:practitioner - t:practitioner
  s:device - t:device
}

uses "http://hl7.org/fhir/StructureDefinition/Group" alias GroupR5 as source
uses "http://hl7.org/fhir/4.3/StructureDefinition/Group" alias GroupR4B as target

imports "http://hl7.org/fhir/StructureMap/*5to4B"

group Group(source src : GroupR5, target tgt : GroupR4B) extends DomainResource <<type+>> {
  src.identifier -> tgt.identifier;
  src.active -> tgt.active;
  src.type as v -> tgt.type = translate(v, '#GroupType', 'code');
  src.code -> tgt.code; // src.membership as v -> tgt.membership = translate(v, '#group-membership-basis', 'code');
  src.name -> tgt.name;
  src.quantity -> tgt.quantity; // src.description -> tgt.description;
  src.managingEntity -> tgt.managingEntity;
  src.characteristic as s -> tgt.characteristic as t then GroupCharacteristic(s, t);
  src.member as s -> tgt.member as t then GroupMember(s, t);
}

group GroupCharacteristic(source src, target tgt) extends BackboneElement {
  src.code -> tgt.code;
  src.value : CodeableConcept -> tgt.value;
  src.value : boolean -> tgt.value;
  src.value : Quantity -> tgt.value;
  src.value : Range -> tgt.value;
  src.value : Reference -> tgt.value;
  src.exclude -> tgt.exclude;
  src.period -> tgt.period;
}

group GroupMember(source src, target tgt) extends BackboneElement {
  src.entity -> tgt.entity;
  src.period -> tgt.period;
  src.inactive -> tgt.inactive;
}