FHIR Extensions Pack
5.1.0-cibuild - Working Copy International flag

FHIR Extensions Pack, published by HL7 International / FHIR Infrastructure. This is not an authorized publication; it is the continuous build for version 5.1.0-cibuild). This version is based on the current content of https://github.com/HL7/fhir-extensions/ and changes regularly. See the Directory of published versions

StructureMap: FML Conversion for CareTeam: R5 to R4

Official URL: http://hl7.org/fhir/StructureMap/CareTeam5to4 Version: 5.1.0-cibuild
Standards status: Trial-use Maturity Level: 1 Computable Name: CareTeam5to4

FMLConversionforCareTeamR5toR4

/// url = 'http://hl7.org/fhir/StructureMap/CareTeam5to4'
/// name = 'CareTeam5to4'
/// title = 'FML Conversion for CareTeam: R5 to R4'
/// status = 'active'

conceptmap "CareTeamStatus" {
  prefix s = "http://hl7.org/fhir/care-team-status"
  prefix t = "http://hl7.org/fhir/4.0/care-team-status"

  s:proposed - t:proposed
  s:active - t:active
  s:suspended - t:suspended
  s:inactive - t:inactive
  s:"entered-in-error" - t:"entered-in-error"
}

uses "http://hl7.org/fhir/StructureDefinition/CareTeam" alias CareTeamR5 as source
uses "http://hl7.org/fhir/4.0/StructureDefinition/CareTeam" alias CareTeamR4 as target

imports "http://hl7.org/fhir/StructureMap/*5to4"

group CareTeam(source src : CareTeamR5, target tgt : CareTeamR4) extends DomainResource <<type+>> {
  src.identifier -> tgt.identifier;
  src.status as v -> tgt.status = translate(v, '#CareTeamStatus', 'code');
  src.category -> tgt.category;
  src.name -> tgt.name;
  src.subject -> tgt.subject;
  src.period -> tgt.period;
  src.participant as s -> tgt.participant as t then CareTeamParticipant(s, t);
  src.reason -> tgt.reasonCode;
  src.reason -> tgt.reasonReference;
  src.managingOrganization -> tgt.managingOrganization;
  src.telecom -> tgt.telecom;
  src.note -> tgt.note;
}

group CareTeamParticipant(source src, target tgt) extends BackboneElement {
  src.role -> tgt.role;
  src.member -> tgt.member;
  src.onBehalfOf -> tgt.onBehalfOf;
  src.coverage : Period -> tgt.period;
}