FHIR Extensions Pack
5.1.0-cibuild - Working Copy International flag

FHIR Extensions Pack, published by HL7 International / FHIR Infrastructure. This is not an authorized publication; it is the continuous build for version 5.1.0-cibuild). This version is based on the current content of https://github.com/HL7/fhir-extensions/ and changes regularly. See the Directory of published versions

StructureMap: FML Conversion for AdverseEvent: R5 to R4

Official URL: http://hl7.org/fhir/StructureMap/AdverseEvent5to4 Version: 5.1.0-cibuild
Standards status: Trial-use Maturity Level: 1 Computable Name: AdverseEvent5to4

FMLConversionforAdverseEventR5toR4

/// url = 'http://hl7.org/fhir/StructureMap/AdverseEvent5to4'
/// name = 'AdverseEvent5to4'
/// title = 'FML Conversion for AdverseEvent: R5 to R4'
/// status = 'active'

conceptmap "AdverseEventActuality" {
  prefix s = "http://hl7.org/fhir/adverse-event-actuality"
  prefix t = "http://hl7.org/fhir/4.0/adverse-event-actuality"

  s:actual - t:actual
  s:potential - t:potential
}

uses "http://hl7.org/fhir/StructureDefinition/AdverseEvent" alias AdverseEventR5 as source
uses "http://hl7.org/fhir/4.0/StructureDefinition/AdverseEvent" alias AdverseEventR4 as target

imports "http://hl7.org/fhir/StructureMap/*5to4"

group AdverseEvent(source src : AdverseEventR5, target tgt : AdverseEventR4) extends DomainResource <<type+>> {
  src.identifier -> tgt.identifier;
  src.actuality as v -> tgt.actuality = translate(v, '#AdverseEventActuality', 'code'); // src.status -> tgt.status;
  src.category -> tgt.category;
  src.code -> tgt.event;
  src.subject -> tgt.subject;
  src.encounter -> tgt.encounter;
  src.occurrence : dateTime -> tgt.date;
  src.occurrence : Period as v -> tgt.date = v.start "periodDateTime";
  src.occurrence : Timing as v -> tgt.date = v.event "timingDateTime";
  src.detected -> tgt.detected;
  src.recordedDate -> tgt.recordedDate;
  src.resultingEffect -> tgt.resultingCondition;
  src.location -> tgt.location;
  src.seriousness -> tgt.seriousness;
  src.outcome -> tgt.outcome;
  src.recorder -> tgt.recorder;
  src.participant as s -> tgt.contributor as t then AdverseEventParticipant(s, t);
  src.study -> tgt.study;
  src.suspectEntity as s -> tgt.suspectEntity as t then AdverseEventSuspectEntity(s, t); // src.expectedInResearchStudy -> tgt.expectedInResearchStudy;
  src.contributingFactor as s -> tgt.subjectMedicalHistory as t then AdverseEventContributingFactor(s, t);
}

group AdverseEventParticipant(source src, target tgt) extends BackboneElement {
  src.actor as v -> tgt = v "reference"; // src.function -> tgt.function;
}

group AdverseEventSuspectEntity(source src, target tgt) extends BackboneElement {
  src.instance : Reference -> tgt.instance; // src.instance : CodeableConcept -> tgt.instance;
  src.causality as s -> tgt.causality as t then AdverseEventSuspectEntityCausality(s, t);
}

group AdverseEventSuspectEntityCausality(source src, target tgt) extends BackboneElement {
  src.assessmentMethod -> tgt.assessment;
  src.entityRelatedness -> tgt.productRelatedness;
  src.author -> tgt.author;
}

group AdverseEventContributingFactor(source src, target tgt) extends BackboneElement {
  src.item : Reference as v -> tgt = v "reference";
}