Quality Measure Implementation Guide
1.0.0 - STU 1 International flag

Quality Measure Implementation Guide, published by HL7 International / Clinical Quality Information. This guide is not an authorized publication; it is the continuous build for version 1.0.0 built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/HL7/fhir-cqm/ and changes regularly. See the Directory of published versions

Library: EXM124 - Cervical Cancer Screening Library (Experimental)

Official URL: http://hl7.org/fhir/uv/cqm/Library/EXM124 Version: 9.0.000
Standards status: Informative Computable Name: EXM124
Other Identifiers: http://example.org/fhir/cqi/ecqm/Library/Identifier#EXM124 (use: official, ), OID:2.16.840.1.113883.4.642.40.61.28.9

This library is used as an example in the FHIR Quality Measure Implementation Guide

Metadata
Title EXM124 - Cervical Cancer Screening Library
Version 9.0.000
Identifier EXM124
Identifier urn:oid:2.16.840.1.113883.4.642.40.61.28.9
Approval Date 2019-08-03
Last Review Date 2019-08-03
Experimental true
Jurisdiction Global (Whole world)
Steward (Publisher) HL7 International / Clinical Quality Information
Description

This library is used as an example in the FHIR Quality Measure Implementation Guide
Type Logic Library
Parameter Name: Measurement Period
Use: In
Min Cardinality: 0
Max Cardinality: 1
Type: Period
Parameter Name: Patient
Use: Out
Min Cardinality: 0
Max Cardinality: 1
Type: Patient
Parameter Name: SDE Ethnicity
Use: Out
Min Cardinality: 0
Max Cardinality: *
Type: Coding
Parameter Name: SDE Payer
Use: Out
Min Cardinality: 0
Max Cardinality: *
Type: Resource
Parameter Name: SDE Race
Use: Out
Min Cardinality: 0
Max Cardinality: *
Type: Coding
Parameter Name: SDE Sex
Use: Out
Min Cardinality: 0
Max Cardinality: 1
Type: Coding
Parameter Name: Initial Population
Use: Out
Min Cardinality: 0
Max Cardinality: 1
Type: boolean
Parameter Name: Denominator
Use: Out
Min Cardinality: 0
Max Cardinality: 1
Type: boolean
Parameter Name: Absence of Cervix
Use: Out
Min Cardinality: 0
Max Cardinality: *
Type: Resource
Parameter Name: Denominator Exclusion
Use: Out
Min Cardinality: 0
Max Cardinality: 1
Type: boolean
Parameter Name: Cervical Cytology Within 3 Years
Use: Out
Min Cardinality: 0
Max Cardinality: *
Type: Observation
Parameter Name: HPV Test Within 5 Years for Women Age 30 and Older
Use: Out
Min Cardinality: 0
Max Cardinality: *
Type: Observation
Parameter Name: Numerator
Use: Out
Min Cardinality: 0
Max Cardinality: 1
Type: boolean
Data Requirement Type: Patient
Profile(s): Patient
Data Requirement Type: Procedure
Profile(s): Procedure
Must Support Elements: code, performed, status
Code Filter(s):
Path: code
ValueSet: Hysterectomy with No Residual Cervix
Data Requirement Type: Condition
Profile(s): Condition
Must Support Elements: code, onset
Code Filter(s):
Path: code
Code(s): SNOMED CT 37687000: Congenital absence of cervix (disorder) (version = http://snomed.info/sct/731000124108/version/201709 )
Data Requirement Type: Observation
Profile(s): Observation
Must Support Elements: code, value, status, effective
Code Filter(s):
Path: code
ValueSet: Pap Test
Data Requirement Type: Observation
Profile(s): Observation
Must Support Elements: code, value, status, effective
Code Filter(s):
Path: code
ValueSet: HPV Test
Library Content
CQL Content 
/*
This example is a work in progress and should not be considered a final specification
or recommendation for guidance. This example will help guide and direct the process
of finding conventions and usage patterns that meet the needs of the various stakeholders
in the measure development community.

Based on CMS124v9 - Cervical Cancer Screening
*/
library EXM124 version '9.0.000'

using FHIR version '4.0.1'

include hl7.fhir.uv.cql.FHIRHelpers version '4.0.1' called FHIRHelpers

include Hospice version '2.0.000' called Hospice
include AdultOutpatientEncounters version '2.0.000' called AdultOutpatientEncounters
include MATGlobalCommonFunctions version '5.0.000' called Global
include SupplementalDataElements version '2.0.000' called SDE

codesystem "SNOMEDCT:2017-09": 'http://snomed.info/sct' version 'http://snomed.info/sct/731000124108/version/201709'

valueset "Hysterectomy with No Residual Cervix": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1014'
valueset "Pap Test": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1017'
valueset "HPV Test": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.110.12.1059'

code "Congenital absence of cervix (disorder)": '37687000' from "SNOMEDCT:2017-09" display 'Congenital absence of cervix (disorder)'

parameter "Measurement Period" Interval<DateTime>
  default Interval[@2019-01-01T00:00:00.0, @2020-01-01T00:00:00.0)

context Patient

define "SDE Ethnicity":
  SDE."SDE Ethnicity"

define "SDE Payer":
  SDE."SDE Payer"

define "SDE Race":
  SDE."SDE Race"

define "SDE Sex":
  SDE."SDE Sex"

define "Initial Population":
	Patient.gender = 'female'
		and Global."CalendarAgeInYearsAt"(FHIRHelpers.ToDate(Patient.birthDate), start of "Measurement Period") in Interval[23, 64]
		and exists AdultOutpatientEncounters."Qualifying Encounters"

define "Denominator":
	"Initial Population"

define "Denominator Exclusion":
	Hospice."Has Hospice"
		or exists "Absence of Cervix"

define "Absence of Cervix":
  ([Procedure: "Hysterectomy with No Residual Cervix"] NoCervixProcedure
   where Global."Normalize Interval"(NoCervixProcedure.performed) ends on or before end of "Measurement Period"
     and NoCervixProcedure.status = 'completed'
     )
  union [Condition : "Congenital absence of cervix (disorder)"] NoCervixBirth
		where Global."Normalize Interval"(NoCervixBirth.onset) starts on or before end of "Measurement Period"

define "Numerator":
	exists "Cervical Cytology Within 3 Years"
		or exists "HPV Test Within 5 Years for Women Age 30 and Older"

define "Cervical Cytology Within 3 Years":
	[Observation: "Pap Test"] CervicalCytology
		where CervicalCytology.value is not null
			and CervicalCytology.status in { 'final', 'amended', 'corrected', 'preliminary' }
		  and Global."Normalize Interval"(CervicalCytology.effective) ends 3 years or less on or before end of "Measurement Period"

define "HPV Test Within 5 Years for Women Age 30 and Older":
	[Observation: "HPV Test"] HPVTest
      where HPVTest.value is not null
        and HPVTest.status in { 'final', 'amended', 'corrected', 'preliminary' }
        and  Global."CalendarAgeInYearsAt"(FHIRHelpers.ToDate(Patient.birthDate), start of Global."Normalize Interval"(HPVTest.effective))>= 30
        and Global."Normalize Interval"(HPVTest.effective) ends 5 years or less on or before end of "Measurement Period"
ELM XML Content 
Encoded data (77256 characters)
ELM JSON Content 
Encoded data (145132 characters)
Generated using version 0.4.9 of the sample-content-ig Liquid templates