Clinical Practice Guidelines
2.0.0 - STU2 International flag

Clinical Practice Guidelines, published by HL7 International / Clinical Decision Support. This guide is not an authorized publication; it is the continuous build for version 2.0.0 built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/HL7/cqf-recommendations/ and changes regularly. See the Directory of published versions

Library: Resume Medication Library (Experimental)

Official URL: http://hl7.org/fhir/uv/cpg/Library/resumemedication-library Version: 2.0.0
Active as of 2026-04-29 Computable Name: ResumeMedicationLibrary
Other Identifiers: OID:2.16.840.1.113883.4.642.40.48.28.19

Logic for an example recommendation to resume a medication

Metadata
Title Resume Medication Library
Version 2.0.0
Identifier urn:oid:2.16.840.1.113883.4.642.40.48.28.19
Experimental true
Jurisdiction World
Steward (Publisher) HL7 International / Clinical Decision Support
Steward Contact HL7 International / Clinical Decision Support
Description

Logic for an example recommendation to resume a medication
Type logic-library from http://terminology.hl7.org/CodeSystem/library-type
Dependency Description: Code System Activity Type
Resource: CPG Activity Type Code System
Canonical URL: http://hl7.org/fhir/uv/cpg/CodeSystem/cpg-activity-type-cs
Data Requirement Type: MedicationRequest
Profile(s): MedicationRequest
Data Requirement Type: Task
Profile(s): Task
Parameters
Name Use Card. Type Documentation
Patient Out 0..1 Patient
Medication Order On Hold Out 0..* MedicationRequest
Inclusion Criteria Out 0..1 boolean
Resume Medication Proposal Out 0..* Task
Is Recommendation Applicable Out 0..1 boolean
Library Content
CQL Content 
library ResumeMedication

using FHIR version '4.0.1'

include FHIRHelpers version '4.0.1'

codesystem "Activity Type": 'http://hl7.org/fhir/uv/cpg/CodeSystem/cpg-activity-type-cs'

code "Resume Activity": 'resume-activity' from "Activity Type"

context Patient

/* Recommendation to resume an existing order for a medication on hold */

/*
Positive recommendation:

If an on-hold order for the medication exists
  Propose resuming the medication

Given a proposal, the user can:
  Accept the proposal
  Ignore the proposal
  Reject the proposal without reason
  Reject the proposal with reason

Scenario 1: On-hold medication order, no plan or proposal, decision support should propose
Scenario 2: Active medication order, incomplete proposal, decision support should not propose
Scenario 3: Active medication order, rejected proposal, decision support should not propose
Scenario 4: No active medication order, decision support should not propose

*/

define "Medication Order On Hold":
  [MedicationRequest] M
    where M.intent = 'order'
      and M.status = 'on-hold'
      and M.doNotPerform is not true

define "Inclusion Criteria":
  Patient.active
    and exists "Medication Order On Hold"

define "Resume Medication Proposal":
  [Task] T
    where T.code ~ "Resume Activity"
      and doNotPerform(T) is not true

define "Is Recommendation Applicable":
  "Inclusion Criteria"
    and not exists "Resume Medication Proposal"

define function doNotPerform(task Task):
  singleton from (
    task.extension E
      where E.url = 'http://hl7.org/fhir/StructureDefinition/request-doNotPerform'
  ).value as boolean
ELM XML Content 
Encoded data
ELM JSON Content 
Encoded data
Generated using version 0.5.4 of the sample-content-ig Liquid templates