Your User Friendly Name for MyContentIG Here
0.5.3 - CI Build

Your User Friendly Name for MyContentIG Here, published by HL7 International - [Some] Work Group. This guide is not an authorized publication; it is the continuous build for version 0.5.3 built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/cqframework/sample-content-ig/ and changes regularly. See the Directory of published versions

## Library: TJCOverallExample

Official URL: http://somewhere.org/fhir/uv/mycontentig/Library/TJCOverallExample | Version: 0.5.3
Draft as of 2025-12-10 | Computable Name: TJCOverallExample

Metadata
Version | 0.5.3
Status | Draft
Jurisdiction | 001 from http://unstats.un.org/unsd/methods/m49/m49.htm
Steward (Publisher) | HL7 International - [Some] Work Group
Type | logic-library from http://terminology.hl7.org/CodeSystem/library-type
Dependency | Description: Library FHIRHelpers Resource: `http://somewhere.org/fhir/uv/mycontentig/Library/FHIRHelpers|4.0.1` Canonical URL: `http://somewhere.org/fhir/uv/mycontentig/Library/FHIRHelpers|4.0.1`
Dependency | Description: Library CQMCommon Resource: CQMCommonExample Canonical URL: `http://somewhere.org/fhir/uv/mycontentig/Library/CQMCommonExample`
Dependency | Description: Library QICoreCommon Resource: QICoreCommonExample Canonical URL: `http://somewhere.org/fhir/uv/mycontentig/Library/QICoreCommonExample`
Dependency | Description: Value set Comfort Measures Resource: Comfort Measures Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/1.3.6.1.4.1.33895.1.3.0.45`
Dependency | Description: Value set Discharge To Acute Care Facility Resource: Discharge To Acute Care Facility Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.87`
Dependency | Description: Value set Discharged to Health Care Facility for Hospice Care Resource: Discharged to Health Care Facility for Hospice Care Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.207`
Dependency | Description: Value set Discharged to Home for Hospice Care Resource: Discharged to Home for Hospice Care Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.209`
Dependency | Description: Value set Hemorrhagic Stroke Resource: Hemorrhagic Stroke Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.212`
Dependency | Description: Value set Ischemic Stroke Resource: Ischemic Stroke Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.247`
Dependency | Description: Value set Left Against Medical Advice Resource: Left Against Medical Advice Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.308`
Dependency | Description: Value set Nonelective Inpatient Encounter Resource: Non-Elective Inpatient Encounter Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.424`
Dependency | Description: Value set Patient Expired Resource: Patient Expired Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.309`
Data Requirement | Type: Patient Profile(s): QICore Patient
Data Requirement | Type: Encounter Profile(s): QICore Encounter Must Support Elements: type, period, hospitalization, hospitalization.dischargeDisposition Code Filter(s): Path: type ValueSet: Non-Elective Inpatient Encounter
Data Requirement | Type: ServiceRequest Profile(s): QICore ServiceRequest Must Support Elements: code, status, status.value, intent, intent.value, doNotPerform, doNotPerform.value Code Filter(s): Path: code ValueSet: Comfort Measures
Data Requirement | Type: Procedure Profile(s): QICore Procedure Must Support Elements: code, status, status.value Code Filter(s): Path: code ValueSet: Comfort Measures
Parameters
Name | Use | Card. | Type | Documentation
Measurement Period | In | 0..1 | Period |
Patient | Out | 0..1 | Resource |
Non Elective Inpatient Encounter | Out | 0..* | Resource |
All Stroke Encounter | Out | 0..* | Resource |
Encounter with Principal Diagnosis and Age | Out | 0..* | Resource |
Ischemic Stroke Encounter | Out | 0..* | Resource |
Ischemic Stroke Encounters with Discharge Disposition | Out | 0..* | Resource |
Intervention Comfort Measures | Out | 0..* | Resource |
Comfort Measures during Hospitalization | Out | 0..* | Resource |
Encounter with Comfort Measures during Hospitalization | Out | 0..* | Resource |
Library Content
CQL Content |
    library TJCOverallExample version '0.4.1'

    using QICore version '4.1.1'

    include FHIRHelpers version '4.0.1' called FHIRHelpers
    include CQMCommonExample called CQMCommon
    include QICoreCommonExample called QICoreCommon

    valueset "Comfort Measures": 'http://cts.nlm.nih.gov/fhir/ValueSet/1.3.6.1.4.1.33895.1.3.0.45'
    valueset "Discharge To Acute Care Facility": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.87'
    valueset "Discharged to Health Care Facility for Hospice Care": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.207'
    valueset "Discharged to Home for Hospice Care": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.209'
    valueset "Hemorrhagic Stroke": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.212'
    valueset "Ischemic Stroke": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.247'
    valueset "Left Against Medical Advice": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.308'
    valueset "Nonelective Inpatient Encounter": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.424'
    valueset "Patient Expired": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.309'

    parameter "Measurement Period" Interval<DateTime>
      default Interval[@2024-01-01T00:00:00.0, @2025-01-01T00:00:00.0)

    context Patient

    define "Non Elective Inpatient Encounter":
      ["Encounter": "Nonelective Inpatient Encounter"] NonElectiveEncounter
            where NonElectiveEncounter.period ends during day of "Measurement Period"

    define "All Stroke Encounter":
      "Non Elective Inpatient Encounter" NonElectiveEncounter
      let ConditionCode: NonElectiveEncounter.principalDiagnosis().code
        where ( ConditionCode in "Hemorrhagic Stroke"
           or   ConditionCode in "Ischemic Stroke" )

    define "Ischemic Stroke Encounter":
      "Encounter with Principal Diagnosis and Age" EncounterWithAge
        where EncounterWithAge.principalDiagnosis().code in "Ischemic Stroke"

    define "Ischemic Stroke Encounters with Discharge Disposition":
      "Ischemic Stroke Encounter" IschemicStrokeEncounter
      let DischDisp: IschemicStrokeEncounter.hospitalization.dischargeDisposition
      	where  DischDisp in "Discharge To Acute Care Facility"
    		or DischDisp in "Left Against Medical Advice"
    		or DischDisp in "Patient Expired"
    		or DischDisp in "Discharged to Home for Hospice Care"
    		or DischDisp in "Discharged to Health Care Facility for Hospice Care"

    define "Encounter with Principal Diagnosis and Age":
      "All Stroke Encounter" AllStrokeEncounter
        where AgeInYearsAt(date from start of AllStrokeEncounter.period ) >= 18

    define "Comfort Measures during Hospitalization":
      "Ischemic Stroke Encounter" IschemicStrokeEncounter
        with "Intervention Comfort Measures" ComfortMeasure
         such that Coalesce(start of ComfortMeasure.performed.toInterval(), ComfortMeasure.authoredOn) during IschemicStrokeEncounter.hospitalizationWithObservation()

    define "Encounter with Comfort Measures during Hospitalization":
      "Ischemic Stroke Encounter" IschemicStrokeEncounter
        with "Intervention Comfort Measures" ComfortMeasure
         such that Coalesce(start of ComfortMeasure.performed.toInterval(), ComfortMeasure.authoredOn) during IschemicStrokeEncounter.hospitalizationWithObservation()

    define "Intervention Comfort Measures":
      ( ["ServiceRequest": code in "Comfort Measures"] SR
        where SR.status in { 'active', 'completed', 'on-hold' }
          and SR.intent in { 'order', 'original-order', 'reflex-order', 'filler-order', 'instance-order' }
          and SR.doNotPerform is not true
      )
      union ( ["Procedure": "Comfort Measures"] InterventionPerformed
            where InterventionPerformed.status in { 'completed', 'in-progress' }
      )

    define fluent function "TruncateTime"(Value DateTime ):
      DateTime(year from Value, month from Value, day from Value, 0, 0, 0, 0, timezoneoffset from Value)

    define fluent function CalendarDayOfOrDayAfter(StartValue DateTime ):
      Interval[StartValue.TruncateTime(), StartValue.TruncateTime() + 2 days )
ELM XML Content |
    Encoded data
ELM JSON Content |
    Encoded data
Generated using version 0.5.3 of the sample-content-ig Liquid templates