Your User Friendly Name for MyContentIG Here
0.5.3 - CI Build

Your User Friendly Name for MyContentIG Here, published by HL7 International - [Some] Work Group. This guide is not an authorized publication; it is the continuous build for version 0.5.3 built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/cqframework/sample-content-ig/ and changes regularly. See the Directory of published versions

## Library: DischargedonAntithromboticTherapyFHIRExample

Official URL: http://somewhere.org/fhir/uv/mycontentig/Library/DischargedonAntithromboticTherapyFHIRExample | Version: 0.5.3
Draft as of 2025-12-10 | Computable Name: DischargedonAntithromboticTherapyFHIRExample

Metadata
Version | 0.5.3
Status | Draft
Jurisdiction | 001 from http://unstats.un.org/unsd/methods/m49/m49.htm
Steward (Publisher) | HL7 International - [Some] Work Group
Type | logic-library from http://terminology.hl7.org/CodeSystem/library-type
Dependency | Description: Library FHIRHelpers Resource: `http://somewhere.org/fhir/uv/mycontentig/Library/FHIRHelpers|4.0.1` Canonical URL: `http://somewhere.org/fhir/uv/mycontentig/Library/FHIRHelpers|4.0.1`
Dependency | Description: Library CQMCommon Resource: CQMCommonExample Canonical URL: `http://somewhere.org/fhir/uv/mycontentig/Library/CQMCommonExample`
Dependency | Description: Library QICoreCommon Resource: QICoreCommonExample Canonical URL: `http://somewhere.org/fhir/uv/mycontentig/Library/QICoreCommonExample`
Dependency | Description: Library SDE Resource: SupplementalDataElementsExample Canonical URL: `http://somewhere.org/fhir/uv/mycontentig/Library/SupplementalDataElementsExample`
Dependency | Description: Library TJC Resource: TJCOverallExample Canonical URL: `http://somewhere.org/fhir/uv/mycontentig/Library/TJCOverallExample`
Dependency | Description: Value set Antithrombotic Therapy for Ischemic Stroke Resource: Antithrombotic Therapy Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1110.62`
Dependency | Description: Value set Medical Reason For Not Providing Treatment Resource: Medical Reason Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.473`
Dependency | Description: Value set Patient Refusal Resource: Patient Refusal Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.93`
Dependency | Description: Value set Pharmacological Contraindications For Antithrombotic Therapy Resource: Pharmacological Contraindications For Antithrombotic Therapy Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1110.52`
Data Requirement | Type: Patient Profile(s): QICore Patient
Data Requirement | Type: MedicationRequest Profile(s): QICore MedicationRequest Must Support Elements: medication, authoredOn, authoredOn.value, status, status.value, intent, intent.value, doNotPerform, doNotPerform.value Code Filter(s): Path: medication ValueSet: Antithrombotic Therapy
Data Requirement | Type: MedicationRequest Profile(s): QICore MedicationRequest Must Support Elements: medication, authoredOn, authoredOn.value, status, status.value, intent, intent.value, doNotPerform, doNotPerform.value Code Filter(s): Path: medication ValueSet: Pharmacological Contraindications For Antithrombotic Therapy
Data Requirement | Type: MedicationRequest Profile(s): QICore MedicationRequest Must Support Elements: medication.reference.value, authoredOn, authoredOn.value, status, status.value, intent, intent.value, doNotPerform, doNotPerform.value
Data Requirement | Type: Medication Profile(s): QICore Medication Must Support Elements: id.value, code
Data Requirement | Type: MedicationRequest Profile(s): `http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-mednotrequested` Must Support Elements: medication, reasonCode, intent, intent.value, authoredOn, authoredOn.value Code Filter(s): Path: medication ValueSet: Antithrombotic Therapy
Parameters
Name | Use | Card. | Type | Documentation
Measurement Period | In | 0..1 | Period |
Patient | Out | 0..1 | Resource |
Initial Population | Out | 0..* | Resource |
Denominator | Out | 0..* | Resource |
Encounter with Comfort Measures during Hospitalization for Patients with Documented Ischemic Stroke | Out | 0..* | Resource |
Denominator Exclusions | Out | 0..* | Resource |
Numerator | Out | 0..* | Resource |
Antithrombotic Therapy at Discharge | Out | 0..* | Resource |
Reason for Not Giving Antithrombotic at Discharge | Out | 0..* | Resource |
Encounter with Documented Reason for No Antithrombotic At Discharge | Out | 0..* | Resource |
Pharmacological Contraindications for Antithrombotic Therapy at Discharge | Out | 0..* | Resource |
Encounter with Pharmacological Contraindications for Antithrombotic Therapy at Discharge | Out | 0..* | Resource |
Denominator Exceptions | Out | 0..* | Resource |
SDE Ethnicity | Out | 0..1 | Resource |
SDE Payer | Out | 0..* | Resource |
SDE Race | Out | 0..1 | Resource |
SDE Sex | Out | 0..1 | Coding |
Library Content
CQL Content |
    library DischargedonAntithromboticTherapyFHIRExample version '0.5.3-cibuild'

    /* based upon FHIR library DischargedonAntithromboticTherapyFHIR4 version '0.4.000' */
    /* 2023 AU */

    using QICore version '4.1.1'

    include FHIRHelpers version '4.0.1' called FHIRHelpers
    include CQMCommonExample called CQMCommon
    include QICoreCommonExample called QICoreCommon
    include SupplementalDataElementsExample called SDE
    include TJCOverallExample called TJC

    valueset "Antithrombotic Therapy for Ischemic Stroke": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1110.62'
    valueset "Medical Reason For Not Providing Treatment": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.473'
    valueset "Patient Refusal": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.93'
    valueset "Pharmacological Contraindications For Antithrombotic Therapy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1110.52'

    parameter "Measurement Period" Interval<DateTime>
      default Interval[@2024-01-01T00:00:00.0, @2025-01-01T00:00:00.0)

    context Patient

    define "Initial Population":
      TJC."Encounter with Principal Diagnosis and Age"

    define "Denominator":
      TJC."Ischemic Stroke Encounter"

    define "Denominator Exclusions":
      TJC."Ischemic Stroke Encounters with Discharge Disposition"
        union "Encounter with Comfort Measures during Hospitalization for Patients with Documented Ischemic Stroke"

    define "Encounter with Comfort Measures during Hospitalization for Patients with Documented Ischemic Stroke":
      "Denominator" Encounter
        with TJC."Intervention Comfort Measures" ComfortMeasure
          such that Coalesce(start of ComfortMeasure.performed.toInterval(), ComfortMeasure.authoredOn) during Encounter.hospitalizationWithObservation ( )

    define "Numerator":
      TJC."Ischemic Stroke Encounter" IschemicStrokeEncounter
        with ["MedicationRequest": "Antithrombotic Therapy for Ischemic Stroke"] DischargeAntithrombotic
          such that DischargeAntithrombotic.authoredOn during IschemicStrokeEncounter.period

    define "Antithrombotic Therapy at Discharge":
      ["MedicationRequest": "Antithrombotic Therapy for Ischemic Stroke"] Antithrombotic
        where ( Antithrombotic.isCommunity ( )
            or Antithrombotic.isDischarge ( )
        )
          and Antithrombotic.status in { 'active', 'completed' }
          and Antithrombotic.intent in { 'order', 'original-order', 'reflex-order', 'filler-order', 'instance-order' }
          and Antithrombotic.doNotPerform is not true

    define "Denominator Exceptions":
      "Encounter with Documented Reason for No Antithrombotic At Discharge"
        union "Encounter with Pharmacological Contraindications for Antithrombotic Therapy at Discharge"

    define "Encounter with Documented Reason for No Antithrombotic At Discharge":
      TJC."Ischemic Stroke Encounter" IschemicStrokeEncounter
        with "Reason for Not Giving Antithrombotic at Discharge" NoDischargeAntithrombotic
          such that NoDischargeAntithrombotic.authoredOn during IschemicStrokeEncounter.period

    define "Reason for Not Giving Antithrombotic at Discharge":
      ["MedicationNotRequested": "Antithrombotic Therapy for Ischemic Stroke"] NoAntithromboticDischarge
        where ( NoAntithromboticDischarge.reasonCode in "Medical Reason For Not Providing Treatment"
            or NoAntithromboticDischarge.reasonCode in "Patient Refusal"
        )
          and ( NoAntithromboticDischarge.isCommunity ( )
              or NoAntithromboticDischarge.isDischarge ( )
          )
          and NoAntithromboticDischarge.intent in { 'order', 'original-order', 'reflex-order', 'filler-order', 'instance-order' }

    define "Encounter with Pharmacological Contraindications for Antithrombotic Therapy at Discharge":
      TJC."Ischemic Stroke Encounter" IschemicStrokeEncounter
        with "Pharmacological Contraindications for Antithrombotic Therapy at Discharge" DischargePharmacological
          such that DischargePharmacological.authoredOn during IschemicStrokeEncounter.period

    define "Pharmacological Contraindications for Antithrombotic Therapy at Discharge":
      ["MedicationRequest": "Pharmacological Contraindications For Antithrombotic Therapy"] Pharmacological
        where ( Pharmacological.isCommunity ( )
            or Pharmacological.isDischarge ( )
        )
          and Pharmacological.status in { 'active', 'completed' }
          and Pharmacological.intent in { 'order', 'original-order', 'reflex-order', 'filler-order', 'instance-order' }
          and Pharmacological.doNotPerform is not true

    define "SDE Ethnicity":
      SDE."SDE Ethnicity"

    define "SDE Payer":
      SDE."SDE Payer"

    define "SDE Race":
      SDE."SDE Race"

    define "SDE Sex":
      SDE."SDE Sex"
ELM XML Content |
    Encoded data
ELM JSON Content |
    Encoded data
Generated using version 0.5.3 of the sample-content-ig Liquid templates