eCQM QICore Content Implementation Guide
2023.0.0 - CI Build

eCQM QICore Content Implementation Guide, published by cqframework. This guide is not an authorized publication; it is the continuous build for version 2023.0.0 built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/cqframework/ecqm-content-qicore-2023/ and changes regularly. See the Directory of published versions

## Library: SupplementalDataElements

Official URL: http://ecqi.healthit.gov/ecqms/Library/SupplementalDataElements | Version: 3.4.000
Active as of 2023-09-06 | Responsible: ICF | Computable Name: SupplementalDataElements
Other Identifiers: https://madie.cms.gov/login#SupplementalDataElements (use: official, )

This is the QI-Core version of the Supplemental Data Elements library containing the CMS SDE definitions for Payer, Race, Ethnicity and Gender

Id: | SupplementalDataElements
Url: | http://ecqi.healthit.gov/ecqms/Library/SupplementalDataElements
Version: | 3.4.000
Identifier: | value: SupplementalDataElements
Name: | SupplementalDataElements
Title: | SupplementalDataElements
Status: | active
Experimental: | false
Type: | system: http://terminology.hl7.org/CodeSystem/library-type code: logic-library
Date: | 2023-09-06T20:02:05+00:00
Publisher: | ICF
Description: | This is the QI-Core version of the Supplemental Data Elements library containing the CMS SDE definitions for Payer, Race, Ethnicity and Gender
Related Artifacts: | Dependencies
Data Requirements: |
Type | Profile | MS | Code Filter
--- | --- | --- | ---
Coverage |  |  | code filter: path: type value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.3591
Content: text/cql
    /*
    @update: BTR 2020-03-31 ->
    Incremented version to 2.0.0

    @update: BTR 2022-05-26 ->
    Updated FHIR version to 4.0.1
    Updated FHIRHelpers version to 4.0.002
    Updated for AU 2022 Content

    @update: JSR 2023-07-18
    Updated "Payer" value set name to "Payer Type"

    @update: JSR 2023-07-20 ->
    Updated FHIRHelpers version to 4.3.000
    */
    library SupplementalDataElements version '3.4.000'

    using QICore version '4.1.1'

    include FHIRHelpers version '4.3.000' called FHIRHelpers

    valueset "Ethnicity": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.837'
    valueset "ONC Administrative Sex": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1'
    valueset "Payer Type": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.3591'
    valueset "Race": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.836'

    context Patient

    define "SDE Ethnicity":
      Patient.ethnicity E
        return Tuple {
          codes: { E.ombCategory } union E.detailed,
          display: E.text
        }

    define "SDE Payer":
      [Coverage: type in "Payer Type"] Payer
        return {
          code: Payer.type,
          period: Payer.period
        }

    define "SDE Race":
      Patient.race R
        return Tuple {
          codes: R.ombCategory union R.detailed,
          display: R.text
        }

    define "SDE Sex":
      case
          when Patient.gender = 'male' then Code { code: 'M', system: 'http://hl7.org/fhir/v3/AdministrativeGender', display: 'Male' }
          when Patient.gender = 'female' then Code { code: 'F', system: 'http://hl7.org/fhir/v3/AdministrativeGender', display: 'Female' }
          else null
        end
Content: application/elm+xml
    Encoded data (55472 characters)
Content: application/elm+json
    Encoded data (76244 characters)