eCQM QICore Content Implementation Guide
2023.0.0 - CI Build

eCQM QICore Content Implementation Guide, published by cqframework. This guide is not an authorized publication; it is the continuous build for version 2023.0.0 built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/cqframework/ecqm-content-qicore-2023/ and changes regularly. See the Directory of published versions

## Library: PalliativeCare

Official URL: http://ecqi.healthit.gov/ecqms/Library/PalliativeCare | Version: 1.7.000
Active as of 2023-08-14 | Responsible: National Committee for Quality Assurance | Computable Name: PalliativeCare
Other Identifiers: https://madie.cms.gov/login#64b86bc9774bb523d9a1457c (use: official, )

This library contains a definition used to exclude patients receiving palliative care for any part of the measurement period.

Id: | 64b86bc9774bb523d9a1457c
Url: | http://ecqi.healthit.gov/ecqms/Library/PalliativeCare
Version: | 1.7.000
Identifier: | value: 64b86bc9774bb523d9a1457c
Name: | PalliativeCare
Title: | PalliativeCare
Status: | active
Experimental: | false
Type: | system: http://terminology.hl7.org/CodeSystem/library-type code: logic-library
Date: | 2023-08-14T15:19:28+00:00
Publisher: | National Committee for Quality Assurance
Description: | This library contains a definition used to exclude patients receiving palliative care for any part of the measurement period.
Related Artifacts: | Dependencies
Data Requirements: |
Type | Profile | MS | Code Filter
--- | --- | --- | ---
Observation |  |  | code filter: path: code system: http://loinc.org code: 71007-9 display: Functional Assessment of Chronic Illness Therapy - Palliative Care Questionnaire (FACIT-Pal)
Condition |  |  | code filter: path: code value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.1167
Encounter |  |  | code filter: path: code value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1090
Procedure |  |  | code filter: path: code value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1135
Content: text/cql
    library PalliativeCare version '1.7.000'

    using QICore version '4.1.1'

    include FHIRHelpers version '4.3.000' called FHIRHelpers
    include QICoreCommon version '1.5.000' called QICoreCommon
    include Status version '1.6.000' called Status

    codesystem "LOINC": 'http://loinc.org'

    valueset "Palliative Care Encounter": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1090'
    valueset "Palliative Care Intervention": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1135'
    valueset "Palliative Care Diagnosis": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.1167'

    code "Functional Assessment of Chronic Illness Therapy - Palliative Care Questionnaire (FACIT-Pal)": '71007-9' from "LOINC" display 'Functional Assessment of Chronic Illness Therapy - Palliative Care Questionnaire (FACIT-Pal)'

    parameter "Measurement Period" Interval<DateTime>

    context Patient

    define "Has Palliative Care in the Measurement Period":
      exists ((([Observation: "Functional Assessment of Chronic Illness Therapy - Palliative Care Questionnaire (FACIT-Pal)"]).isAssessmentPerformed()) PalliativeAssessment
          where PalliativeAssessment.effective.toInterval() overlaps day of "Measurement Period"
      )
        or exists ([Condition: "Palliative Care Diagnosis"] PalliativeDiagnosis
            where PalliativeDiagnosis.prevalenceInterval() overlaps day of "Measurement Period"
        )
        or exists ((([Encounter: "Palliative Care Encounter"]).isEncounterPerformed()) PalliativeEncounter
            where PalliativeEncounter.period.toInterval() overlaps day of "Measurement Period"
        )
        or exists ((([Procedure: "Palliative Care Intervention"]).isInterventionPerformed()) PalliativeIntervention
            where PalliativeIntervention.performed.toInterval() overlaps day of "Measurement Period"
        )
Content: application/elm+xml
    Encoded data (59160 characters)
Content: application/elm+json
    Encoded data (83384 characters)