eCQM QICore Content Implementation Guide
2023.0.0 - CI Build

eCQM QICore Content Implementation Guide, published by cqframework. This guide is not an authorized publication; it is the continuous build for version 2023.0.0 built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/cqframework/ecqm-content-qicore-2023/ and changes regularly. See the Directory of published versions

## Library: DischargedonAntithromboticTherapyFHIR

Official URL: http://ecqi.healthit.gov/ecqms/Library/DischargedonAntithromboticTherapyFHIR | Version: 0.8.000
Active as of 2023-08-01 | Computable Name: DischargedonAntithromboticTherapyFHIR
Other Identifiers: https://madie.cms.gov/login#DischargedonAntithromboticTherapyFHIR (use: official, )
Usage:Program: EH/CAH

DischargedonAntithromboticTherapyFHIR

Id: | DischargedonAntithromboticTherapyFHIR
Url: | http://ecqi.healthit.gov/ecqms/Library/DischargedonAntithromboticTherapyFHIR
Version: | 0.8.000
Identifier: | value: DischargedonAntithromboticTherapyFHIR
Name: | DischargedonAntithromboticTherapyFHIR
Title: | DischargedonAntithromboticTherapyFHIR
Status: | active
Experimental: | false
Type: | system: http://terminology.hl7.org/CodeSystem/library-type code: logic-library
Date: | 2023-08-01T14:34:09+00:00
Description: | DischargedonAntithromboticTherapyFHIR
Use Context: |
code | value | display
--- | --- | ---
program | eh-cah | EH/CAH
Related Artifacts: | Dependencies
Data Requirements: |
Type | Profile | MS | Code Filter
--- | --- | --- | ---
Patient | http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-patient |  |
Patient | http://hl7.org/fhir/Patient | ;; |
Encounter | http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-encounter | ;; | code filter: path: type value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.424
Condition | http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-condition | ;; |
Condition | http://hl7.org/fhir/Condition | ; |
Encounter | http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-encounter | ;; | code filter: path: type value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.424
Patient | http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-patient |  |
MedicationRequest | http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-medicationrequest | ; | code filter: path: medication value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1110.62
MedicationRequest | http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-medicationrequest | ; | code filter: path: medication value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1110.62
Coverage | http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-coverage | ;; | code filter: path: type value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.3591
uri | http://hl7.org/fhir/uri | ; |
Patient | http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-patient | ;; |
Patient | http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-patient | ;; |
ServiceRequest | http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-servicerequest | ;;;;;;; | code filter: path: code value set: http://cts.nlm.nih.gov/fhir/ValueSet/1.3.6.1.4.1.33895.1.3.0.45
Procedure | http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-procedure | ;;; | code filter: path: code value set: http://cts.nlm.nih.gov/fhir/ValueSet/1.3.6.1.4.1.33895.1.3.0.45
Encounter | http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-encounter | ;;;; | code filter: path: type value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1111.143
Encounter | http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-encounter | ;;;; | code filter: path: type value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.292
Encounter | http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-encounter | ;;;; | code filter: path: type value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1111.143
Encounter | http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-encounter | ;;;; | code filter: path: type value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.292
Patient | http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-patient | ;; |
Patient | http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-patient | ;; |
MedicationRequest | http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-mednotrequested | ; | code filter: path: medication value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1110.62
MedicationRequest | http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-mednotrequested | ; | code filter: path: medication value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1110.62
MedicationRequest | http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-medicationrequest | ; | code filter: path: medication value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1110.52
MedicationRequest | http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-medicationrequest | ; | code filter: path: medication value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1110.52
Coverage | http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-coverage | ;; | code filter: path: type value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.3591
Patient | http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-patient | ;; |
Patient | http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-patient | ;; |
Content: text/cql
    library DischargedonAntithromboticTherapyFHIR version '0.8.000'

    /* based upon FHIR library DischargedonAntithromboticTherapyFHIR4 version '0.4.000' */
    /* 2023 AU */

    using QICore version '4.1.1'

    include FHIRHelpers version '4.3.000' called FHIRHelpers
    include CQMCommon version '1.4.000' called CQMCommon
    include QICoreCommon version '1.5.000' called QICoreCommon
    include SupplementalDataElements version '3.4.000' called SDE
    include TJCOverall version '8.9.000' called TJC

    valueset "Antithrombotic Therapy for Ischemic Stroke": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1110.62'
    valueset "Medical Reason For Not Providing Treatment": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.473'
    valueset "Patient Refusal": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.93'
    valueset "Pharmacological Contraindications For Antithrombotic Therapy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1110.52'

    parameter "Measurement Period" Interval<DateTime>

    context Patient

    define "Initial Population":
      TJC."Encounter with Principal Diagnosis and Age"

    define "Denominator":
      TJC."Ischemic Stroke Encounter"

    define "Denominator Exclusions":
      TJC."Ischemic Stroke Encounters with Discharge Disposition"
        union "Encounter with Comfort Measures during Hospitalization for Patients with Documented Ischemic Stroke"

    define "Encounter with Comfort Measures during Hospitalization for Patients with Documented Ischemic Stroke":
      "Denominator" Encounter
        with TJC."Intervention Comfort Measures" ComfortMeasure
          such that Coalesce(start of ComfortMeasure.performed.toInterval(), ComfortMeasure.authoredOn) during Encounter.hospitalizationWithObservation ( )

    define "Numerator":
      TJC."Ischemic Stroke Encounter" IschemicStrokeEncounter
        with ["MedicationRequest": "Antithrombotic Therapy for Ischemic Stroke"] DischargeAntithrombotic
          such that DischargeAntithrombotic.authoredOn during IschemicStrokeEncounter.period

    define "Antithrombotic Therapy at Discharge":
      ["MedicationRequest": "Antithrombotic Therapy for Ischemic Stroke"] Antithrombotic
        where ( Antithrombotic.isCommunity ( )
            or Antithrombotic.isDischarge ( )
        )
          and Antithrombotic.status in { 'active', 'completed' }
          and Antithrombotic.intent in { 'order', 'original-order', 'reflex-order', 'filler-order', 'instance-order' }
          and Antithrombotic.doNotPerform is not true

    define "Denominator Exceptions":
      "Encounter with Documented Reason for No Antithrombotic At Discharge"
        union "Encounter with Pharmacological Contraindications for Antithrombotic Therapy at Discharge"

    define "Encounter with Documented Reason for No Antithrombotic At Discharge":
      TJC."Ischemic Stroke Encounter" IschemicStrokeEncounter
        with "Reason for Not Giving Antithrombotic at Discharge" NoDischargeAntithrombotic
          such that NoDischargeAntithrombotic.authoredOn during IschemicStrokeEncounter.period

    define "Reason for Not Giving Antithrombotic at Discharge":
      ["MedicationNotRequested": "Antithrombotic Therapy for Ischemic Stroke"] NoAntithromboticDischarge
        where ( NoAntithromboticDischarge.reasonCode in "Medical Reason For Not Providing Treatment"
            or NoAntithromboticDischarge.reasonCode in "Patient Refusal"
        )
          and ( NoAntithromboticDischarge.isCommunity ( )
              or NoAntithromboticDischarge.isDischarge ( )
          )
          and NoAntithromboticDischarge.intent in { 'order', 'original-order', 'reflex-order', 'filler-order', 'instance-order' }

    define "Encounter with Pharmacological Contraindications for Antithrombotic Therapy at Discharge":
      TJC."Ischemic Stroke Encounter" IschemicStrokeEncounter
        with "Pharmacological Contraindications for Antithrombotic Therapy at Discharge" DischargePharmacological
          such that DischargePharmacological.authoredOn during IschemicStrokeEncounter.period

    define "Pharmacological Contraindications for Antithrombotic Therapy at Discharge":
      ["MedicationRequest": "Pharmacological Contraindications For Antithrombotic Therapy"] Pharmacological
        where ( Pharmacological.isCommunity ( )
            or Pharmacological.isDischarge ( )
        )
          and Pharmacological.status in { 'active', 'completed' }
          and Pharmacological.intent in { 'order', 'original-order', 'reflex-order', 'filler-order', 'instance-order' }
          and Pharmacological.doNotPerform is not true

    define "SDE Ethnicity":
      SDE."SDE Ethnicity"

    define "SDE Payer":
      SDE."SDE Payer"

    define "SDE Race":
      SDE."SDE Race"

    define "SDE Sex":
      SDE."SDE Sex"
Content: application/elm+xml
    Encoded data (108784 characters)
Content: application/elm+json
    Encoded data (154080 characters)