dQM QICore Content Implementation Guide
2026.0.0 - CI Build

dQM QICore Content Implementation Guide, published by cqframework. This guide is not an authorized publication; it is the continuous build for version 2026.0.0 built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/cqframework/dqm-content-qicore-2026/ and changes regularly. See the Directory of published versions

## Library: Supplemental Data Elements

Official URL: https://madie.cms.gov/Library/SupplementalDataElements | Version: 2026.0.0
Standards status: Informative | Maturity Level: 1 | Computable Name: SupplementalDataElements

SupplementalDataElements logic.

Metadata
Title | Supplemental Data Elements
Version | 2026.0.0
Topic | FHIR
Topic | CQL
Description | SupplementalDataElements logic.
Type | logic-library from http://terminology.hl7.org/CodeSystem/library-type
Parameter | Name: Patient Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: Resource
Parameter | Name: SDE Ethnicity Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: Resource
Parameter | Name: SDE Payer Use: Out Min Cardinality: 0 Max Cardinality: * Type: Resource
Parameter | Name: SDE Race Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: Resource
Parameter | Name: SDE Sex Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: Coding
Data Requirement | Type: Coverage Profile(s): QICore Coverage Code Filter(s): Path: type ValueSet: Payer Type
Library Content
CQL Content |
    /*
    @description: Supplemental data elements for use in digital quality measure specifications in CMS programs

    NOTE: This library is not published in this IG, it is included here for convenience. The source of truth for
    this library will be the MADiE environment once it fully supports use of QICore STU7.
    */
    library SupplementalDataElements version '6.0.000'

    using QICore version '7.0.2'
    using USCore version '7.0.0'
    using FHIR version '4.0.1'

    include hl7.fhir.uv.cql.FHIRHelpers version '4.0.1' called FHIRHelpers
    include hl7.fhir.uv.cql.FHIRCommon version '2.0.0' called FHIRCommon
    include hl7.fhir.us.cql.USCoreCommon called USCommon
    include QICoreCommon

    codesystem "SNOMEDCT": 'http://snomed.info/sct'

    valueset "Ethnicity": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.837'
    valueset "Federal Administrative Sex": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1021.121'
    valueset "Payer Type": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.3591'
    valueset "Race": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.836'

    code "Male (finding)": '248153007' from "SNOMEDCT" display 'Male (finding)'
    code "Female (finding)": '248152002' from "SNOMEDCT" display 'Female (finding)'

    context Patient

    define "SDE Ethnicity":
      (Patient.ethnicity()) E
        return Tuple {
          codes: { E.ombCategory } union E.detailed,
          display: E.text
        }

    define "SDE Payer":
      [QICore.Coverage: type in "Payer Type"] Payer
        return {
          code: Payer.type,
          period: Payer.period
        }

    define "SDE Race":
      (Patient.race()) R
        return Tuple {
          codes: R.ombCategory union R.detailed,
          display: R.text
        }

    define "SDE Sex":
      case
        when Patient.sex() = '248153007' then "Male (finding)"
        when Patient.sex() = '248152002' then "Female (finding)"
        else null
      end
ELM XML Content |
    Encoded data (34836 characters)
ELM JSON Content |
    Encoded data (61952 characters)
Generated using version 0.5.0 of the sample-content-ig Liquid templates