dQM QICore Content Implementation Guide
2026.0.0 - CI Build

dQM QICore Content Implementation Guide, published by cqframework. This guide is not an authorized publication; it is the continuous build for version 2026.0.0 built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/cqframework/dqm-content-qicore-2026/ and changes regularly. See the Directory of published versions

## Library: Palliative Care

Official URL: https://madie.cms.gov/Library/PalliativeCare | Version: 2026.0.0
Standards status: Informative | Maturity Level: 1 | Computable Name: PalliativeCare

PalliativeCare logic.

Metadata
Title | Palliative Care
Version | 2026.0.0
Topic | FHIR
Topic | CQL
Description | PalliativeCare logic.
Type | logic-library from http://terminology.hl7.org/CodeSystem/library-type
Parameter | Name: Measurement Period Use: In Min Cardinality: 0 Max Cardinality: 1 Type: Period
Parameter | Name: Patient Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: Resource
Parameter | Name: Has Palliative Care in the Measurement Period Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: boolean
Data Requirement | Type: Observation Profile(s): QICore Observation Screening Assessment Code Filter(s): Path: code Code(s): LOINC: 71007-9 (Functional Assessment of Chronic Illness Therapy - Palliative Care Questionnaire (FACIT-Pal))
Data Requirement | Type: Condition Profile(s): Condition Code Filter(s): Path: code ValueSet: Palliative Care Diagnosis
Data Requirement | Type: Encounter Profile(s): QICore Encounter Code Filter(s): Path: type ValueSet: Palliative Care Encounter
Data Requirement | Type: Procedure Profile(s): QICore Procedure Code Filter(s): Path: code ValueSet: Palliative Care Intervention
Library Content
CQL Content |
    /*
    NOTE: For use by January 2026 Connectathon participants for internal use only. Not for use or distribution in commercial products.
    */
    library PalliativeCare version '2.0.000'

    using QICore version '7.0.2'
    using USCore version '7.0.0'
    using FHIR version '4.0.1'

    include hl7.fhir.uv.cql.FHIRHelpers version '4.0.1' called FHIRHelpers
    include hl7.fhir.uv.cql.FHIRCommon version '2.0.0' called FHIRCommon
    include Status version '2.0.000' called Status

    codesystem "LOINC": 'http://loinc.org'

    valueset "Palliative Care Encounter": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1090'
    valueset "Palliative Care Intervention": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1135'
    valueset "Palliative Care Diagnosis": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.1167'

    code "Functional Assessment of Chronic Illness Therapy - Palliative Care Questionnaire (FACIT-Pal)": '71007-9' from "LOINC" display 'Functional Assessment of Chronic Illness Therapy - Palliative Care Questionnaire (FACIT-Pal)'

    parameter "Measurement Period" Interval<DateTime>

    context Patient

    define "Has Palliative Care in the Measurement Period":
      // TODO: Shouldn't need to specify a code path here (see https://jira.hl7.org/browse/FHIR-53941)
      exists ((([ObservationScreeningAssessment: code ~ "Functional Assessment of Chronic Illness Therapy - Palliative Care Questionnaire (FACIT-Pal)"]).isAssessmentPerformed()) PalliativeAssessment
          where PalliativeAssessment.effective.toInterval() overlaps day of "Measurement Period"
      )
        // TODO: Consider whether to keep this as the union of the problems and encounter diagnosis list? Anything enforced by the profiles that is expected but isn't stated here?
        or exists ((([Condition: "Palliative Care Diagnosis"]).verified()) PalliativeDiagnosis
            where PalliativeDiagnosis.prevalenceInterval() overlaps day of "Measurement Period"
        )
        or exists ((([QICore.Encounter: "Palliative Care Encounter"]).isEncounterPerformed()) PalliativeEncounter
            where PalliativeEncounter.period overlaps day of "Measurement Period"
        )
        or exists ((([QICore.Procedure: "Palliative Care Intervention"]).isInterventionPerformed()) PalliativeIntervention
            where PalliativeIntervention.performed.toInterval() overlaps day of "Measurement Period"
        )
ELM XML Content |
    Encoded data (44412 characters)
ELM JSON Content |
    Encoded data (81860 characters)
Generated using version 0.5.0 of the sample-content-ig Liquid templates