dQM QICore Content Implementation Guide
2025.0.0 - CI Build

dQM QICore Content Implementation Guide, published by cqframework. This guide is not an authorized publication; it is the continuous build for version 2025.0.0 built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/cqframework/dqm-content-qicore-2025/ and changes regularly. See the Directory of published versions

Library: CMS131FHIRDiabetesEyeExam

Official URL: https://madie.cms.gov/Library/CMS131FHIRDiabetesEyeExam Version: 1.0.000
Active as of 2025-07-25 Responsible: National Committee for Quality Assurance Computable Name: CMS131FHIRDiabetesEyeExam
Other Identifiers: https://madie.cms.gov/login#CMS131FHIRDiabetesEyeExam (use: official, )

CMS131FHIRDiabetesEyeExam

Metadata
Title CMS131FHIRDiabetesEyeExam
Version 1.0.000
Identifier CMS131FHIRDiabetesEyeExam
Steward (Publisher) National Committee for Quality Assurance
Description

CMS131FHIRDiabetesEyeExam
Type http://terminology.hl7.org/CodeSystem/library-type#logic-library
Data Requirement Type: Patient
Profile(s): http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-patient
Data Requirement Type: Encounter
Profile(s): http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-encounter
Must Support Elements: type
Code Filter(s):
Path: type
ValueSet: Office Visit
Data Requirement Type: Encounter
Profile(s): http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-encounter
Must Support Elements: type
Code Filter(s):
Path: type
ValueSet: Annual Wellness Visit
Data Requirement Type: Encounter
Profile(s): http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-encounter
Must Support Elements: type
Code Filter(s):
Path: type
ValueSet: Preventive Care Services Established Office Visit, 18 and Up
Data Requirement Type: Encounter
Profile(s): http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-encounter
Must Support Elements: type
Code Filter(s):
Path: type
ValueSet: Preventive Care Services Initial Office Visit, 18 and Up
Data Requirement Type: Encounter
Profile(s): http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-encounter
Must Support Elements: type
Code Filter(s):
Path: type
ValueSet: Home Healthcare Services
Data Requirement Type: Encounter
Profile(s): http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-encounter
Must Support Elements: type
Code Filter(s):
Path: type
ValueSet: Ophthalmological Services
Data Requirement Type: Encounter
Profile(s): http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-encounter
Must Support Elements: type
Code Filter(s):
Path: type
ValueSet: Telephone Visits
Data Requirement Type: Condition
Profile(s): http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-condition-encounter-diagnosis
Must Support Elements: code
Code Filter(s):
Path: code
ValueSet: Diabetes
Data Requirement Type: Condition
Profile(s): http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-condition-problems-health-concerns
Must Support Elements: code
Code Filter(s):
Path: code
Code(s): SNOMED CT: 15665641000119103 (Anophthalmos of bilateral eyes (disorder))
Data Requirement Type: Condition
Profile(s): http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-condition-encounter-diagnosis
Must Support Elements: code
Code Filter(s):
Path: code
Code(s): SNOMED CT: 15665641000119103 (Anophthalmos of bilateral eyes (disorder))
Data Requirement Type: Condition
Profile(s): http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-condition-problems-health-concerns
Must Support Elements: code
Code Filter(s):
Path: code
ValueSet: Diabetic Retinopathy
Data Requirement Type: Condition
Profile(s): http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-condition-encounter-diagnosis
Must Support Elements: code
Code Filter(s):
Path: code
ValueSet: Diabetic Retinopathy
Data Requirement Type: Observation
Profile(s): http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-observation-clinical-result
Must Support Elements: code, effective
Code Filter(s):
Path: code
ValueSet: Retinal or Dilated Eye Exam
Data Requirement Type: Observation
Profile(s): http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-observation-clinical-result
Must Support Elements: code, value, effective
Code Filter(s):
Path: code
Code(s): LOINC: 105914-6 (Eye Diabetic retinopathy screening Autonomous artificial intelligence)
Data Requirement Type: Observation
Profile(s): http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-observation-clinical-result
Must Support Elements: code, value, effective
Code Filter(s):
Path: code
Code(s): LOINC: 71491-5 (Right eye Diabetic retinopathy severity level by Ophthalmoscopy)
Data Requirement Type: Observation
Profile(s): http://hl7.org/fhir/us/qicore/StructureDefinition/qicore-observation-clinical-result
Must Support Elements: code, value, effective
Code Filter(s):
Path: code
Code(s): LOINC: 71490-7 (Left eye Diabetic retinopathy severity level by Ophthalmoscopy)
Parameters
Name Use Card. Type Documentation
Measurement Period In 0..1 Period
Patient Out 0..1 Resource
Qualifying Encounters Out 0..* Resource
Initial Population Out 0..1 boolean
Denominator Out 0..1 boolean
Bilateral Absence of Eyes Out 0..1 boolean
Denominator Exclusions Out 0..1 boolean
Diabetic Retinopathy Overlapping Measurement Period Out 0..1 boolean
Retinal Exam in Measurement Period Out 0..1 boolean
Retinal Exam in Measurement Period or Year Prior Out 0..1 boolean
Autonomous Eye Exam in Measurement Period Out 0..1 boolean
Has Left Eye Retinopathy Out 0..1 boolean
Has Right Eye Retinopathy Out 0..1 boolean
Has Right Eye No Retinopathy in Year Prior Out 0..1 boolean
Has Left Eye No Retinopathy in Year Prior Out 0..1 boolean
Retinal Exam Finding with Retinopathy Severity Level in Measurement Period Out 0..1 boolean
Retinal Exam Finding with No Retinopathy Severity Level in Year Prior Out 0..1 boolean
Numerator Out 0..1 boolean
SDE Ethnicity Out 0..1 Resource
SDE Payer Out 0..* Resource
SDE Race Out 0..1 Resource
SDE Sex Out 0..1 Coding
Library Content
CQL Content 
library CMS131FHIRDiabetesEyeExam version '1.0.000'

using QICore version '6.0.0'

include FHIRHelpers version '4.4.000' called FHIRHelpers
include SupplementalDataElements version '5.1.000' called SDE
include QICoreCommon version '4.0.000' called QICoreCommon
include Hospice version '6.18.000' called Hospice
include Status version '1.15.000' called Status
include PalliativeCare version '1.18.000' called PalliativeCare
include AdvancedIllnessandFrailty version '1.27.000' called AIFrailLTCF

codesystem "LOINC": 'http://loinc.org'
codesystem "SNOMEDCT": 'http://snomed.info/sct'

valueset "Annual Wellness Visit": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.526.3.1240'
valueset "Autonomous Eye Exam Result or Finding": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1004.2616'
valueset "Diabetes": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.103.12.1001'
valueset "Diabetic Retinopathy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.526.3.327'
valueset "Diabetic Retinopathy Severity Level": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.1266'
valueset "Home Healthcare Services": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1016'
valueset "Office Visit": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1001'
valueset "Ophthalmological Services": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.526.3.1285'
valueset "Preventive Care Services Established Office Visit, 18 and Up": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1025'
valueset "Preventive Care Services Initial Office Visit, 18 and Up": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1023'
valueset "Retinal or Dilated Eye Exam": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.115.12.1088'
valueset "Telephone Visits": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1080'

code "Anophthalmos of bilateral eyes (disorder)": '15665641000119103' from "SNOMEDCT" display 'Anophthalmos of bilateral eyes (disorder)'
code "Eye Diabetic retinopathy screening Autonomous artificial intelligence": '105914-6' from "LOINC" display 'Eye Diabetic retinopathy screening Autonomous artificial intelligence'
code "Left eye Diabetic retinopathy severity level by Ophthalmoscopy": '71490-7' from "LOINC" display 'Left eye Diabetic retinopathy severity level by Ophthalmoscopy'
code "No apparent retinopathy": 'LA18643-9' from "LOINC" display 'No apparent retinopathy'
code "Right eye Diabetic retinopathy severity level by Ophthalmoscopy": '71491-5' from "LOINC" display 'Right eye Diabetic retinopathy severity level by Ophthalmoscopy'

parameter "Measurement Period" Interval<DateTime>
  default Interval[@2026-01-01T00:00:00.000Z, @2027-01-01T00:00:00.000Z)

context Patient

define "Initial Population":
  AgeInYearsAt(date from 
    end of "Measurement Period"
  ) in Interval[18, 75]
    and exists ( "Qualifying Encounters" )
    and exists ( ( ( [ConditionEncounterDiagnosis: "Diabetes"] ).verified ( ) ) DiabetesDx
        where DiabetesDx.prevalenceInterval ( ) overlaps day of "Measurement Period"
    )

define "Qualifying Encounters":
  ( ( [Encounter: "Office Visit"]
      union [Encounter: "Annual Wellness Visit"]
      union [Encounter: "Preventive Care Services Established Office Visit, 18 and Up"]
      union [Encounter: "Preventive Care Services Initial Office Visit, 18 and Up"]
      union [Encounter: "Home Healthcare Services"]
      union [Encounter: "Ophthalmological Services"]
      union [Encounter: "Telephone Visits"]
  ).isEncounterPerformed ( ) ) ValidEncounters
    where ValidEncounters.period during day of "Measurement Period"

define "Denominator":
  "Initial Population"

define "Denominator Exclusions":
  Hospice."Has Hospice Services"
    or AIFrailLTCF."Is Age 66 or Older with Advanced Illness and Frailty"
    or AIFrailLTCF."Is Age 66 or Older Living Long Term in a Nursing Home"
    or PalliativeCare."Has Palliative Care in the Measurement Period"
    or "Bilateral Absence of Eyes"

define "Numerator":
  ( "Diabetic Retinopathy Overlapping Measurement Period"
      and ( "Retinal Exam in Measurement Period" )
  )
    or ( not ( "Diabetic Retinopathy Overlapping Measurement Period" )
        and ( "Retinal Exam in Measurement Period or Year Prior" )
    )
    or "Autonomous Eye Exam in Measurement Period"
    or "Retinal Exam Finding with Retinopathy Severity Level in Measurement Period"
    or "Retinal Exam Finding with No Retinopathy Severity Level in Year Prior"

define "Autonomous Eye Exam in Measurement Period":
  exists ( ( [ObservationClinicalResult: "Eye Diabetic retinopathy screening Autonomous artificial intelligence"] ).isPhysicalExamPerformed ( ) ) AutonomousEyeExam
    where AutonomousEyeExam.value as Concept in "Autonomous Eye Exam Result or Finding"
      and AutonomousEyeExam.effective.toInterval ( ) during day of "Measurement Period"

define "Bilateral Absence of Eyes":
  exists ( ( [ConditionProblemsHealthConcerns: "Anophthalmos of bilateral eyes (disorder)"]
      union [ConditionEncounterDiagnosis: "Anophthalmos of bilateral eyes (disorder)"]
  ).verified ( ) ) BilateralAbsenceEyes
    where BilateralAbsenceEyes.prevalenceInterval ( ) starts on or before day of end of "Measurement Period"

define "Retinal Exam in Measurement Period":
  exists ( ( [ObservationClinicalResult: "Retinal or Dilated Eye Exam"] ).isPhysicalExamPerformed ( ) ) RetinalExam
    where RetinalExam.effective.toInterval ( ) during day of "Measurement Period"

define "Retinal Exam in Measurement Period or Year Prior":
  exists ( ( [ObservationClinicalResult: "Retinal or Dilated Eye Exam"] ).isPhysicalExamPerformed ( ) ) RetinalExam
    where RetinalExam.effective.toInterval ( ) during day of Interval[start of "Measurement Period" - 1 year, end of "Measurement Period"]

define "Diabetic Retinopathy Overlapping Measurement Period":
  exists ( ( [ConditionProblemsHealthConcerns: "Diabetic Retinopathy"]
      union [ConditionEncounterDiagnosis: "Diabetic Retinopathy"]
  ).verified ( ) ) Retinopathy
    where Retinopathy.prevalenceInterval ( ) overlaps day of "Measurement Period"

define "Has Left Eye No Retinopathy in Year Prior":
  exists ( ( [ObservationClinicalResult: "Left eye Diabetic retinopathy severity level by Ophthalmoscopy"] ).isPhysicalExamPerformed ( ) ) LeftEyeNoRetinopathy
    where LeftEyeNoRetinopathy.value ~ "No apparent retinopathy"
      and LeftEyeNoRetinopathy.effective.toInterval ( ) during day of Interval[start of "Measurement Period" - 1 year, end of "Measurement Period" - 1 year]

define "Has Left Eye Retinopathy":
  exists ( ( [ObservationClinicalResult: "Left eye Diabetic retinopathy severity level by Ophthalmoscopy"] ).isPhysicalExamPerformed ( ) ) LeftEyeRetinopathy
    where LeftEyeRetinopathy.value as Concept in "Diabetic Retinopathy Severity Level"
      and LeftEyeRetinopathy.effective.toInterval ( ) during day of "Measurement Period"

define "Has Right Eye No Retinopathy in Year Prior":
  exists ( ( [ObservationClinicalResult: "Right eye Diabetic retinopathy severity level by Ophthalmoscopy"] ).isPhysicalExamPerformed ( ) ) RightEyeNoRetinopathy
    where RightEyeNoRetinopathy.value ~ "No apparent retinopathy"
      and RightEyeNoRetinopathy.effective.toInterval ( ) during day of Interval[start of "Measurement Period" - 1 year, end of "Measurement Period" - 1 year]

define "Has Right Eye Retinopathy":
  exists ( ( [ObservationClinicalResult: "Right eye Diabetic retinopathy severity level by Ophthalmoscopy"] ).isPhysicalExamPerformed ( ) ) RightEyeRetinopathy
    where RightEyeRetinopathy.value as Concept in "Diabetic Retinopathy Severity Level"
      and RightEyeRetinopathy.effective.toInterval ( ) during day of "Measurement Period"

define "Retinal Exam Finding with No Retinopathy Severity Level in Year Prior":
  ( "Has Left Eye No Retinopathy in Year Prior"
      and "Has Right Eye No Retinopathy in Year Prior"
  )

define "Retinal Exam Finding with Retinopathy Severity Level in Measurement Period":
  ( "Has Left Eye Retinopathy"
      and "Has Right Eye Retinopathy"
  )
    or ( "Has Left Eye Retinopathy"
        and "Has Right Eye No Retinopathy in Year Prior"
    )
    or ( "Has Right Eye Retinopathy"
        and "Has Left Eye No Retinopathy in Year Prior"
    )

define "SDE Ethnicity":
  SDE."SDE Ethnicity"

define "SDE Payer":
  SDE."SDE Payer"

define "SDE Race":
  SDE."SDE Race"

define "SDE Sex":
  SDE."SDE Sex"
ELM XML Content 
Encoded data
ELM JSON Content 
Encoded data
Citations and References
Dependency Description: Library FHIRHelpers
Resource: FHIRHelpers version: 4.4.000
Canonical URL: https://madie.cms.gov/Library/FHIRHelpers|4.4.000
Dependency Description: Library SDE
Resource: SupplementalDataElements version: 5.1.000
Canonical URL: https://madie.cms.gov/Library/SupplementalDataElements|5.1.000
Dependency Description: Library QICoreCommon
Resource: QICoreCommon version: 4.0.000
Canonical URL: https://madie.cms.gov/Library/QICoreCommon|4.0.000
Dependency Description: Library Hospice
Resource: Hospice version: 6.18.000
Canonical URL: https://madie.cms.gov/Library/Hospice|6.18.000
Dependency Description: Library Status
Resource: Status version: 1.15.000
Canonical URL: https://madie.cms.gov/Library/Status|1.15.000
Dependency Description: Library PalliativeCare
Resource: PalliativeCare version: 1.18.000
Canonical URL: https://madie.cms.gov/Library/PalliativeCare|1.18.000
Dependency Description: Library AIFrailLTCF
Resource: AdvancedIllnessandFrailty version: 1.27.000
Canonical URL: https://madie.cms.gov/Library/AdvancedIllnessandFrailty|1.27.000
Dependency Description: Code system LOINC
Resource: Logical Observation Identifiers, Names and Codes (LOINC)
Canonical URL: http://loinc.org
Dependency Description: Code system SNOMEDCT
Resource: SNOMED CT (all versions)
Canonical URL: http://snomed.info/sct
Dependency Description: Value set Annual Wellness Visit
Resource: Annual Wellness Visit
Canonical URL: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.526.3.1240
Dependency Description: Value set Autonomous Eye Exam Result or Finding
Resource: Autonomous Eye Exam Result or Finding
Canonical URL: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1004.2616
Dependency Description: Value set Diabetes
Resource: Diabetes
Canonical URL: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.103.12.1001
Dependency Description: Value set Diabetic Retinopathy
Resource: Diabetic Retinopathy
Canonical URL: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.526.3.327
Dependency Description: Value set Diabetic Retinopathy Severity Level
Resource: Diabetic Retinopathy Severity Level
Canonical URL: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.1266
Dependency Description: Value set Home Healthcare Services
Resource: Home Healthcare Services
Canonical URL: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1016
Dependency Description: Value set Office Visit
Resource: Office Visit
Canonical URL: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1001
Dependency Description: Value set Ophthalmological Services
Resource: Ophthalmological Services
Canonical URL: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.526.3.1285
Dependency Description: Value set Preventive Care Services Established Office Visit, 18 and Up
Resource: Preventive Care Services Established Office Visit, 18 and Up
Canonical URL: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1025
Dependency Description: Value set Preventive Care Services Initial Office Visit, 18 and Up
Resource: Preventive Care Services Initial Office Visit, 18 and Up
Canonical URL: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1023
Dependency Description: Value set Retinal or Dilated Eye Exam
Resource: Retinal or Dilated Eye Exam
Canonical URL: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.115.12.1088
Dependency Description: Value set Telephone Visits
Resource: Telephone Visits
Canonical URL: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1080
Generated using version 0.5.6 of the sample-content-ig Liquid templates