CPG Opioid Prescribing Guideline Examples
1.0.0 - ci-build International flag

CPG Opioid Prescribing Guideline Examples, published by HL7 International - Clinical Decision Support WG. This guide is not an authorized publication; it is the continuous build for version 1.0.0 built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/cqframework/cpg-example-opioids/ and changes regularly. See the Directory of published versions

Library: Opioid CDS R4 Logic for recommendation #5 (Experimental)

Official URL: http://hl7.org/fhir/uv/cpg/opiods/Library/OpioidCDSR4Recommendation05 Version: 1.0.0
Draft as of 2024-03-01 Computable Name: OpioidCDSR4Recommendation05

Copyright/Legal: CDC 2016+

Opioid Decision Support Logic for use in implementing CDC Opioid Prescribing Guidelines.

This library works in concert with the OMTK logic library to provide decision support for Morphine Milligram Equivalence calculations and dynamic value resolution.

Participants

AuthorKensaku Kawamoto, MD, PhD, MHS
AuthorBryn Rhodes
AuthorFloyd Eisenberg, MD, MPH
AuthorRobert McClure, MD, MPH

Related Artifacts

documentationCDC guideline for prescribing opioids for chronic painhttps://www.cdc.gov/mmwr/volumes/65/rr/rr6501e1.htm?CDC_AA_refVal=https%3A%2F%2Fwww.cdc.gov%2Fmmwr%2Fvolumes%2F65%2Frr%2Frr6501e1er.htm
documentationMME Conversion Tableshttps://www.cdc.gov/drugoverdose/pdf/calculating_total_daily_dose-a.pdf
depends-onLibrary Commonhttp://hl7.org/fhir/uv/cpg/opioids/Library/OpioidCDSR4Common|0.1.0

Parameters

ContextPrescriptionsin01MedicationRequest
Patientout01Patient
Exclusion Criteriaout01boolean
Total MMEout01Quantity
Inclusion Criteriaout01boolean
Taper Nowout01boolean
Consider Taperingout01boolean
Get Indicatorout01string
Get Summaryout01string
Get Detailout01string

Contents

text/cql

library OpioidCDSR4Recommendation05 version '0.1.0'

using FHIR version '4.0.0'

include OpioidCDSR4Common version '0.1.0' called Common

/*
**
** Recommendation #5
**
*/

/*
  Plan Definition:
	http://build.fhir.org/ig/cqframework/opioid-cds/PlanDefinition-opioidcds-r4-recommendation-05.html
*/

parameter ContextPrescriptions List<MedicationRequest>

context Patient

define "Inclusion Criteria":
  AgeInYears() >= 18
    and not "Exclusion Criteria"
    and "Total MME" >= 50 'mg/d'

define "Exclusion Criteria":
  Common."End of Life Assessment"

define "Total MME":
  Common.TotalMME(ContextPrescriptions union Common."Active Ambulatory Opioid Rx")

define "Taper Now": "Total MME".value >= 90

define "Consider Tapering": "Total MME".value < 90

define "Get Indicator":
  if "Inclusion Criteria"
    then 'warning'
  else null

define "Get Summary":
  if "Inclusion Criteria"
    then
      'High risk for opioid overdose - '
        + case when "Taper Now"
           then 'taper now'
           else 'consider tapering'
         end
  else null

define "Get Detail":
  if "Inclusion Criteria"
    then'Total morphine milligram equivalent (MME) is ' + ToString("Total MME") + '. Taper to less than 50.'
  else null

Content not shown - (application/elm+xml, size = 16Kb)