WHO Antenatal Care Guideline Implementation Guide
0.3.0 - CI Build International flag

WHO Antenatal Care Guideline Implementation Guide, published by World Health Organization (WHO). This guide is not an authorized publication; it is the continuous build for version 0.3.0 built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/WorldHealthOrganization/smart-anc/ and changes regularly. See the Directory of published versions

Library: ANC.IND.02 Percentage of pregnant women who received iron and folic acid (IFA) supplements for 90+ days

Official URL: http://fhir.org/guides/who/anc-cds/Library/ANCIND02 Version: 0.3.0
Active as of 2024-02-13 Computable Name: ANCIND02

This library provides logic for calculating the percentage of pregnant women who received iron and folic acid (IFA) supplements for 90+ days

Id: ANCIND02
Url: ANC.IND.02 Percentage of pregnant women who received iron and folic acid (IFA) supplements for 90+ days
Version: 0.3.0
Name: ANCIND02
Title: ANC.IND.02 Percentage of pregnant women who received iron and folic acid (IFA) supplements for 90+ days
Status: active
Experimental: false
Type:

system: LibraryType

code: logic-library

Date: 2024-02-13 15:17:14+0000
Publisher: World Health Organization (WHO)
Description: This library provides logic for calculating the percentage of pregnant women who received iron and folic acid (IFA) supplements for 90+ days
Jurisdiction: 001
Related Artifacts:

Dependencies

Parameters:
NameTypeMinMaxIn/Out
Measurement PeriodPeriod01in
PatientPatient01out
Initial Populationboolean01out
Numeratorboolean01out
Denominatorboolean01out
Age StratifierCoding01out
Education Level StratifierCodeableConcept0*out
Data Requirements:
TypeProfileMSCode Filter
Patient http://hl7.org/fhir/StructureDefinition/Patient ;;
EpisodeOfCare http://hl7.org/fhir/StructureDefinition/EpisodeOfCare ; code filter:
path: type
value set: http://fhir.org/guides/who/anc-cds/ValueSet/antenatal-care-case
Encounter http://hl7.org/fhir/StructureDefinition/Encounter ;; code filter:
path: type
value set: http://fhir.org/guides/who/anc-cds/ValueSet/antenatal-care-contact
MedicationRequest http://hl7.org/fhir/StructureDefinition/MedicationRequest ; code filter:
path: medication
value set: http://fhir.org/guides/who/anc-cds/ValueSet/iron-supplement
MedicationRequest http://hl7.org/fhir/StructureDefinition/MedicationRequest ; code filter:
path: medication
value set: http://fhir.org/guides/who/anc-cds/ValueSet/folic-acid-supplement
Observation http://hl7.org/fhir/StructureDefinition/Observation ;;;; code filter:
path: code
value set: http://fhir.org/guides/who/anc-cds/ValueSet/anc-end-1
Content: text/cql
/*
Library ANC.IND.2
WHO Antenatal Care (ANC) Indicator 2
Percentage of pregnant women who received iron and folic acid (IFA) supplements for 90+ days

Numerator: Number of pregnant women who received the recommended number of IFA tablets during all previous contacts
Numerator Computation: COUNT of number of women who were prescribed IFA tablets at each ANC contact they have had
Denominator: Total number of antenatal clients with a first contact
Denominator Computation: COUNT of all women whose records were closed (ANC
  close form) in the last reporting period due to any of the reasons below:
    » live birth
    » stillbirth
    » miscarriage
    » abortion
    » woman died
    » lost to follow-up
    » moved away
Disaggregation:
Age (10–14, 15–19, 20+)
Education level (none, don’t know, primary, secondary, higher)
Reference:
WHO ANC monitoring framework (1)
*/
library ANCIND02

using FHIR version '4.0.1'

include FHIRHelpers version '4.0.1'
include FHIRCommon called FC
include ANCBaseConcepts called BCx
include ANCConcepts called Cx
include ANCBaseDataElements called BaseData
include ANCDataElements called PatientData
include ANCContactDataElements called ContactData
include ANCStratifiers called Stratifiers

parameter "Measurement Period" Interval<Date> default Interval[@2020-01-01, @2020-01-31]

context Patient

/*
Initial population: Antenatal clients
*/
define "Initial Population":
  exists (BaseData."Antenatal care case")

/*
Numerator: Number of pregnant women who received the recommended number of IFA tablets during all previous contacts
Numerator Computation: COUNT of number of women who were prescribed IFA tablets at each ANC contact they have had
*/
define Numerator:
  not exists (
    BaseData."Antenatal care contact" C
      without PatientData."Amount of iron prescribed" I
        such that (singleton from I.dosageInstruction).timing.repeat.bounds overlaps C.period
      without PatientData."Amount of daily dose of folic acid prescribed" FA
          such that (singleton from FA.dosageInstruction).timing.repeat.bounds overlaps C.period
  )

/*
Denominator: Total number of antenatal clients with a first contact
Denominator Computation: COUNT of all women whose records were closed (ANC
  close form) in the last reporting period due to any of the reasons below:
    » live birth
    » stillbirth
    » miscarriage
    » abortion
    » woman died
    » lost to follow-up
    » moved away
*/
define Denominator:
  exists (
    PatientData."Reason for closing ANC record" R
      where FC.ToInterval(R.effective) during "Measurement Period"
        and R.value as FHIR.CodeableConcept in Stratifiers."Qualifying Reason for closing ANC record Choices"
  )

/*
Disaggregation: Age (10–14, 15–19, 20+)
*/
define "Age Stratifier":
  Stratifiers."By Age"

/*
Disaggregation: Education level (none, don’t know, primary, secondary, higher)
*/
define "Education Level Stratifier":
  Stratifiers."By Education Level"
Content: application/elm+xml
Encoded data (39368 characters)
Content: application/elm+json
Encoded data (68764 characters)