Clinical Practice Guidelines
2.0.0-ballot - ballot International flag

Clinical Practice Guidelines, published by HL7 International / Clinical Decision Support. This guide is not an authorized publication; it is the continuous build for version 2.0.0-ballot built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/HL7/cqf-recommendations/ and changes regularly. See the Directory of published versions

Library: Recommend Immunization (Experimental)

Official URL: http://hl7.org/fhir/uv/cpg/Library/recommendimmunization-library Version: 2.0.0-ballot
Active as of 2023-12-19 Computable Name: RecommendImmunization

Logic for an example recommendation to recommend an immunization

Related Artifacts

depends-onCode System Activity TypeCPG Activity Type Code System

Parameters

Patientout01Patient
Inclusion Criteriaout01boolean
Active or Completed Immunizationout0*Immunization
Immunization Not Doneout0*Immunization
Immunization Proposalout0*MedicationRequest
Immunization Not Proposedout0*MedicationRequest
Immunization Proposal Rejectedout0*MedicationRequest
Is Recommendation Applicableout01boolean

Data Requirements

Type: Immunization (Immunization)
Type: Immunization (Immunization)
Type: MedicationRequest (MedicationRequest)
Type: MedicationRequest (MedicationRequest)
Type: MedicationRequest (MedicationRequest)

Contents

text/cql

library RecommendImmunization

using FHIR version '4.0.1'

include FHIRHelpers version '4.0.1'

codesystem "Activity Type": 'http://hl7.org/fhir/uv/cpg/CodeSystem/cpg-activity-type-cs'

code "Recommend Immunization": 'immunization-recommendation' from "Activity Type"

context Patient

/* Recommendation to immunize the patient */

/*
NOTE: This recommendation is dramatically simplified to illustrate the general
pattern for a positive recommendation, with the ability for users to reject
the recommendation, and flexibility in how the recommendation is achieved.

Specifically:
* There is no terminology, any immunization request/event on any topic will do
* There is no timing, any immunization request/event will do at any time
* There is no reference to participants other than the patient
* There is no relationship to a setting
* There is no relationship to an encounter or episode
* There is no relationship to a care plan

These simplifications allow the example to focus exclusively on the pattern for
recommending and for accepting/rejecting the proposal, as well as documenting
the completion, or explicit non-performance of the communication.
*/

/*
Positive recommendation:

If the activity has not been performed
  If the activity has not been planned or proposed
    Propose the activity

Given a proposal, the user can:
  Accept the proposal
  Ignore the proposal
  Reject the proposal without reason
  Reject the proposal with reason

Scenario 1: No event, no plan or proposal, decision support should propose
Scenario 2: No event, incomplete proposal, decision support should not propose
Scenario 3: No event, rejected proposal, decision support should not propose
Scenario 4: Event, no proposal, decision support should not propose
Scenario 5: Event, completed proposal, decision support should not propose
Scenario 6: Event not done, no proposal, decision support should not propose
Scenario 7: Event not done, proposal, decision support should not propose

*/

define "Inclusion Criteria":
  Patient.active

define "Active or Completed Immunization":
  [Immunization] C
    where C.status in { 'completed' }

define "Immunization Not Done":
  [Immunization] C
    where C.status in { 'not-done' }

define "Immunization Proposal":
  [MedicationRequest] MR
    where exists ( (MR.category) C where C ~ "Recommend Immunization" )
      and MR.status in { 'draft', 'active' }
      and MR.doNotPerform is not true

define "Immunization Not Proposed":
  [MedicationRequest] MR
    where exists ( (MR.category) C where C ~ "Recommend Immunization" )
      and MR.status in { 'draft', 'active' }
      and MR.doNotPerform is true

define "Immunization Proposal Rejected":
  [MedicationRequest] MR
    where exists ( (MR.category) C where C ~ "Recommend Immunization" )
      and MR.status = 'cancelled'

define "Is Recommendation Applicable":
  "Inclusion Criteria"
    and not exists (
      "Active or Completed Immunization"
        union "Immunization Not Done"
    )
    and not exists (
      "Immunization Proposal"
        union "Immunization Not Proposed"
        union "Immunization Proposal Rejected"
    )

Content not shown - (application/elm+xml, size = 36Kb)

Content not shown - (application/elm+json, size = 65Kb)