Clinical Practice Guidelines
2.0.0-ballot - ballot International flag

Clinical Practice Guidelines, published by HL7 International / Clinical Decision Support. This guide is not an authorized publication; it is the continuous build for version 2.0.0-ballot built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/HL7/cqf-recommendations/ and changes regularly. See the Directory of published versions

Library: Do Not Send Message (Experimental)

Official URL: http://hl7.org/fhir/uv/cpg/Library/donotsendmessage-library Version: 2.0.0-ballot
Active as of 2023-12-19 Computable Name: DoNotSendMessage

Logic for an example recommendation not to send a message

Parameters

Patientout01Patient
Inclusion Criteriaout01boolean
Active or In-progress Communicationout0*Communication
Communication Not Doneout0*Communication
Communication Proposalout0*CommunicationRequest
Do Not Communicate Proposalout0*CommunicationRequest
Rejected Do Not Communicate Proposalout0*CommunicationRequest
Is Recommendation Applicableout01boolean

Data Requirements

Type: Communication (Communication)
Type: Communication (Communication)
Type: CommunicationRequest (CommunicationRequest)
Type: CommunicationRequest (CommunicationRequest)
Type: CommunicationRequest (CommunicationRequest)

Contents

text/cql

library DoNotSendMessage

using FHIR version '4.0.1'

include FHIRHelpers version '4.0.1'

context Patient

/* Recommendation not to greet the patient */

/*
NOTE: This recommendation is dramatically simplified to illustrate the general
pattern for a negative recommendation, with the ability for users to reject
the recommendation, and flexibility in how the recommendation is achieved/documented.

Specifically:
* There is no terminology, any communication request/event on any topic will do
* There is no timing, any communication request/event will do at any time
* There is no reference to participants other than the patient
* There is no relationship to a setting
* There is no relationship to an encounter or episode
* There is no relationship to a care plan

These simplifications allow the example to focus exclusively on the pattern for
not recommending and for accepting/rejecting the proposal, as well as documenting
the completion, or explicit non-performance of the event.
*/

/*
Negative recommendation:

If the activity is planned, in progress, and not documented
  If stopping the activity has not been proposed
    Propose the planned or in progress activity be stopped

Scenario 1: Event in progress, no proposal to stop, decision support should propose stopping
Scenario 2: Event in progress, accepted proposal to stop, decision support should not propose
Scenario 3: Event in progress, rejected proposal to stop, decision support should not propose
Scenario 4: Event planned, no proposal to stop, decision support should propose stopping
Scenario 5: Event planned, accepted proposal to stop, decision support should not propose
Scenario 6: Event planned, rejected proposal to stop, decision support should not propose
Scenario 7: Negative Event documented, decision support should not propose (nothing to do)
Scenario 8: Event completed, decision support should not propose (nothing to do)
Scenario 9: No event in progress, decision support should not propose (nothing to do)
*/

define "Inclusion Criteria":
  Patient.active

define "Active or In-progress Communication":
  [Communication] C
    where C.status in { 'preparation', 'in-progress', 'on-hold' }

define "Communication Not Done":
  [Communication] C
    where C.status in { 'not-done', 'stopped' }

define "Communication Proposal":
  [CommunicationRequest] R
    where R.status in { 'draft', 'active', 'on-hold' }
      and not (Coalesce(R.doNotPerform, false))

define "Do Not Communicate Proposal":
  [CommunicationRequest] R
    where R.status in { 'draft', 'active', 'on-hold' }
      and R.doNotPerform

define "Rejected Do Not Communicate Proposal":
  [CommunicationRequest] R
    where R.status in { 'revoked' }
      and R.doNotPerform

define "Is Recommendation Applicable":
  "Inclusion Criteria"
    and exists (
      "Active or In-progress Communication"
        union "Communication Proposal"
    )
    and not exists (
      "Communication Not Done"
    )
    and not exists (
      "Do Not Communicate Proposal"
        union "Rejected Do Not Communicate Proposal"
    )

Content not shown - (application/elm+xml, size = 29Kb)

Content not shown - (application/elm+json, size = 51Kb)