Clinical Practice Guidelines
2.0.0-ballot - ballot International flag

Clinical Practice Guidelines, published by HL7 International / Clinical Decision Support. This guide is not an authorized publication; it is the continuous build for version 2.0.0-ballot built by the FHIR (HL7® FHIR® Standard) CI Build. This version is based on the current content of https://github.com/HL7/cqf-recommendations/ and changes regularly. See the Directory of published versions

Library: Do Not Collect Information Library (Experimental)

Official URL: http://hl7.org/fhir/uv/cpg/Library/donotcollectinformation-library Version: 2.0.0-ballot
Active as of 2023-12-19 Computable Name: DoNotCollectInformationLibrary

Logic for an example recommendation not to collect information

Related Artifacts

depends-onCode System Activity TypeCPG Activity Type Code System

Parameters

collectWithQuestionnairein01string
Patientout01Patient
Inclusion Criteriaout01boolean
Collect Information Taskout0*Task
Do Not Collect Information Taskout0*Task
Active or In-progress Activityout0*Task
Activity Not Doneout0*Task
Activity Proposalout0*Task
Do Not Perform Activity Proposalout0*Task
Rejected Do Not Perform Activity Proposalout0*Task
Is Recommendation Applicableout01boolean

Data Requirements

Type: Task (Task)
Type: Task (Task)

Contents

text/cql

library DoNotCollectInformation

using FHIR version '4.0.1'

include FHIRHelpers version '4.0.1'

codesystem "Activity Type": 'http://hl7.org/fhir/uv/cpg/CodeSystem/cpg-activity-type-cs'

code "Collect information": 'collect-information' from "Activity Type"

parameter collectWithQuestionnaire String

context Patient

/* Recommendation not to collect specific information */

/*
NOTE: This recommendation is dramatically simplified to illustrate the general
pattern for a negative recommendation, with the ability for users to reject
the recommendation, and flexibility in how the recommendation is achieved/documented.

Specifically:
* There is no terminology, any task on any topic will do
* There is no timing, any task will do at any time
* There is no reference to participants other than the patient
* There is no relationship to a setting
* There is no relationship to an encounter or episode
* There is no relationship to a care plan

These simplifications allow the example to focus exclusively on the pattern for
not recommending and for accepting/rejecting the proposal, as well as documenting
the completion, or explicit non-performance of the event.
*/

/*
Negative recommendation:

If the activity is planned, in progress, and not documented
  If stopping the activity has not been proposed
    Propose the planned or in progress activity be stopped

Scenario 1: Event in progress, no proposal to stop, decision support should propose stopping
Scenario 2: Event in progress, accepted proposal to stop, decision support should not propose
Scenario 3: Event in progress, rejected proposal to stop, decision support should not propose
Scenario 4: Event planned, no proposal to stop, decision support should propose stopping
Scenario 5: Event planned, accepted proposal to stop, decision support should not propose
Scenario 6: Event planned, rejected proposal to stop, decision support should not propose
Scenario 7: Negative Event documented, decision support should not propose (nothing to do)
Scenario 8: Event completed, decision support should not propose (nothing to do)
Scenario 9: No event in progress, decision support should not propose (nothing to do)
*/

define "Inclusion Criteria":
  Patient.active

define "Collect Information Task":
  [Task] C
    where C.code ~ "Collect information"
      and collectWith(C) = collectWithQuestionnaire
      and not Coalesce(doNotPerform(C), false)

define "Do Not Collect Information Task":
[Task] C
  where C.code ~ "Collect information"
    and collectWith(C) = collectWithQuestionnaire
    and doNotPerform(C)

define "Active or In-progress Activity":
  "Collect Information Task" C
    where C.status in { 'in-progress', 'on-hold' }

define "Activity Not Done":
  ("Collect Information Task" C
    where C.status in { 'cancelled', 'failed' }
  )
    union (
      "Do Not Collect Information Task" C
        where C.status in { 'completed' }
    )

define "Activity Proposal":
  "Collect Information Task" R
    where R.status in { 'draft', 'requested', 'received', 'accepted', 'ready' }

define "Do Not Perform Activity Proposal":
  "Do Not Collect Information Task" R
    where R.status in { 'draft', 'requested', 'received', 'accepted', 'ready' }

define "Rejected Do Not Perform Activity Proposal":
  "Do Not Collect Information Task" R
    where R.status in { 'rejected' }

define "Is Recommendation Applicable":
  "Inclusion Criteria"
    and exists (
      "Active or In-progress Activity"
        union "Activity Proposal"
    )
    and not exists (
      "Activity Not Done"
    )
    and not exists (
      "Do Not Perform Activity Proposal"
        union "Rejected Do Not Perform Activity Proposal"
    )

define function doNotPerform(task Task):
  singleton from (
    task.modifierExtension E
      where E.url = 'http://hl7.org/fhir/StructureDefinition/request-doNotPerform'
  ).value as boolean

define function collectWith(task Task):
  singleton from (
    task.input I
      where I.type ~ "Collect information"
  ).value as canonical

Content not shown - (application/elm+xml, size = 50Kb)

Content not shown - (application/elm+json, size = 90Kb)